-- File: [Indigo]<Sakura>Dragon>DragonProcessorImpl2.sak
-- Dragon processor with random fetch
--  8-Mar-82 12:37:45

DIRECTORY
  DragonCache,
  DragonProcessor,
  RandomCard,
  SakuraRT,
  SimIO;
  
DragonProcessorImpl2: MONITOR
  IMPORTS RandomCard, SakuraRT, SimIO 
  EXPORTS DragonProcessor = {

  Processor: PUBLIC DEVICE = {
    IN ClockA, ClockB, Fault, Reject: BOOLEAN, InData: DragonCache.PbusType
    OUT Op: DragonCache.PbusOp, RQ: BOOLEAN, OutData: DragonCache.PbusType
    GUARDIAN {}
    CONTROL {
      Fetch: PROC [loc: CARDINAL]= {
        vp: LONG CARDINAL;
	bl: [0..37B];
	word: [0..3];
	printval: LONG CARDINAL;
	[vp, bl, word] _ SplitAddress[loc];
	printval _ word+bl*4+vp*128;
	WHEN ClockB UP: {
	  RQ _ TRUE;
	  Op _ Fetch;
	  OutData _ [Instruction[vp, bl, word]]};
	DO
	  WHEN ClockA UP: IF ~Reject THEN EXIT;
	  ENDLOOP;
	SimIO.WF1["  Fetch started %ld*n", @printval];
	WHEN ClockB UP: RQ _ FALSE;
	SimIO.WF1["  Fetch finished %ld*n", @printval]};
      
      FetchAndRead: PROC [loc, prevloc: CARDINAL] = {
        vp: LONG CARDINAL;
	bl: [0..37B];
	word: [0..3];
	printval: LONG CARDINAL;
	data: LONG CARDINAL;
	[vp, bl, word] _ SplitAddress[loc];
	printval _ word+bl*4+vp*128;
	data _ 37777777777B - prevloc;
	RQ _ TRUE;
	Op _ Fetch;
	OutData _ [Instruction[vp, bl, word]];
	DO
	  WHEN ClockA UP: IF ~Reject THEN EXIT;
	  ENDLOOP;
	SimIO.WF1["  Fetch started %ld*n", @printval];
	WHEN ClockB UP: {
	  SakuraRT.Delay[30];
	  WITH b: InData SELECT FROM
	    Data => IF data # b.data THEN ERROR;
	    ENDCASE => ERROR;
	  RQ _ FALSE};
	SimIO.WF1["  Fetch finished %ld*n", @printval]};
      
      Read: PROC [prevloc: CARDINAL] = {
	data: LONG CARDINAL;
	data _ 37777777777B - prevloc;
	DO
	  WHEN ClockA UP: IF ~Reject THEN EXIT;
	  ENDLOOP;
	WHEN ClockB UP: SakuraRT.Delay[30];
	WITH b: InData SELECT FROM
	    Data => IF data # b.data THEN ERROR;
	    ENDCASE => ERROR};
      
      SplitAddress: PROC [loc: CARDINAL] RETURNS [vp: LONG CARDINAL, 
        bl: [0..37B], word: [0..3]] = {
	word _ loc MOD 4;
	loc _ loc / 4;
	bl _ loc MOD 40B;
	vp _ loc / 40B};
	  
      loc, prevloc: CARDINAL;
      
      RQ _ FALSE;
      WHEN ClockB UP: NULL;
      WHEN ClockB UP: NULL;
      [ ] _ RandomCard.InitRandom[-1];
      prevloc _ RandomCard.Choose[0,2000];
      Fetch[prevloc];
      THROUGH [0..300] DO
        loc _ RandomCard.Choose[0,2000];
	FetchAndRead[loc, prevloc];
	prevloc _ loc;
	ENDLOOP;
      Read[prevloc];
      SimIO.WF0["++++++++++++++++++++++++++++++++++++++++++++++++++++++++++"];
      }
    };
    
  }.