-- SimStorageImpl.mesa
-- last edited by Suzuki: November 30, 1981  2:46 PM 

DIRECTORY
	AltoDefs,
	SegmentDefs,
	SimStorage,
	SimTsim;

SimStorageImpl: PROGRAM
	IMPORTS SegmentDefs
	EXPORTS SimStorage = { OPEN SimTsim;

restNode: CARDINAL _ 0;
originNode: LONG POINTER;
restTrans: CARDINAL _ 0;
originTrans: LONG POINTER;
restUsymbol: CARDINAL _ 0;
originUsymbol: LONG POINTER;
restWnode: CARDINAL _ 0;
originWnode: LONG POINTER;

VMPageUsed: PACKED ARRAY [0..AltoDefs.MaxVMPage] OF BOOLEAN;

AllocateNode: PUBLIC PROC RETURNS [ret: LONG POINTER] = { OPEN SegmentDefs;
	segment: DataSegmentHandle;
	IF restNode<SIZE[Node] THEN {
		restNode _ 1024;
		segment _ NewDataSegment[base: DefaultXMBase, pages: 4];
		MarkVMPage[segment, 4];
		originNode _ LongDataSegmentAddress[segment]};
	ret _ originNode;
	originNode _ originNode + SIZE[Node];
	restNode _ restNode - SIZE[Node];
	};

AllocateTrans: PUBLIC PROC RETURNS [ret: LONG POINTER] = { OPEN SegmentDefs;
	segment: DataSegmentHandle;
	IF restTrans<SIZE[Trans] THEN {
		restTrans _ 1024;
		segment _ NewDataSegment[base: DefaultXMBase, pages: 4];
		MarkVMPage[segment, 4];
		originTrans _ LongDataSegmentAddress[segment]};
	ret _ originTrans;
	originTrans _ originTrans + SIZE[Trans];
	restTrans _ restTrans - SIZE[Trans];
	};

AllocateUsymbol: PUBLIC PROC RETURNS [ret: LONG POINTER] = { OPEN SegmentDefs;
	segment: DataSegmentHandle;
	IF restUsymbol<SIZE[Usymbol] THEN {
		restUsymbol _ 1024;
		segment _ NewDataSegment[base: DefaultXMBase, pages: 4];
		MarkVMPage[segment, 4];
		originUsymbol _ LongDataSegmentAddress[segment]};
	ret _ originUsymbol;
	originUsymbol _ originUsymbol + SIZE[Usymbol];
	restUsymbol _ restUsymbol - SIZE[Usymbol];
	};

AllocateWnode: PUBLIC PROC RETURNS [ret: LONG POINTER] = { OPEN SegmentDefs;
	segment: DataSegmentHandle;
	IF restWnode<SIZE[Wnode] THEN {
		restWnode _ 1024;
		segment _ NewDataSegment[base: DefaultXMBase, pages: 4];
		MarkVMPage[segment, 4];
		originWnode _ LongDataSegmentAddress[segment]};
	ret _ originWnode;
	originWnode _ originWnode + SIZE[Wnode];
	restWnode _ restWnode - SIZE[Wnode];
	};

MarkVMPage: PROC [segment: SegmentDefs.DataSegmentHandle, pages: CARDINAL] = { 
	i: CARDINAL;
	FOR i IN [0..pages) DO
		VMPageUsed[segment.VMpage+i] _ TRUE
		ENDLOOP};

FreeNodes: PUBLIC PROC = { OPEN SegmentDefs;
	i: [0..AltoDefs.MaxVMPage];
	p: LONG POINTER;
	ds: DataSegmentHandle;
	FOR i IN [0..AltoDefs.MaxVMPage] DO
		IF VMPageUsed[i]=TRUE THEN {
			VMPageUsed[i] _ FALSE;
			p _ LongAddressFromPage[i];
			ds _ LongVMtoDataSegment[p];
			IF ds#NIL THEN DeleteDataSegment[ds]}
		ENDLOOP};

i: [0..AltoDefs.MaxVMPage];
FOR i IN [0..AltoDefs.MaxVMPage] DO
  VMPageUsed[i] _ FALSE
  ENDLOOP;
}.