-- File: PupRouterCool.Mesa,  Last Edit: HGM  July 15, 1979  9:35 PM
-- This section of code is mostly used when creating/destroying sockets

-- Copyright  Xerox Corporation 1979, 1980

DIRECTORY
  CommUtilDefs: FROM "CommUtilDefs" USING [InitializeCondition, GetTicks],
  PupRouterDefs: FROM "PupRouterDefs" USING [
    routerLock, BeSurePupIsOn,
    pupRoutingTable, PupRoutingTableEntry,
    firstSocket, PupRouterSocket],
  DriverDefs: FROM "DriverDefs" USING [doDebug, Network, GetDeviceChain],
  PupDefs: FROM "PupDefs", -- EXPORTS
  BufferDefs: FROM "BufferDefs" USING [QueueInitialize, QueueCleanup],
  PupTypes: FROM "PupTypes" USING [
    fillInNetID, fillInHostID, fillInSocketID,
    PupAddress, PupNetID, PupSocketID, Pair];

PupRouterCool: MONITOR LOCKS PupRouterDefs.routerLock
  IMPORTS CommUtilDefs, DriverDefs, PupRouterDefs, BufferDefs
  EXPORTS PupDefs, PupRouterDefs =
PUBLIC BEGIN OPEN PupTypes, PupRouterDefs;

spareSocket: CARDINAL _ 1000B;
nextConnectionID: CARDINAL _ 1000;

UniqueLocalPupSocketID: PUBLIC ENTRY PROCEDURE RETURNS [socket: PupSocketID] =
  BEGIN
  IF (spareSocket_spareSocket+1)=0 THEN spareSocket_1000B;
  socket _ [CommUtilDefs.GetTicks[],spareSocket];
  END;

UniqueLocalPupAddress: PUBLIC PROCEDURE [him: POINTER TO PupAddress]  RETURNS [me: PupAddress] =
  BEGIN
  RETURN[GetLocalPupAddress[PupTypes.fillInSocketID,him]];
  END;

NextPupConnectionID: PUBLIC ENTRY PROCEDURE RETURNS [p: PupTypes.Pair] =
  BEGIN
  p.a _ CommUtilDefs.GetTicks[];
  p.b _ nextConnectionID _ nextConnectionID+1;
  END;

GetLocalPupAddress: PUBLIC PROCEDURE [local: PupSocketID, remote: POINTER TO PupAddress] RETURNS [me: PupAddress] =
  BEGIN
  destNet: CARDINAL _ 0;
  routing: DESCRIPTOR FOR ARRAY OF PupRoutingTableEntry _ GetPupRoutingTable[];
  network: DriverDefs.Network _ NIL;
  IF remote#NIL THEN
    BEGIN OPEN PupTypes;
    destNet _ remote.net;
    -- Maybe we should scan for the right net if he specifies a host?
    IF remote.net=fillInNetID OR remote.host=fillInHostID THEN destNet _ 0;
    END;
  IF destNet<LENGTH[routing] THEN network _ routing[destNet].network;
  IF network=NIL THEN network _ DriverDefs.GetDeviceChain[];
  me.net _ [network.netNumber];
  me.host _ [network.hostNumber];
  me.socket _ IF local#PupTypes.fillInSocketID THEN local ELSE UniqueLocalPupSocketID[];
  IF remote#NIL THEN
    BEGIN OPEN PupTypes;
    IF remote.net=fillInNetID THEN
      remote.net _ IF network#NIL THEN [network.netNumber] ELSE me.net;
    IF remote.host=fillInHostID THEN
      remote.host _ IF network#NIL THEN [network.hostNumber] ELSE me.host;
    IF remote.socket=fillInSocketID THEN remote.socket _ me.socket;
    END;
  END;

PupRouterKnowAboutSocket: PUBLIC ENTRY PROCEDURE [so: PupRouterSocket] =
  BEGIN
  IF DriverDefs.doDebug THEN BeSurePupIsOn[];
  CommUtilDefs.InitializeCondition[@so.ready,0];
  BufferDefs.QueueInitialize[@so.input];
  so.next _ firstSocket;
  firstSocket _ so;
  END;

PupRouterForgetAboutSocket: PUBLIC ENTRY PROCEDURE [so: PupRouterSocket] =
  BEGIN
  previous: PupRouterSocket;
  IF DriverDefs.doDebug THEN BeSurePupIsOn[];
  IF firstSocket=so THEN firstSocket _ so.next
  ELSE FOR previous_firstSocket,previous.next UNTIL previous=NIL DO
    IF previous.next=so THEN
      BEGIN previous.next _ so.next; EXIT; END;
    ENDLOOP;
  BufferDefs.QueueCleanup[@so.input];
  END;

GetPupRoutingTable: PROCEDURE RETURNS [
    DESCRIPTOR FOR ARRAY OF PupRoutingTableEntry ] =
  BEGIN
  BeSurePupIsOn[];
  RETURN[pupRoutingTable];
  END;

GetFirstPupSocket: PROCEDURE RETURNS [PupRouterSocket] =
  BEGIN
  BeSurePupIsOn[];
  RETURN[firstSocket];
  END;

GetHopsToNetwork: PROCEDURE [net: PupTypes.PupNetID] RETURNS [CARDINAL] =
  BEGIN
  routing: DESCRIPTOR FOR ARRAY OF PupRoutingTableEntry _ GetPupRoutingTable[];
  BeSurePupIsOn[];
  IF net ~IN [0..LENGTH[routing]) THEN RETURN [LAST[CARDINAL]];
  RETURN[routing[net].hop];
  END;

END.(2048)\272t10 1t0 16t10 19t0 387b13B249b22B182b21B18t10 30t0 45t10 18t0 40b19B150t10b18t0B18t10 52t0 119t10 20t0 480t10 5t0 30t10 5t0 179t10 1t0 110t10 1t0 92b24B86t10 13t0 147b26B115t10 13t0 255t10b18B50t0 20t10 5t0 10t10 13t0 39b17B50t10 13t0 35b16B124t10 20t0 4t10 13t0