-- Copyright (C) 1985  by Xerox Corporation. All rights reserved. 
-- ThinTTYTajo.config, HGM,  6-Jan-85  6:21:16

TTYTajo: CONFIGURATION
  IMPORTS
    Auth, CH, NSString,
    AddressTranslation, BeepFace, Courier,  
    DisplayFace, EthernetFace, FileTransfer,
    HeadStartChain, Heap, KeyboardFace, MouseFace,
    PilotDiskFace, ProcessorFace, PupDefs, PupStream, 
    RealMemory, RuntimeInternal, SA800Face, TajoMisc, TemporarySetGMT,
    TIP, TIPTable, TTYPortFace
  EXPORTS ALL =
  BEGIN
  
  HideIntExpRecs: CONFIG 
    IMPORTS 
      BeepFace, DisplayFace, HeadStartChain, Heap, KeyboardFace, KernelPrograms,
      MouseFace, PilotDiskFace, ProcessorFace,  RealMemory, 
      RuntimeInternal, SA800Face,
      TemporarySetGMT, Event, MDirectory, Supervisor, 
      RuntimePrograms, CommunicationPrograms, PilotClient
    EXPORTS 
      ByteBlt, File, FileExtras, FloppyChannel, ObjAlloc,
      PhysicalVolume, Process, Runtime,
      Scavenger, Space, Stream, System, TemporaryBooting,
      UserTerminal, UserTerminalExtras, Volume, VolumeConversion, Zone,
      DebuggerSwap, DeviceCleanup, DeviceError, DiskChannel,
      MVolume, MVolumeExtras, DiskScheduler, ResidentHeap,
      Snapshot, SpecialBooting, SpecialFile, SpecialRuntime, SpecialSpace,
      SpecialSystem, SpecialVolume,
      VM, ZoneInternal, DiskDriversPerf, FileBasicsPerf, FileMgrPerf,
      ResMemPerf, SpacePerf, VMPerf, KernelFile, LoadState, RuntimeInternal,
      SpaceCheckDefs = 
    BEGIN
      
    [ByteBlt, File, FileExtras, FloppyChannel, ObjAlloc,
      PhysicalVolume, Process, Runtime,
      Scavenger, Space1, Stream, System, TemporaryBooting,
      UserTerminal1, UserTerminalExtras, Volume1, VolumeConversion, Zone,
      DebuggerSwap, DeviceCleanup, DeviceError, DiskChannel, DiskScheduler,
      ResidentHeap, Snapshot, SpecialBooting, SpecialFile, SpecialRuntime,
      SpecialSpace, SpecialSystem, SpecialVolume1,
      VM, ZoneInternal, DiskDriversPerf, FileBasicsPerf,
      FileMgrPerf, ResMemPerf, SpacePerf, VMPerf, KernelFile, LoadState,
      RuntimeInternal] ¬ PilotKernel[];
    
    [Space2, SpaceCheckDefs] ¬ SpaceCheckPack[Runtime, Space1, System];
    Space ¬ Space2 THEN Space1;
    
    [MVolume, MVolumeExtras, SpecialVolume2, Volume2] ¬ MVolumeImpl[
      Event, MDirectory, SpecialVolume1, Supervisor, Volume1];
    SpecialVolume ¬ SpecialVolume2 THEN SpecialVolume1;
    Volume ¬ Volume2 THEN Volume1;
    
    UserTerminal2 ¬ DummyUserTerminal[];
    UserTerminal ¬ UserTerminal2 THEN UserTerminal1;
    
    END;
  
  HideIntExpRecs;
  
  Loader;
  Communication;
  SupervisorImpl;

  DumbTTYImpl;
  
  ThinSimpleSubTajo;
  SimpleTajoControl;
  VersionImpl;
    
  END..