(FILECREATED " 2-MAY-83 11:01:55" {DSK}DWINDOW.LSP;1 4090   

      changes to:  (VARS DWINDOWCOMS))


(PRETTYCOMPRINT DWINDOWCOMS)

(RPAQQ DWINDOWCOMS ((GLISPOBJECTS DOLPHINREGION MENU MOUSE WINDOW)
		    (GLISPGLOBALS MOUSE)
		    (GLISPCONSTANTS WINDOWCHARWIDTH WINDOWLINEYSPACING)
		    (P (SETQ MOUSE (QUOTE MOUSE)))
		    (FNS MOUSE-POSITIONIN MOUSE-TESTBUTTON WINDOW-CENTEROFFSET WINDOW-DRAWLINE 
			 WINDOW-INVERTAREA WINDOW-MOVETO WINDOW-PRETTYPRINTAT WINDOW-PRINTAT 
			 WINDOW-UNDRAWLINE WINDOW-UNPRINTAT)))


[GLISPOBJECTS


(DOLPHINREGION

   (LIST (LEFT INTEGER)
	 (BOTTOM INTEGER)
	 (WIDTH INTEGER)
	 (HEIGHT INTEGER))

   PROP   ((START (self)
		  RESULT VECTOR)
	   (SIZE ((CDDR self))
		 RESULT VECTOR))

   SUPERS (REGION)  )

(MENU

   (RECORD MENU (ITEMS (LISTOF ATOM)))

   MSG    ((SELECT MENU RESULT ATOM))  )

(MOUSE

   ANYTHING

   MSG    ((POSITIONIN MOUSE-POSITIONIN OPEN T)
	   (TESTBUTTON MOUSE-TESTBUTTON OPEN T))  )

(WINDOW

   ANYTHING

   PROP   ((REGION ((DSPCLIPPINGREGION NIL self))
		   RESULT DOLPHINREGION)
	   (XPOSITION ((DSPXPOSITION NIL self))
		      RESULT INTEGER)
	   (YPOSITION ((DSPYPOSITION NIL self))
		      RESULT INTEGER)
	   (HEIGHT (REGION:HEIGHT))
	   (WIDTH (REGION:WIDTH))
	   (LEFT ((DSPXOFFSET NIL self))
		 RESULT INTEGER)
	   (RIGHT (LEFT + WIDTH))
	   (BOTTOM ((DSPYOFFSET NIL self))
		   RESULT INTEGER)
	   (START (REGION:START))
	   (SIZE (REGION:SIZE))
	   (LEFTMARGIN (1))
	   (RIGHTMARGIN (WIDTH - 1)))

   MSG    ((CLEAR CLEARW)
	   (OPEN OPENW)
	   (CLOSE CLOSEW)
	   (INVERTAREA WINDOW-INVERTAREA OPEN T)
	   (MOVETO WINDOW-MOVETO OPEN T)
	   (PRINTAT WINDOW-PRINTAT OPEN T)
	   (PRETTYPRINTAT WINDOW-PRETTYPRINTAT OPEN T)
	   (UNPRINTAT WINDOW-UNPRINTAT OPEN T)
	   (DRAWLINE WINDOW-DRAWLINE OPEN T)
	   (UNDRAWLINE WINDOW-UNDRAWLINE OPEN T)
	   (CENTEROFFSET WINDOW-CENTEROFFSET OPEN T))  )
]



[GLISPGLOBALS

(MOUSE   MOUSE  )
]



[GLISPCONSTANTS

(WINDOWCHARWIDTH   7   INTEGER  )

(WINDOWLINEYSPACING   12   INTEGER  )
]

(SETQ MOUSE (QUOTE MOUSE))
(DEFINEQ

(MOUSE-POSITIONIN
  (GLAMBDA (M:MOUSE W:WINDOW)                                (* GSN " 2-MAR-83 16:19")
    (GETMOUSESTATE)
    (A VECTOR WITH X =(LASTMOUSEX W)
       Y =(LASTMOUSEY W))))

(MOUSE-TESTBUTTON
  [GLAMBDA (M:MOUSE BUTTON:INTEGER)                          (* GSN " 2-MAR-83 16:19")
    (GETMOUSESTATE)
    (NOT (ZEROP (LOGAND LASTMOUSEBUTTONS BUTTON])

(WINDOW-CENTEROFFSET
  (GLAMBDA (W:WINDOW V:VECTOR)                               (* GSN " 2-FEB-83 13:57")
    (SEND W:REGION CENTEROFFSET V)))

(WINDOW-DRAWLINE
  (GLAMBDA (W:WINDOW FROM:VECTOR TO:VECTOR)                  (* GSN "28-FEB-83 16:10")
    (DRAWLINE FROM:X FROM:Y TO:X TO:Y 1 (QUOTE PAINT)
	      W)))

(WINDOW-INVERTAREA
  (GLAMBDA (W:WINDOW AREA:REGION)                            (* GSN "28-FEB-83 16:58")
    (BITBLT WINDOW AREA:LEFT AREA:BOTTOM WINDOW AREA:LEFT AREA:BOTTOM AREA:WIDTH AREA:HEIGHT
	    (QUOTE INVERT)
	    (QUOTE REPLACE)
	    NIL NIL)))

(WINDOW-MOVETO
  (GLAMBDA (W:WINDOW POS:VECTOR)                             (* GSN "13-JAN-83 15:29")
    (MOVETO POS:X POS:Y W)))

(WINDOW-PRETTYPRINTAT
  (GLAMBDA (W:WINDOW VALUE POSITION:VECTOR)                  (* GSN " 2-MAR-83 13:58")
    (MOVETO POSITION:X POSITION:Y W)
    (RESETLST (RESETSAVE SYSPRETTYFLG T)
	      (SHOWPRINT VALUE W))))

(WINDOW-PRINTAT
  (GLAMBDA (W:WINDOW S:STRING POS:VECTOR)                    (* GSN "13-JAN-83 16:25")
    (PROG (LASTWOP)
          (SEND W MOVETO POS)
          (SETQ LASTWOP (DSPOPERATION (QUOTE PAINT)
				      W))
          (PRIN1 S W)
          (DSPOPERATION LASTWOP W))))

(WINDOW-UNDRAWLINE
  (GLAMBDA (W:WINDOW FROM:VECTOR TO:VECTOR)                  (* GSN "28-FEB-83 16:11")
    (DRAWLINE FROM:X FROM:Y TO:X TO:Y 1 (QUOTE ERASE)
	      W)))

(WINDOW-UNPRINTAT
  (GLAMBDA (W:WINDOW S:STRING POS:VECTOR)                    (* GSN "13-JAN-83 16:24")
    (PROG (LASTWOP)
          (SEND W MOVETO POS)
          (SETQ LASTWOP (DSPOPERATION (QUOTE ERASE)
				      W))
          (PRIN1 S W)
          (DSPOPERATION LASTWOP W))))
)
(DECLARE: DONTCOPY
  (FILEMAP (NIL (2032 4068 (MOUSE-POSITIONIN 2042 . 2231) (MOUSE-TESTBUTTON 2233 . 2407) (
WINDOW-CENTEROFFSET 2409 . 2553) (WINDOW-DRAWLINE 2555 . 2724) (WINDOW-INVERTAREA 2726 . 2981) (
WINDOW-MOVETO 2983 . 3113) (WINDOW-PRETTYPRINTAT 3115 . 3331) (WINDOW-PRINTAT 3333 . 3611) (
WINDOW-UNDRAWLINE 3613 . 3784) (WINDOW-UNPRINTAT 3786 . 4066)))))
STOP