(FILECREATED "25-Jan-87 20:11:35" {QV}<NOTECARDS>1.3K>NEXT>RHTPATCH186.;2 19332
changes to: (VARS RHTPATCH186COMS)
(FNS NC.LinkIconWhenCopiedFn NC.LinkIconWhenMovedFn NC.LinkAtCharPos
NC.FillInLinkIcon)
previous date: "25-Jan-87 20:01:31" {QV}<NOTECARDS>1.3K>NEXT>RHTPATCH186.;1)
(* Copyright (c) 1987 by Xerox Corporation. All rights reserved.)
(PRETTYCOMPRINT RHTPATCH186COMS)
(RPAQQ RHTPATCH186COMS ((* * Fix to bug #247: links not keeping correct order in ShowLinks after
copy. Fix is KLUDGY in that it peeks up the stack at the
TEDIT.SELECTED.PIECES frame to figure out that we're under a multiple
links copy.)
(* * Changes to NCLINKS)
(FNS NC.FillInLinkIcon NC.LinkIconWhenCopiedFn NC.LinkIconWhenMovedFn
NC.LinkAtCharPos)))
(* * Fix to bug #247: links not keeping correct order in ShowLinks after copy. Fix is KLUDGY
in that it peeks up the stack at the TEDIT.SELECTED.PIECES frame to figure out that we're under
a multiple links copy.)
(* * Changes to NCLINKS)
(DEFINEQ
(NC.FillInLinkIcon
(LAMBDA (ImageObj Label DestinationCard SourceCard DisplayMode LinkToInsertAfter CrossFileLinksMode)
(* rht: "25-Jan-87 20:01")
(* * Called by WhenCopiedFn and WhenMovedFn to build the new link and stick it in the ImageObj.)
(* * rht 1/25/87: Now returns the new link.)
(DECLARE (GLOBALVARS NC.LinkIconImageFns))
(LET ((Link (NC.MakeLink NIL Label DestinationCard SourceCard DisplayMode NIL NIL NIL
LinkToInsertAfter CrossFileLinksMode)))
(IMAGEOBJPROP ImageObj (QUOTE OBJECTDATUM)
Link)
(replace (IMAGEOBJ IMAGEOBJFNS) of ImageObj with NC.LinkIconImageFns)
Link)))
(NC.LinkIconWhenCopiedFn
(LAMBDA (ImageObject ToWindowStream FromTextStream ToTextStream)
(* rht: "25-Jan-87 20:10")
(* * Called when copying a link icon from FromTextStream to ToWindowStream. Sets the necessary link information up
for card corresponding to ToWindowStream.)
(* * rht 11/18/84: Major hacking. Now checks for all sorts of illegal cases. Either goes ahead with copy, converts
link type to "Unspecified", or deletes the new "invisible" link. The latter will change when imageobj fns can
return DON'T.)
(* * rht 12/12/84: now does RETFROM instead of adding processes to delete imageobj's. This is cleaner, but still
ugly.)
(* * rht 3/25/85: Fixed to handle copies within a sketch card. That is indicated by nullity of the two textstream
args.)
(* * rht 3/24/86: Changed call to NC.CoerceToID to NC.CoerceToCard)
(* * fgh 6/30/86 Now ERROR! out of attempt to copy between NoteFiles)
(* * rht 7/14/86: Reversed order of tests for WINDOWP and TEXTSTREAMP in computation of NewSourceCard.)
(* * rht 8/11/86: Now only resets NewSourceCard if it was NIL so that copies to a sketch will work.)
(* * rht 10/5/86: Undid change fgh 6/30/86: now allows copies of links across notefiles. Also handles illegal
copies differently. Rather than RETFROM'ing or ERROR!'ing, it puts in a DELETE ME imageobj.)
(* * rht 12/16/86: Now passes Window to NC.GetCrossFileLinkDestCard.)
(* * rht 1/21/87: Now handles attempt to copy to non-NoteCards stream differently than other illegalities.)
(* * rht 1/25/87: Now stashes new link created on source card's user data props for use by NC.LinkAtCharPos in case
this is a copy of multiple links.)
(DECLARE (GLOBALVARS NC.CopyCrossFileLinksMode NC.DELETEMEImageObjDatum NC.SystemLinkLabels
NC.UnspecifiedLinkLabel NC.NewCrossFileLinksTwoWayFlg))
(LET ((Link (NC.FetchLinkFromLinkIcon ImageObject))
(ImageObjectCopy (IMAGEOBJPROP ImageObject (QUOTE ImageObjectCopy)))
(InTEditCopyFlg (COND
((STKPOS (QUOTE TEDIT.COPY))
T)))
(Window (AND ToWindowStream (WFROMDS ToWindowStream T)))
SourceCard DestinationCard NewSourceCard NewLabel NewDisplayMode OldDisplayMode Label
InsertPos IllegalCopyFlg ExternalCopyFlg)
(SETQ Label (fetch (Link Label) of Link))
(SETQ SourceCard (fetch (Link SourceCard) of Link))
(SETQ DestinationCard (fetch (Link DestinationCard) of Link))
(SETQ OldDisplayMode (fetch (Link DisplayMode) of Link))
(SETQ NewSourceCard (COND
((TEXTSTREAMP ToTextStream)
(NC.CoerceToCard ToTextStream))
((WINDOWP Window)
(NC.CoerceToCard Window))))
(COND
((AND (NULL NewSourceCard)
(NULL FromTextStream)
(NULL ToTextStream)) (* We must be moving within a sketch.)
(SETQ NewSourceCard SourceCard))
((TEXTSTREAMP ToTextStream) (* If it's a text copy, then compute position to
insert link at.)
(SETQ InsertPos (NC.CharPosFromTextObject (TEXTOBJ ToTextStream)))))
(COND
((NULL NewSourceCard) (* Trying to copy to a non NoteCard stream)
(NC.PrintMsg Window NIL (CONCAT "Tried to copy a NoteCards link icon"
" to a non-NoteCards stream."
(CHARACTER 13)))
(SETQ ExternalCopyFlg T))
((NULL (NC.LinksSupportedP NewSourceCard (QUOTE (Local))))
(NC.PrintMsg Window NIL (CONCAT "Tried to copy a NoteCards link icon"
" to a NoteCard that"
" does not support links!!."
(CHARACTER 13)))
(SETQ IllegalCopyFlg T))
((AND (FMEMB Label (QUOTE (FiledCard SubBox)))
(NEQ (NC.RetrieveType NewSourceCard)
(QUOTE FileBox))) (* Copy from filebox to non-filebox.)
(NC.PrintMsg Window NIL (CONCAT
"Tried to copy filedcard or subbox link to a non-filebox."
(CHARACTER 13)
"Link type of copy set to 'Unspecified'."
(CHARACTER 13)))
(SETQ NewLabel NC.UnspecifiedLinkLabel)
(SETQ NewDisplayMode (create LINKDISPLAYMODE
copying OldDisplayMode SHOWTITLEFLG ← T SHOWLINKTYPEFLG ← T))
)
((AND (NEQ (NC.RetrieveType SourceCard)
(QUOTE FileBox))
(EQ (NC.RetrieveType NewSourceCard)
(QUOTE FileBox))) (* Copy from non-filebox to filebox.)
(NC.PrintMsg Window NIL (CONCAT "Can't copy links from non-filebox to filebox."
(CHARACTER 13)
"Try using 'PutCardsHere'."
(CHARACTER 13)))
(SETQ IllegalCopyFlg T))
((AND (FMEMB Label (QUOTE (FiledCard SubBox)))
(EQ NewSourceCard SourceCard)) (* Copy within same filebox.)
(NC.PrintMsg Window NIL (CONCAT
"Can't copy links within a FileBox. Try move instead."
(CHARACTER 13)))
(SETQ IllegalCopyFlg T))
((AND (EQ (NC.RetrieveType NewSourceCard)
(QUOTE FileBox))
(for Link1 in (NC.FetchToLinks NewSourceCard)
thereis (AND (NC.ChildLinkP Link1)
(EQ DestinationCard (fetch (Link DestinationCard)
of Link1)))))
(* Copy to a filebox already containing this child.)
(NC.PrintMsg Window NIL (CONCAT (NC.RetrieveTitle DestinationCard)
" not copied: already appears as a child of "
(NC.RetrieveTitle NewSourceCard)
(CHARACTER 13)))
(SETQ IllegalCopyFlg T))
((AND (EQ Label (QUOTE SubBox))
(OR (EQ NewSourceCard DestinationCard)
(NOT (NC.NotDaughterP DestinationCard NewSourceCard
(FUNCTION NC.ChildLinkP)))))
(* Copy to a filebox causes a cycle.)
(NC.PrintMsg Window NIL (CONCAT "Couldn't copy " Link " because of subbox cycle."
(CHARACTER 13)))
(SETQ IllegalCopyFlg T))
((AND (FMEMB Label NC.SystemLinkLabels)
(NOT (FMEMB Label (QUOTE (FiledCard SubBox))))
(NEQ NewSourceCard SourceCard)) (* Copy of system link outside of own card.)
(NC.PrintMsg Window NIL (CONCAT "Tried to copy system link." (CHARACTER 13)
"Link type of copy set to 'Unspecified'."
(CHARACTER 13)))
(SETQ NewLabel NC.UnspecifiedLinkLabel)
(SETQ NewDisplayMode (create LINKDISPLAYMODE
copying OldDisplayMode SHOWTITLEFLG ← T SHOWLINKTYPEFLG ← T))
)
((NC.CrossFileLinkCardP DestinationCard) (* Copy of a cross-file link.)
(if (NOT (NC.ActiveCardP DestinationCard))
then (NC.GetNoteCard DestinationCard))
(* If it's to be two-way, then make a fresh
CrossFileLinkCard.)
(if (OR (EQ NC.CopyCrossFileLinksMode (QUOTE TWOWAY))
(AND (NULL NC.CopyCrossFileLinksMode)
NC.NewCrossFileLinksTwoWayFlg))
then (SETQ DestinationCard (NC.GetCrossFileLinkDestCard DestinationCard Window)
))
(OR DestinationCard (SETQ IllegalCopyFlg T))))
(COND
(IllegalCopyFlg (IMAGEOBJPROP ImageObjectCopy (QUOTE OBJECTDATUM)
NC.DELETEMEImageObjDatum)
(NC.SetUserDataProp SourceCard (QUOTE NeedsCleaningFlg)
T))
(ExternalCopyFlg (NC.CoerceToExternalPutLinkIcon ImageObjectCopy SourceCard
DestinationCard (OR NewLabel Label)))
(T (NC.SetUserDataProp NewSourceCard (QUOTE LastLinkCopiedOrMoved)
(NC.FillInLinkIcon ImageObjectCopy (OR NewLabel Label)
DestinationCard NewSourceCard
(OR NewDisplayMode OldDisplayMode)
(NC.LinkAtCharPos InsertPos ToTextStream)
NC.CopyCrossFileLinksMode))))
(IMAGEOBJPROP ImageObject (QUOTE ImageObjectCopy)
NIL))))
(NC.LinkIconWhenMovedFn
(LAMBDA (ImageObject ToWindowStream FromTextStream ToTextStream)
(* rht: "25-Jan-87 20:10")
(* * Called when moving a link icon from FromTextStream to ToWindowStream. Sets the necessary link information up
for card corresponding to ToWindowStream.)
(* * rht 11/18/84: Major hacking. Now checks for all sorts of illegal cases. Either goes ahead with move, converts
link type to "Unspecified", or deletes the new "invisible" link. The code is very similar to
NC.LinkIconWhenCopiedFn except that within-filebox moves are allowed. Also when aborting a move, we must insert a
copy of the link back to take the place of the deleted original. This will all change when imageobj fns can return
DON'T.)
(* * rht 12/12/84: Now just RETFROM's rather than doing the addprocess stuff. Should be cleaner, but still ugly.)
(* * kirk 15Nov85: deleted use of PSA.Database)
(* * rht 3/24/86: Changed call to NC.CoerceToID to NC.CoerceToCard)
(* * kirk 24Mar86: added Dave Newman patch to avoid duplicate links in sketch cards)
(* * rht 7/14/86: Reversed order of tests for WINDOWP and TEXTSTREAMP in computation of NewSourceCard.)
(* * rht 8/11/86: Now only resets NewSourceCard if it was NIL so that moves to a sketch will work.
Now checks if SourceCard = NewSourceCard in which case we're moving within a card. Don't make a new link in that
case.)
(* * rht 10/5/86: Undid change fgh 6/30/86: now allows copies of links across notefiles.)
(* * rht 11/13/86: Removed "tsk, tsk" messages.)
(* * rht 12/16/86: Fixed calls to NC.PrintMsg to use Window arg.)
(* * rht 1/25/87: Now stashes new link created on source card's user data props for use by NC.LinkAtCharPos in case
this is a copy of multiple links.)
(DECLARE (GLOBALVARS NC.SystemLinkLabels NC.UnspecifiedLinkLabel))
(LET (Label (Link (NC.FetchLinkFromLinkIcon ImageObject))
SourceCard DestinationCard NewSourceCard NewLabel NewDisplayMode OldDisplayMode
(Window (AND ToWindowStream (WFROMDS ToWindowStream T)))
InsertPos)
(SETQ Label (fetch (Link Label) of Link))
(SETQ NewSourceCard (COND
((TEXTSTREAMP ToTextStream)
(NC.CoerceToCard ToTextStream))
((WINDOWP Window)
(NC.CoerceToCard Window))))
(SETQ SourceCard (fetch (Link SourceCard) of Link))
(SETQ DestinationCard (fetch (Link DestinationCard) of Link))
(SETQ OldDisplayMode (fetch (Link DisplayMode) of Link))
(COND
((AND (NULL NewSourceCard)
(NULL FromTextStream)
(NULL ToTextStream)) (* We must be moving within a sketch.)
(SETQ NewSourceCard SourceCard))
((TEXTSTREAMP ToTextStream) (* If it's a text copy, then compute position to
insert link at.)
(SETQ InsertPos (NC.CharPosFromTextObject (TEXTOBJ ToTextStream)))))
(COND
((NULL NewSourceCard) (* Trying to copy to a non NoteCard stream)
(NC.PrintMsg Window NIL (CONCAT "Tried to move a NoteCards link icon"
" to a non-NoteCards stream!!."
(CHARACTER 13)))
(RETFROM (QUOTE TEDIT.MOVE)
NIL T))
((NULL (NC.LinksSupportedP NewSourceCard (QUOTE (Local))))
(NC.PrintMsg Window NIL (CONCAT "Tried to move a NoteCards link icon"
" to a NoteCard that"
" does not support links!!."
(CHARACTER 13)))
(RETFROM (QUOTE TEDIT.MOVE)
NIL T))
((AND (FMEMB Label (QUOTE (FiledCard SubBox)))
(NEQ (NC.RetrieveType NewSourceCard)
(QUOTE FileBox))) (* Move from filebox to non-filebox.)
(NC.PrintMsg Window NIL (CONCAT
"Tried to move filedcard or subbox link to a non-filebox."
(CHARACTER 13)
"Link type of copy set to 'Unspecified'."
(CHARACTER 13)))
(SETQ NewLabel NC.UnspecifiedLinkLabel)
(SETQ NewDisplayMode (create LINKDISPLAYMODE
copying OldDisplayMode SHOWTITLEFLG ← T SHOWLINKTYPEFLG ← T))
)
((AND (NEQ (NC.RetrieveType SourceCard)
(QUOTE FileBox))
(EQ (NC.RetrieveType NewSourceCard)
(QUOTE FileBox))) (* Move from non-filebox to filebox.)
(NC.PrintMsg Window NIL (CONCAT "Can't move links from non-filebox to filebox."
(CHARACTER 13)
"Try using PutCardsHere."
(CHARACTER 13)))
(RETFROM (QUOTE TEDIT.MOVE)
NIL T))
((AND (EQ (NC.RetrieveType NewSourceCard)
(QUOTE FileBox))
(NEQ NewSourceCard SourceCard)
(for Link1 in (NC.FetchToLinks NewSourceCard)
thereis (AND (NC.ChildLinkP Link1)
(EQ DestinationCard (fetch (Link DestinationCard)
of Link1)))))
(* Move to a filebox already containing this child.)
(NC.PrintMsg Window NIL (CONCAT (NC.RetrieveTitle DestinationCard)
" not moved: already appears as a child of "
(NC.RetrieveTitle NewSourceCard)
(CHARACTER 13)))
(RETFROM (QUOTE TEDIT.MOVE)
NIL T))
((AND (EQ Label (QUOTE SubBox))
(NEQ NewSourceCard SourceCard)
(OR (EQ NewSourceCard DestinationCard)
(NOT (NC.NotDaughterP DestinationCard NewSourceCard
(FUNCTION NC.ChildLinkP)))))
(* Move to a filebox causes a cycle.)
(NC.PrintMsg Window NIL (CONCAT "Couldn't move " Link " because of subbox cycle."
(CHARACTER 13)))
(RETFROM (QUOTE TEDIT.MOVE)
NIL T))
((AND (FMEMB Label NC.SystemLinkLabels)
(NOT (FMEMB Label (QUOTE (FiledCard SubBox))))
(NEQ NewSourceCard SourceCard)) (* Move of system link outside of own card.)
(NC.PrintMsg Window NIL (CONCAT "Tried to copy system link." (CHARACTER 13)
"Link type of copy set to 'Unspecified'."
(CHARACTER 13)))
(SETQ NewLabel NC.UnspecifiedLinkLabel)
(SETQ NewDisplayMode (create LINKDISPLAYMODE
copying OldDisplayMode SHOWTITLEFLG ← T SHOWLINKTYPEFLG ← T))
))
(if (EQ SourceCard NewSourceCard)
then (* Moving within a card, so just reposition Link in
ToLinks list.)
(AND (NC.TEditBasedP SourceCard)
(IMAGEOBJPROP ImageObject (QUOTE LinkBeingMovedWithinCard)
Link))
(NC.AddToLink Link (NC.LinkAtCharPos InsertPos ToTextStream)
T)
else (IMAGEOBJPROP ImageObject (QUOTE LinkBeingMoved)
Link)
(NC.SetUserDataProp NewSourceCard (QUOTE LastLinkCopiedOrMoved)
(NC.FillInLinkIcon ImageObject (OR NewLabel Label)
DestinationCard NewSourceCard
(OR NewDisplayMode OldDisplayMode)
(NC.LinkAtCharPos InsertPos
ToTextStream)))))))
(NC.LinkAtCharPos
(LAMBDA (CharPos TextStream) (* rht: "25-Jan-87 20:10")
(* * Returns the link right before CharPos in TextStream. Return NIL if there is no link icon located before
CharPos.)
(* * rht 1/25/87: Now takes special kludgy action if we're under a copy of multiple links. If it's past the first
link in the copy then the value returned is the link just copied previously.)
(if (TEXTSTREAMP TextStream)
then (if (CAR (NLSETQ (STKARG (QUOTE NPC)
(QUOTE TEDIT.SELECTED.PIECES))))
then (NC.FetchUserDataProp (NC.CoerceToCard TextStream)
(QUOTE LastLinkCopiedOrMoved))
else (for LinkIconPair in (TEDIT.LIST.OF.OBJECTS (TEXTOBJ TextStream)
(FUNCTION
NC.LinkIconImageObjP))
bind OldLinkIconPair while (LESSP (CADR LinkIconPair)
CharPos)
do (SETQ OldLinkIconPair LinkIconPair)
finally (RETURN (AND OldLinkIconPair (NC.FetchLinkFromLinkIcon
(CAR OldLinkIconPair)))))))))
)
(PUTPROPS RHTPATCH186 COPYRIGHT ("Xerox Corporation" 1987))
(DECLARE: DONTCOPY
(FILEMAP (NIL (1071 19250 (NC.FillInLinkIcon 1081 . 1848) (NC.LinkIconWhenCopiedFn 1850 . 10451) (
NC.LinkIconWhenMovedFn 10453 . 18075) (NC.LinkAtCharPos 18077 . 19248)))))
STOP