-- Transport Mechanism Mail Server - managing records of other servers --

-- [Indigo]<Grapevine>MS>ServerAlloc.mesa

-- Randy Gobbel		19-May-81 12:36:43 --
-- Andrew Birrell	29-Dec-81 15:34:31 --

DIRECTORY
Ascii		USING[ CR ],
BodyDefs	USING[ RName, RNameSize ],
EnquiryDefs	USING[ ],
GlassDefs	USING[ Handle ],
Inline		USING[ COPY ],
Process		USING[ InitializeMonitor ],
ServerDefs	USING[ ServerHandle, ServerData, ServerName, ServerType ],
Storage		USING[ Node, String ],
String		USING[ EquivalentStrings ];

ServerAlloc: MONITOR
   IMPORTS BodyDefs, Inline, Process, Storage, String
   EXPORTS EnquiryDefs, ServerDefs
   SHARES  ServerDefs =
BEGIN

OPEN ServerDefs;

noServer: ServerHandle = NIL;

freeChain:   ServerHandle _ noServer;
mailChain:   ServerHandle _ noServer;


CreateServer: INTERNAL PROCEDURE[ name: ServerName, type: ServerType ]
                         RETURNS[ res: ServerHandle ] =
   BEGIN
   chain: POINTER TO ServerHandle = @mailChain;
   IF freeChain = noServer
   THEN res _ Storage.Node[SIZE[ServerData]]
   ELSE BEGIN res _ freeChain; freeChain _ freeChain.next; END;
   res.next _ chain^; chain^ _ res;
   Process.InitializeMonitor[@res.LOCK];
   res.type _ type;
   WITH name SELECT FROM
      rName =>
         BEGIN --copy RName into permanent storage--
         size: CARDINAL = BodyDefs.RNameSize[value];
         place: BodyDefs.RName = Storage.Node[size];
         Inline.COPY[value, size, place];
         res.name _ [rName[place]];
--MTP--  FOR index: CARDINAL IN [0..place.length)
--MTP--  DO IF place[index] = '. THEN EXIT;
--MTP--  REPEAT --if no dot, asssume foreign--
--MTP--  FINISHED => { res.type _ foreign; res.name _ [connect[place]] }
--MTP--  ENDLOOP;
         res.addrKnown _ FALSE;
         END;
      connect =>
         BEGIN --copy connect site into permanent storage --
         place: STRING = Storage.String[value.length];
         Inline.COPY[@(value.text), (1+value.length)/2, @(place.text)];
         place.length _ value.length;
         res.name _ [connect[place]];
         res.addrKnown _ FALSE;
         END;
      netAddr =>
         BEGIN
         res.name _ [netAddr[value]];
         res.addr _ value;
         res.addrKnown _ TRUE;
         END;
   ENDCASE => ERROR;
   res.up _ TRUE;
   res.SL _ NIL;
   END;

GetServer: PUBLIC ENTRY PROCEDURE[ name: ServerName, type: ServerType ]
                              RETURNS[ res: ServerHandle ] =
   BEGIN
   FOR res _  mailChain, res.next
   UNTIL res = noServer
   DO IF (WITH wanted: name SELECT FROM
            rName =>
              (WITH found: res.name SELECT FROM
                 rName =>
                   String.EquivalentStrings[found.value, wanted.value],
--MTP--          connect =>
--MTP--            String.EquivalentStrings[found.value, wanted.value],
               ENDCASE => FALSE),
            connect =>
              (WITH found: res.name SELECT FROM
                 connect =>
                   String.EquivalentStrings[found.value, wanted.value],
               ENDCASE => FALSE),
            netAddr =>
              (WITH found: res.name SELECT FROM
                 netAddr =>
                   found.value = wanted.value,
               ENDCASE => FALSE),
          ENDCASE => ERROR)
      THEN EXIT;
   ENDLOOP;
   IF res = noServer THEN res _ CreateServer[name,type];
   END;

EnumerateAll: PUBLIC ENTRY PROCEDURE[ work: PROCEDURE[ServerHandle]] =
   BEGIN
   ENABLE UNWIND => NULL;
   FOR ptr: ServerHandle _ mailChain, ptr.next UNTIL ptr = noServer
   DO work[ptr] ENDLOOP;
   END;

RemoteServers: PUBLIC PROC[ str: GlassDefs.Handle ] =
   BEGIN
   OPEN str;
   FOR ptr: ServerHandle _ mailChain, ptr.next UNTIL ptr = noServer
   DO WriteChar[Ascii.CR];
      WriteString[ WITH this: ptr.name SELECT FROM
          rName => this.value,
          connect => this.value,
          netAddr => "[net address]"L,
        ENDCASE => "[bad name]"L ];
      WriteString[": "L];
      WriteString[IF ptr.up THEN "up"L ELSE "down"L];
      WriteString[", handle="L];
      WriteDecimal[LOOPHOLE[ptr]];
   ENDLOOP;
   END;

END.