-- TiogaFileOpsImpl.mesa
-- written by Bill Paxton, June 1982
-- last written by Paxton. June 7, 1982 2:37 pm

DIRECTORY
TiogaFileOps,
NameSymbolTable,
PutGet,
TextEdit,
TextLooks,
TextNode,
Rope;

TiogaFileOpsImpl: PROGRAM
	IMPORTS NameSymbolTable, PutGet, Rope, TextEdit, TextNode
	EXPORTS TiogaFileOps =
BEGIN
OPEN TiogaFileOps;

CreateRoot: PUBLIC PROC RETURNS [root: Ref] = {
	root _ TextNode.NewTextNode[];
	root.last _ TRUE };

InsertNode: PUBLIC PROC [x: Ref, child: BOOL _ FALSE] RETURNS [new: Ref] = {
	-- if ~child then new is sibling of x
	-- else new is first child of x
	new _ TextNode.NewTextNode[];
	IF child THEN {
		IF x.child # NIL THEN { new.next _ x.child; new.last _ FALSE }
		ELSE { new.next _ x; new.last _ TRUE };
		x.child _ new }
	ELSE { new.next _ x.next; new.last _ x.last; x.next _ new; x.last _ FALSE }};

SetContents: PUBLIC PROC [x: Ref, txt: Rope.Ref] = { x.rope _ txt; x.runs _ NIL };

AddLooks: PUBLIC PROC [x: Ref, start, len: INT, look: CHAR ['a..'z], root: Ref _ NIL] = {
	looks: TextLooks.Looks _ TextLooks.noLooks;
	looks[look] _ TRUE;
	IF root = NIL THEN root _ TextNode.NarrowToTextNode[TextNode.Root[x]];
	TextEdit.AddLooks[root, x, looks, start, len] };

SetFormat: PUBLIC PROC [x: Ref, format: Rope.Ref] = {
	name: TextNode.TypeName _ NameSymbolTable.MakeName[
		LOOPHOLE[Rope.Flatten[format]]];
	TextEdit.ChangeType[x, name] };

SetStyle: PUBLIC PROC [x: Ref, style: Rope.Ref] = { TextEdit.ChangeStyle[x, style] };

Store: PUBLIC PROC [x: Ref, filename: Rope.Ref] = { [] _ PutGet.ToFile[filename, x] };

END.