(FILECREATED "26-Jun-84 23:38:09" {ERIS}<LISPCORE>LIBRARY>LOGOCLOCK.;2
 3353   

      changes to:  (FNS LOGOCLOCK1)

      previous date: "13-Apr-84 08:32:38" {PHYLUM}<LISPCORE>LIBRARY>LOGOCLOCK.;1)


(* Copyright (c) 1983, 1984 by Xerox Corporation. All rights reserved.)

(PRETTYCOMPRINT LOGOCLOCKCOMS)

(RPAQQ LOGOCLOCKCOMS
 ((FNS LOGOCLOCK LOGOCLOCK.PROC LOGOCLOCK1 DRAWANGLE WAKE.LOGOCLOCK)
		      (P (LOGOCLOCK LOGOW))))
(DEFINEQ

(LOGOCLOCK

  [LAMBDA (W)                                                (* lmm "23-JUN-83 03:30")

    (COND
      ((TYPENAMEP W (QUOTE WINDOW))
	(CLEARW W)))
    (LOGOCLOCK1
 W])

(LOGOCLOCK.PROC

  [LAMBDA (WINDOW X Y R)                                     (* lmm "23-JUN-83 03:25")

    (PROG (INSIDERADIUS HOURHANDSIZE MINUTEHANDSIZE DATE SECONDS HOUR MINUTE)
                                                             (* Allow 10 points at top for digital form)

          (SETQ INSIDERADIUS (IDIFFERENCE R 10))
          (SETQ HOURHANDSIZE (FTIMES .5 INSIDERADIUS))
          (SETQ MINUTEHANDSIZE (FTIMES .8 INSIDERADIUS))
          (do
 (SETQ DATE (DATE))
	      (SETQ SECONDS (SUBATOM DATE -2 -1))
	      (SETQ DATE (SUBSTRING DATE 1 -4 DATE))
	      (SETQ MINUTE (SUBATOM DATE -2 -1))
	      (BITBLT NIL NIL NIL WINDOW (IDIFFERENCE X INSIDERADIUS)
		      (IDIFFERENCE Y INSIDERADIUS)
		      (TIMES 2 INSIDERADIUS)
		      (TIMES 2 INSIDERADIUS)
		      (QUOTE TEXTURE)
		      (QUOTE ERASE)
		      BLACKSHADE)
	      (DRAWCIRCLE X Y 2 (QUOTE (ROUND 4))
			  NIL WINDOW)
	      (SETQ HOUR (SUBATOM DATE -5 -4))
	      (DRAWANGLE
 X Y (PLUS (TIMES 30 HOUR)
				   (QUOTIENT MINUTE 2))
			 HOURHANDSIZE 5 WINDOW)
	      (DRAWANGLE
 X Y (TIMES 6 MINUTE)
			 MINUTEHANDSIZE 3 WINDOW)
	      (RESHOWTITLE DATE WINDOW)
	      (BLOCK (ITIMES 1000 (IDIFFERENCE 60 SECONDS])

(LOGOCLOCK1

  [LAMBDA (W)                                                (* mpl "26-Jun-84 23:37")

                                                             (* creates a logo window.)

    (PROG NIL
          (SETQ W (LOGOW NIL W (DATE)
			 30))
          (DEL.PROCESS (QUOTE LOGOCLOCK.PROC))
          (PROCESSPROP (WINDOWPROP W (QUOTE PROCESS)
				   (ADD.PROCESS (LIST (FUNCTION LOGOCLOCK.PROC)
						      W 88 80 42)
						(QUOTE RESTARTABLE)
						T))
		       (QUOTE RESTARTABLE)
		       T)
          (WINDOWPROP W (QUOTE SCROLLFN)
		      (QUOTE SCROLLBYREPAINTFN))
          (WINDOWPROP W (QUOTE REPAINTFN)
		      (FUNCTION LOGOCLOCK1))
          [WINDOWADDPROP W (QUOTE CLOSEFN)
			 (FUNCTION (LAMBDA (W)
			     (DEL.PROCESS (WINDOWPROP W (QUOTE PROCESS]
          (WINDOWPROP W (QUOTE BUTTONEVENTFN)
		      (FUNCTION WAKE.LOGOCLOCK))
          (RETURN W])

(DRAWANGLE

  [LAMBDA (X Y HOURANGLE HOURHANDSIZE Z WINDOW)              (* lmm "23-JUN-83 02:32")

    (DRAWLINE X Y [PLUS X (FIXR (FTIMES HOURHANDSIZE (SIN HOURANGLE]
	      [PLUS Y (FIXR (FTIMES HOURHANDSIZE (COS HOURANGLE]
	      Z
	      (QUOTE PAINT)
	      WINDOW])

(WAKE.LOGOCLOCK

  [LAMBDA (WINDOW)                                           (* lmm " 7-JUN-83 01:31")

    (COND
      ((LASTMOUSESTATE (NOT UP))
	(WAKE.PROCESS (WINDOWPROP WINDOW (QUOTE PROCESS))
		      (QUOTE REPAINT])
)
(LOGOCLOCK LOGOW)
(PUTPROPS LOGOCLOCK COPYRIGHT ("Xerox Corporation" 1983 1984))
(DECLARE: DONTCOPY
  (FILEMAP (NIL (435 3250 (LOGOCLOCK 445 . 634) (LOGOCLOCK.PROC 636 . 1851) (LOGOCLOCK1 1853 . 2737) (
DRAWANGLE 2739 . 3017) (WAKE.LOGOCLOCK 3019 . 3248)))))
STOP