
<<BluejaySmartsImpl.mesa>>
<<Last modified by D. Swinehart, August 4, 1984 8:05:33 pm PDT>>
<<>>
DIRECTORY
BluejaySmarts,
BluejayUtils    USING [ Initialize, Uninitialize ],
Commander    USING [ CommandProc, Register ],
IO,
Jukebox        USING [ bytesPerChirp, CloseJukebox, CreateJukebox, CloseTune, CreateTune, EOF, Error, Handle, MissingChirp, 
OpenJukebox, OpenTune, Tune, TuneSize ],
Lark            USING [ noMachine, VoiceSocket ],

Nice,

Process        USING [ Detach, MsecToTicks, Pause, SecondsToTicks, SetTimeout ],
PupDefs        USING [ MsToTocks, PupSocket, PupSocketDestroy, PupSocketMake ],
Rope,
Log            USING [ FindWhere, Problem, RegisterWhereToReport, Report, ReportFR, WhereProc ],
ThParty        USING [ Advance, CreateParty, DescribeParty, Enable, RegisterClone, SetInterval ],
Thrush        USING [ ConversationHandle, ConvEvent, Disposition, IntervalSpec, NB, newTune, nullConvHandle, nullHandle, nullTune, 
PartyHandle, Reason, ROPE, SHHH, SmartsHandle, StateInConv, Tune ],
ThSmarts,
ThSmartsPrivate USING [ ConvDesc, ConvDescBody, OpenConversations ],
UserProfile USING [ Token ],
VoiceStream    USING [ AddPiece, Close, FlushPieces, Handle, IsEmpty, NotifyProc, Open, SetSocket, wholeTune ]
;

BluejaySmartsImpl: CEDAR MONITOR
IMPORTS BluejaySmarts, BluejayUtils, Commander, IO, Jukebox, Log, Nice, Process, PupDefs, Rope, ThParty, UserProfile, VoiceStream
EXPORTS BluejaySmarts, ThSmarts  = {
OPEN IO;

<<Types, Definitions>>

ConvDesc: TYPE = ThSmartsPrivate.ConvDesc;
ConversationHandle: TYPE = Thrush.ConversationHandle;
nullConvHandle: ConversationHandle = Thrush.nullConvHandle;
Disposition: TYPE = Thrush.Disposition;
PartyHandle: TYPE = Thrush.PartyHandle;
SHHH: TYPE = Thrush.SHHH;
SmartsHandle: TYPE = Thrush.SmartsHandle;
StateInConv: TYPE = Thrush.StateInConv;
JayInfo: TYPE = BluejaySmarts.JayInfo;
JayInfoBody: TYPE = BluejaySmarts.JayInfoBody;

jayShh: PUBLIC SHHH;
interfaceIsImported: PUBLIC BOOLEAN_FALSE;
encryptionRequested: PUBLIC BOOLEAN _ TRUE;
handle: PUBLIC Jukebox.Handle;
debug: PUBLIC BOOLEAN _ TRUE;
NB: TYPE = Thrush.NB;

noActiveSocket: Lark.VoiceSocket = [
net: [Lark.noMachine.net], host: [Lark.noMachine.host], socket: [0,0]];

infos: PUBLIC ARRAY[0..100) OF BluejaySmarts.JayInfo_ALL[NIL];
smartses: PUBLIC ARRAY[0..100) OF Thrush.SmartsHandle _ ALL[Thrush.nullHandle];
numParties: PUBLIC NAT_0;
haveJuke: PUBLIC BOOL_TRUE;

timeoutNoAction: INTEGER _ 30;
Ctr: TYPE = RECORD[
count: INT,
stop: INT
];

PD: TYPE = RECORD [
cPr: REF Ctr_NEW[Ctr_[0,1000000]],
cSp: REF Ctr_NEW[Ctr_[0,1000000]],
cRs: REF Ctr_NEW[Ctr_[0,1000000]],
cZp: REF Ctr_NEW[Ctr_[0,1000000]],
cNw: REF Ctr_NEW[Ctr_[0,1000000]],
numReportDones: INT_0,
numReportDoneEs: INT_0,
doReports: BOOL_FALSE,
doNice: BOOL_FALSE
];
pd: REF PD _ NEW[PD_[]];

Report: PROC[what: ROPE, ctr: REF Ctr] = {
IF NOT pd.doReports THEN RETURN;
Log.Report[what, $Bluejay];
ctr.count_ctr.count+1;
IF ctr.count>ctr.stop THEN { Log.Problem["Report overflow", $Bluejay]; };
};

BeNice: PROC[r: REF, d: INT] = {
IF NOT pd.doNice THEN RETURN;
Nice.BeNice[r, d, $Bluejay, NIL];
};

<<Call Supervision>>

Progress: PUBLIC ENTRY PROC[
shh: SHHH,
smartsID: Thrush.SmartsHandle,
event: Thrush.ConvEvent,
yourParty: BOOL,
latestEvent: BOOL,
informationOnly: BOOL
] RETURNS [ d: Thrush.Disposition ] = {
info: JayInfo _ InfoForSmarts[smartsID: smartsID];
cDesc: ThSmartsPrivate.ConvDesc;
IF info=NIL THEN RETURN[pass];
d_actedAndStop;
<<Update local state information>>

cDesc _ GetConv[info, event.credentials.convID, FALSE];

IF pd.doReports THEN Report[
Rope.Concat[
IO.PutFR["---- JyProg: %t(%d) %g %g yr=%g ",
time[event.credentials.convID], int[event.credentials.stateID],
refAny[NEW[StateInConv_event.state]], DParty[info, cDesc], bool[yourParty]],
IO.PutFR["lt=%g in=%g, ky=%g\n",
bool[latestEvent], bool[event.intervalSpec#NIL], bool[event.keyTable#NIL]]],
pd.cPr];

IF event.credentials.stateID <= cDesc.cState.credentials.stateID THEN RETURN[pass]; -- Old news!
<<>>
<<Fields always extracted>>
cDesc.cState.credentials.smartsID _ smartsID;
cDesc.cState.credentials.stateID _ event.credentials.stateID;
<<<<Need to check for increasing stateID here, and reject old ones?  If so, enable>>
<<test in alrt case below.>>>>

<<Extracted if present>>
IF event.keyTable#NIL THEN {
cDesc.cState.keyTable _ event.keyTable; cDesc.newKeys_TRUE; };
IF event.intervalSpec#NIL AND event.intervalSpec.type=request THEN
EnqueueInterval[cDesc, event.intervalSpec];
IF event.address#NIL THEN { cDesc.cState.address_event.address; cDesc.newAddress_TRUE; };
<<>>
<<Extracted if the event changes our state. >>
IF yourParty THEN {
cDesc.descValid _ TRUE;
cDesc.cState.credentials.partyID _ event.credentials.partyID;
cDesc.cState.state _ event.state;
cDesc.cState.comment _ event.comment;
cDesc.cState.reason _ event.reason;
IF event.spec#NIL THEN { cDesc.cState.spec _ event.spec; cDesc.newSpec_TRUE; };
<<Extracted if non-standard?>>
IF event.comment#NIL THEN cDesc.cState.comment _ event.comment;
IF event.urgency#normal THEN cDesc.cState.urgency _ event.urgency;
IF event.alertKind#standard THEN cDesc.cState.alertKind _ event.alertKind;
};

BeNice[event, 4];
BeNice[cDesc, 6];
<<>>
IF latestEvent THEN Apprise[info]; -- Wait for the last report to wake process.
};

Supervise: PUBLIC ENTRY PROC[info: JayInfo ] = {
OPEN Jukebox;
TRUSTED {Process.SetTimeout[@info.thAction, Process.SecondsToTicks[timeoutNoAction]]; };
IF info.apprise THEN DO
ENABLE {
UNWIND => NULL;
Jukebox.Error, Jukebox.MissingChirp, Jukebox.EOF => {
Log.Problem["Error detected in Bluejay", $Bluejay]; GOTO Failing; };
};
prevL: ThSmartsPrivate.OpenConversations _ NIL;
nb: NB_success;
convL: ThSmartsPrivate.OpenConversations;
trans: Transition;
info.apprise _ FALSE;
FOR convL _ info.conversations,
convL.rest WHILE convL#NIL DO
cDesc: ConvDesc = convL.first;
stateNow: StateInConv = cDesc.cState.state;
ours: BOOL _ ( cDesc.cState.credentials.convID = info.currentConvID );

IF pd.doReports THEN Report[
Rope.Concat[
IO.PutFR["**** JySup: %t(%d) %g %g->%g",
time[cDesc.cState.credentials.convID], int[cDesc.cState.credentials.stateID],
DParty[info, cDesc], refAny[NEW[StateInConv_stateNow]], refAny[NEW[StateInConv_cDesc.desiredState]]],
IO.PutFR[" %g%g\n",
refAny[NEW[Transition_transForStates[stateNow][cDesc.desiredState]]],
rope[IF ours THEN " (ours)" ELSE ""]]],
pd.cSp];
BeNice[cDesc, 6];
<<>>
IF NOT cDesc.descValid THEN LOOP;
IF info.currentConvID = nullConvHandle AND stateNow#idle THEN {
<<<<This stuff feels like it's in the wrong place.  Will feel more so when multi-calls
are dealt with. >>>>
ours_TRUE; info.currentConvID _ cDesc.cState.credentials.convID;
};
IF stateNow#idle AND (NOT ours) THEN
<<Conv isn't the one we're interested in, and doesn't look like it's going idle: idle it.>>
<<Should probably consult transForStates for validity.>>
nb _ ThParty.Advance[
shhh: info.shh,
credentials: cDesc.cState.credentials,
state: idle,
reason: busy,
comment: "One conversation at a time, please."
]
ELSE {
<<State and substate (below) and desired state indicate there's something to do. Do it:>>
SELECT (trans_transForStates[stateNow][cDesc.desiredState]) FROM
noop => NULL;
elim => {
<<Conv. is now idle: forget about it or re-use it, as a reserved conversation. >>
<<Remove dead conversation from list.>>

Report[IO.PutFR["  ** Zap: %t\n", time[cDesc.cState.credentials.convID]], pd.cZp];
<<>>
IF prevL#NIL THEN { prevL.rest _ convL.rest; convL _ prevL; }
ELSE info.conversations_convL.rest;
IF ours THEN {
info.currentConvID _ nullConvHandle;
CloseConnection[info];
};
};
idle => nb _ AdvanceToDesired[info, cDesc];
actv => {
IF cDesc.signallingStarted THEN LOOP;
cDesc.signallingStarted _ TRUE;
cDesc.desiredState _ active;
nb _ AdvanceToDesired[info, cDesc];
};
nrvl => { -- report new interval accepted
IF cDesc.newSpec THEN OpenConnection[info, cDesc];
IF cDesc.newIntervals#NIL THEN {
IF DoSetInterval[info, cDesc] THEN
nb _ ThParty.SetInterval[
shhh: info.shh,
credentials: cDesc.cState.credentials,
intervalSpec: cDesc.newIntervals.first
];
IF nb=success THEN []_DequeueInterval[cDesc];
info.apprise _ TRUE; -- one more time, in case more intervals exist.
};
};
invl, ntiy => {
Log.Problem["BluejaySmarts: Invalid or not yet implemented state transition request.", $Bluejay];
info.apprise_TRUE;
cDesc.desiredState _ idle;
cDesc.desiredReason _ error;
cDesc.desiredComment _ "Invalid state transition";
};
ENDCASE => ERROR;
};
<<Analyze any results of trying to reach a different state.>>

IF nb#success THEN
Report[IO.PutFR["  ** Results: nb=%g\n", refAny[NEW[Thrush.NB_nb]]], pd.cRs];
<<>>
SELECT nb FROM
success, stateMismatch => NULL;
partyNotEnabled => ours_FALSE;
invalidTransition, convNotActive, convStillActive => {
<<Complain and transition to idle>>
comment: ROPE="Bluejay: Party-level detected invalid state transition request";
Log.Problem[comment, $Bluejay];
cDesc.desiredState _ idle;
cDesc.cState.comment _ comment;
cDesc.cState.reason _ error;
info.apprise_TRUE;
};
notInConv, noSuchConv => { -- Complain, zap, go idle and repeat.
comment: ROPE="Bluejay: NotInConv or NoSuchConv";
Log.Problem[comment, $Bluejay];
IF ours THEN info.currentConvID _ nullConvHandle;
cDesc.cState.credentials.convID _ nullConvHandle;
cDesc.cState.credentials.stateID _ 0;
cDesc.desiredState _ idle;
cDesc.cState.comment _ comment;
cDesc.cState.reason _ error;
info.apprise_TRUE;
};
noSuchParty, noSuchSmarts => { -- Complain, deregister, we gone! Needs tuning.
Log.Problem[
"Bluejay: NoSuchParty or NoSuchSmarts reported, must try to go away", $Bluejay];
GOTO Failing;
};
noSuchParty2, narcissism => ERROR; -- shouldn't be provoking these
ENDCASE => ERROR;
prevL _ convL;
ENDLOOP;
IF NOT info.apprise THEN WAIT info.thAction;
IF info.conversations = NIL THEN EXIT;
REPEAT Failing => NULL; -- ThSmartsPrivate.Deregister[info]; now Failed
ENDLOOP;
info.thProcess _ NIL;
};

<<Utilities>>
<<>>
GetConv: PUBLIC INTERNAL PROC[info: JayInfo, convID: ConversationHandle, validIfNew: BOOL
] RETURNS [ cDesc: ConvDesc_NIL ] = --INLINE-- {
FOR convs: ThSmartsPrivate.OpenConversations _ info.conversations, convs.rest WHILE convs#NIL DO
IF convs.first.cState.credentials.convID = convID THEN RETURN[convs.first];
ENDLOOP;
cDesc _ NEW[ThSmartsPrivate.ConvDescBody_[]];
cDesc.descValid _ validIfNew;
cDesc.cState.credentials.convID _ convID;
cDesc.cState.credentials.smartsID _ info.smartsID;
cDesc.cState.credentials.partyID _ info.partyID;
info.conversations _ CONS[cDesc, info.conversations];

IF pd.doReports THEN
Report[IO.PutFR["  ** NewConv, %t %g, vl=%g\n", time[convID], DParty[info, cDesc], bool[validIfNew]], pd.cNw];
<<>>
};

GetCDesc: PROC[info: JayInfo] RETURNS [ cDesc: ConvDesc_NIL ] = {
<<Not at present protected by monitor -- LarkStateImpl back-pointer problem.>>
convID: ConversationHandle=info.currentConvID;
IF convID=nullConvHandle THEN RETURN;
FOR convs: ThSmartsPrivate.OpenConversations _ info.conversations, convs.rest WHILE convs#NIL DO
IF convs.first.cState.credentials.convID = convID THEN {
cDesc _ convs.first; EXIT; };
ENDLOOP;
RETURN[IF cDesc#NIL AND cDesc.descValid THEN cDesc ELSE NIL];
};

EnqueueInterval: INTERNAL PROC[cDesc: ConvDesc, int: Thrush.IntervalSpec] =  INLINE {
iL: LIST OF Thrush.IntervalSpec = LIST[int];
IF cDesc.newIntervals#NIL THEN cDesc.iTail.rest _ iL ELSE cDesc.newIntervals _ iL;
cDesc.iTail _ iL;
};

DequeueInterval: INTERNAL PROC[cDesc: ConvDesc] RETURNS [ int: Thrush.IntervalSpec_NIL ] =  INLINE {
IF cDesc.newIntervals=NIL THEN RETURN;
int_cDesc.newIntervals.first;
cDesc.newIntervals _ cDesc.newIntervals.rest;
};

GetSIC: PUBLIC INTERNAL PROC[info: JayInfo] RETURNS [ state: StateInConv ] = {
cDesc: ConvDesc = GetCDesc[info];
RETURN[IF cDesc=NIL THEN idle ELSE cDesc.cState.state];
};

Apprise: PUBLIC INTERNAL PROC[info: JayInfo] = TRUSTED --INLINE-- {
IF info.thProcess=NIL THEN
Process.Detach[info.thProcess _ FORK Supervise[info]];
info.apprise _ TRUE;
NOTIFY info.thAction;
};

AdvanceToDesired: INTERNAL PROC[info: JayInfo, cDesc: ConvDesc] RETURNS [nb: NB] = {
RETURN[nb _ ThParty.Advance[
shhh: info.shh,
credentials: cDesc.cState.credentials,
state: cDesc.desiredState,
reason: cDesc.desiredReason,
comment: cDesc.desiredComment
]];
};

InfoForSmarts: INTERNAL PROC [ smartsID: SmartsHandle ] RETURNS [ info: JayInfo ] = {
FOR i: NAT IN [0..numParties) DO IF smartsID=smartses[i] THEN RETURN [ infos[i] ]; ENDLOOP;
RETURN[ NIL ]; };

OpenConnection: INTERNAL PROC[info: JayInfo, cDesc: ConvDesc] = TRUSTED {
IF NOT cDesc.newSpec THEN RETURN;
IF info.stream=NIL THEN info.stream _ VoiceStream.Open[jukebox: handle, proc: ReportDone, clientData: info];
Log.ReportFR["C %d ", $Bluejay, NIL, card[info.smartsID]];
info.socket _ PupDefs.PupSocketMake[
local: cDesc.cState.spec.localSocket.socket,
remote: cDesc.cState.spec.remoteSocket,
ticks: PupDefs.MsToTocks[100]];
VoiceStream.SetSocket[socket: info.socket, handle: info.stream];
info.lastIntervalSpec _ NIL;
cDesc.newSpec _ FALSE;
};

CloseConnection: INTERNAL PROC[info: JayInfo] = TRUSTED {
IF info.stream#NIL THEN VoiceStream.Close[info.stream];
info.stream _ NIL;
IF info.socket#NIL THEN PupDefs.PupSocketDestroy[info.socket];
info.lastIntervalSpec _ NIL;
Log.ReportFR["D %d ", $Bluejay, NIL, card[info.smartsID]];
};

<<Tunes: control of recording and playback>>

DoSetInterval: INTERNAL PROC[info: JayInfo, cDesc: ConvDesc] 
RETURNS[didSomething: BOOL] = TRUSTED {
jTune: Jukebox.Tune;
intervalSpec: Thrush.IntervalSpec = cDesc.newIntervals.first;
tune: Thrush.Tune;
flush: BOOL;
IF intervalSpec=NIL THEN ERROR;
flush _ intervalSpec.interval.length=0 AND (NOT intervalSpec.queueIt);
tune _ intervalSpec.tune;
SELECT intervalSpec.type FROM
request => NULL; -- Let's go start it.
started => RETURN[TRUE]; -- was started before, but not successfully reported (mismatch?)
finished => RETURN[NOT flush]; -- report unless due to flushing (does this happen?)
ENDCASE => ERROR;
IF info.stream=NIL THEN info.stream _ VoiceStream.Open[jukebox: handle, proc: ReportDone, clientData: info];
IF flush THEN {
VoiceStream.FlushPieces[handle: info.stream];
RETURN[FALSE]; -- no report
};
IF tune = Thrush.newTune THEN
IF intervalSpec.direction = record THEN {
jTune _ Jukebox.CreateTune[handle, -1];
tune _ jTune.tuneId;
intervalSpec.tune_tune;
Jukebox.CloseTune[ handle, jTune ]; }
ELSE RETURN[TRUE]--<<??>>--;
IF intervalSpec.direction = play THEN Process.Pause[Process.MsecToTicks[100]];
VoiceStream.AddPiece[
handle: info.stream,
tuneId: tune,
firstByte: intervalSpec.interval.start,
nBytes: IF intervalSpec.interval.length=-1 THEN VoiceStream.wholeTune
ELSE intervalSpec.interval.length,
create: intervalSpec.direction = record,
playback: intervalSpec.direction # record,
keyIndex: intervalSpec.keyIndex,
flush: NOT intervalSpec.queueIt ];
intervalSpec.type _ started;
info.lastIntervalSpec _ intervalSpec;
RETURN[TRUE];
<<<< Perhaps should be able to specify, in request, whether started/finished notes are needed.>>>>
};

ReportDone: VoiceStream.NotifyProc = TRUSTED {
info: JayInfo _ NARROW[clientData];
pd.numReportDones _ pd.numReportDones+1;
IF ~VoiceStream.IsEmpty[self] OR info=NIL THEN RETURN;
Process.Detach[FORK ReportDoneEntry[info]];
};

 ReportDoneEntry: ENTRY PROC[info: JayInfo] = TRUSTED {
cDesc: ConvDesc;
intervalSpec: Thrush.IntervalSpec;
tune: Thrush.Tune_Thrush.nullTune;
totLen, start: INT_0;
jTune: Jukebox.Tune_NIL;
pd.numReportDoneEs _ pd.numReportDoneEs+1;
cDesc _ GetCDesc[info];
IF cDesc=NIL OR cDesc.cState.state#active THEN RETURN;
intervalSpec _ info.lastIntervalSpec;
IF intervalSpec = NIL THEN { Log.Problem["Bluejay: No interval spec.", $Bluejay]; RETURN; };
<<<<Need list of specs, else multiple requests can confuse this!!!!!>>>>
tune _ intervalSpec.tune;
IF tune>=0 THEN jTune _ Jukebox.OpenTune[handle, tune, FALSE];
IF jTune#NIL THEN {
totLen _ Jukebox.TuneSize[jTune]*Jukebox.bytesPerChirp;
Jukebox.CloseTune[handle, jTune];
start _ MIN[intervalSpec.interval.start, totLen];
intervalSpec.interval _ [start: start, length: MAX[totLen-start, 0]];
};
intervalSpec.type _ finished;
info.lastIntervalSpec _ NIL;
EnqueueInterval[cDesc, intervalSpec]; -- Notify client
Apprise[info];
};

DParty: PROC[info: JayInfo, cDesc: ConvDesc] RETURNS [IO.Value] = {
RETURN[rope[ThParty.DescribeParty[shh: info.shh, partyID: cDesc.cState.credentials.partyID]]];
};

<<Initialization>>

InitJay: PROC[ numTrunks: NAT ] = {
partyID: Thrush.PartyHandle;
smartsID: Thrush.SmartsHandle;
clonePartyID: Thrush.PartyHandle;
jukeboxName: Thrush.ROPE =
UserProfile.Token[key: "BluejayJukeboxName", default: "///Morley/Morley.Jukebox"];

info: BluejaySmarts.JayInfo;

<<Initialize anything that has to be set up on the Jay side.>>
<<>>
BluejaySmarts.haveJuke_TRUE;
TRUSTED {
BluejaySmarts.handle _ Jukebox.OpenJukebox[name: jukeboxName!
Jukebox.Error => IF reason= NoJukebox THEN {
BluejaySmarts.haveJuke_FALSE; CONTINUE; }];
IF ~BluejaySmarts.haveJuke THEN {
Jukebox.CreateJukebox[jukeboxName, 5000, 100];
BluejaySmarts.handle _ Jukebox.OpenJukebox[jukeboxName];
};
};
BluejaySmarts.haveJuke_TRUE;
Log.RegisterWhereToReport[ReportBluejay, $Bluejay];
<<>>
<<Export/Import interfaces, create first Jay party and smarts.>>
<<>>
[partyID, smartsID] _ BluejaySmarts.BluejayRegister[];
IF partyID=Thrush.nullHandle OR smartsID=Thrush.nullHandle THEN GOTO InitFailed;

Log.Report["Bluejay Smarts Initialized and Exported, ThParty Imported", $Bluejay];
TRUSTED { BluejayUtils.Initialize[]; };
<<>>
<<Get Jay Parties>>
FOR i: NAT IN [0..numTrunks) DO
IF i#0 THEN {
partyID_ThParty.CreateParty[type: recording, rName: NIL];
IF partyID=Thrush.nullHandle THEN ERROR;
smartsID _ ThParty.RegisterClone[
shh: BluejaySmarts.jayShh, partyID: partyID, clonePartyID: clonePartyID];
}
ELSE clonePartyID _ partyID;
IF smartsID=Thrush.nullHandle THEN ERROR; -- <<try to delete the Party?>>
IF ThParty.Enable[shh: BluejaySmarts.jayShh, smartsID: smartsID]#success THEN ERROR; -- <<!!!!!!!!!>> --
info_NEW[JayInfoBody _ [smartsID: smartsID, partyID: partyID, shh: BluejaySmarts.jayShh]];
BluejaySmarts.infos[BluejaySmarts.numParties]_info;
BluejaySmarts.smartses[BluejaySmarts.numParties]_smartsID;
BluejaySmarts.numParties_BluejaySmarts.numParties+1;
ENDLOOP;
EXITS
InitFailed => TRUSTED {
Log.Problem["Bluejay: initialization failed", $Bluejay];
BluejayUtils.Uninitialize[];
IF BluejaySmarts.haveJuke THEN BluejaySmarts.handle _ Jukebox.CloseJukebox[BluejaySmarts.handle!
Jukebox.Error, Jukebox.MissingChirp, Jukebox.EOF=>CONTINUE];
BluejaySmarts.jayShh_NIL;
};
};

ReportBluejay: Log.WhereProc = TRUSTED {
s_Log.FindWhere[$System, NIL];
};
<<>>
<<State Transition Tables>>

Transition: TYPE = {
<<Just codes to dispatch on in Supervisor; explained there>>
noop, elim, idle, actv, nrvl, invl, ntiy
};

transForStates: ARRAY StateInConv OF ARRAY StateInConv OF Transition _ [
<<  idle  resrv  pars    init pend mayb ring canAc   activ inact   any -- desired>>
<<>>
[ elim, invl, invl,    invl, invl, invl, invl, invl,   elim, ntiy,   elim ], -- idle     (current)
[ idle, invl, invl,    invl, invl, invl, invl, invl,   invl, ntiy,    invl ], -- reserved
[ idle, invl, invl,    invl, invl, invl, invl, invl,   invl, ntiy,    invl ], -- parsing
[ idle, invl, invl,    invl, invl, invl, invl, invl,   invl, ntiy,   invl ], -- initiating

[ idle, invl, invl,    invl, invl, invl, invl, invl,   actv, ntiy,    actv ], -- pending
[ idle, invl, invl,    invl, invl, invl, invl, invl,   invl, ntiy,   invl ], -- maybe
[ idle, invl, invl,    invl, invl, invl, invl, invl,   invl, ntiy,    invl ], -- ringing
[ idle, invl, invl,    invl, invl, invl, invl, invl,   ntiy, ntiy,    ntiy ], -- canActivate

[ idle, invl, invl,    invl, invl, invl, invl, invl,   nrvl, ntiy,   nrvl ], -- active
[ idle, invl, invl,    invl, invl, invl, invl, invl,   ntiy, ntiy,    noop ], -- inactive
[ invl, invl, invl,   invl, invl, invl, invl, invl,   invl, invl,    invl ] -- any (nonex)
];
<<NB: examine relationship to validity table in PartyOpsImpl someday.>>

<<Debugging nonsense>>
JayCmd: Commander.CommandProc = TRUSTED { InitJay[5]; };

Commander.Register["Jay", JayCmd, "Start Bluejay server"];
Nice.View[pd, "Bluejay PD"];

}.