-- StreamDefsImpl.mesa
-- Updated for Pilot Martin Newell 23-Jul-81 14:02:05
-- Last changed by Doug Wyatt, 13-Oct-81 17:46:21

DIRECTORY
  DCSFileTypes USING [tLeaderPage],
  Directory USING [CreateFile, Error, Lookup],
  File USING [Capability, grow, LimitPermissions, Permissions, read, shrink, write],
  FileStream USING [Create, EndOf, SetIndex],
  Heap USING [systemZone],
  Inline USING [BITAND, BITOR],
  Stream USING [Delete, GetChar, GetWord, Handle, PutChar, PutWord],
  StreamDefs USING [AccessOptions, Append, Read, StreamErrorCode,
    StreamHandle, StreamObject, Write];

StreamDefsImpl: PROGRAM
IMPORTS Directory, File, FileStream, Heap, Inline, Stream
EXPORTS StreamDefs = {
OPEN StreamDefs;

zone: UNCOUNTED ZONE = Heap.systemZone;

StreamError: PUBLIC SIGNAL[stream: StreamHandle, error: StreamErrorCode] = CODE;
FileNameError: PUBLIC SIGNAL[name: LONG STRING] = CODE;

IsSet: PROC[a,b: UNSPECIFIED] RETURNS[BOOLEAN] = INLINE {
  RETURN[Inline.BITAND[a,b]#0] };
Set: PROC[p: POINTER TO UNSPECIFIED, b: UNSPECIFIED] = INLINE {
  p^ _ Inline.BITOR[p^,b] };

NewByteStream: PUBLIC PROC[name: LONG STRING, access: AccessOptions]
  RETURNS [StreamHandle] = { OPEN File;
  data: Data _ NIL;
  s: StreamHandle _ NIL;
  permissions: Permissions _ 0;
  IF IsSet[access,Read] THEN Set[@permissions,read];
  IF IsSet[access,Write] THEN Set[@permissions,write+shrink];
  IF IsSet[access,Append] THEN Set[@permissions,write+grow];
  IF permissions=0 THEN permissions _ read;
  data _ NewStream[name,permissions];
  s _ zone.NEW[StreamObject _ [reset: FileReset, get: FileGetChar,
    putback: FilePutback, put: FilePutChar, endof: FileEndof, destroy: FileDestroy,
    data: data]];
  RETURN[s];
  };

NewWordStream: PUBLIC PROC[name: LONG STRING, access: AccessOptions]
  RETURNS [StreamHandle] = {
  s: StreamHandle _ NewByteStream[name,access];
  s.get _ FileGetWord; s.put _ FilePutWord;
  RETURN[s];
  };

Data: TYPE = LONG POINTER TO FileStreamData;
FileStreamData: TYPE = RECORD[file: Stream.Handle];

NewStream: PROC[name: LONG STRING, access: File.Permissions]
  RETURNS[Data] = {
  cap: File.Capability;
  new: BOOLEAN _ FALSE;
  cap _ Directory.Lookup[fileName: name, permissions: access !
    Directory.Error => SELECT type FROM
      fileNotFound => { new _ TRUE; CONTINUE };
      invalidFileName => GOTO NotFound;
      ENDCASE];
  IF new THEN {
    IF IsSet[access,File.read] THEN GOTO NotFound;
    cap _ Directory.CreateFile[fileName: name,
      fileType: DCSFileTypes.tLeaderPage, size: 0];
    cap _ File.LimitPermissions[cap,access];
    };
  RETURN[zone.NEW[FileStreamData _ [FileStream.Create[cap]]]];
  EXITS NotFound => ERROR FileNameError[name];
  };

-- File Stream Procedures

  FileReset: PROC[s: StreamHandle] = {
    data: Data _ s.data;
    FileStream.SetIndex[data.file,0];
    };
  
  FileGetChar: PROC[s: StreamHandle] RETURNS [CHARACTER] = {
    data: Data _ s.data;
    RETURN[Stream.GetChar[data.file]];
    };
  
  FileGetWord: PROC[s: StreamHandle] RETURNS [WORD] = {
    data: Data _ s.data;
    RETURN[Stream.GetWord[data.file]];
    };
  
  FilePutback: PROC[s: StreamHandle, c: CHARACTER] = {
    ERROR StreamError[s,StreamOperation];
    };
  
  FilePutChar: PROC[s: StreamHandle, c: CHARACTER] = {
    data: Data _ s.data;
    Stream.PutChar[data.file, c];
    };
  
  FilePutWord: PROC[s: StreamHandle, w: WORD] = {
    data: Data _ s.data;
    Stream.PutWord[data.file, w];
    };
  
  FileEndof: PROC[s: StreamHandle] RETURNS [BOOLEAN] = {
    data: Data _ s.data;
    RETURN[FileStream.EndOf[data.file]];
    };
  
  FileDestroy: PROC[s: StreamHandle] = {
    data: Data _ s.data;
    Stream.Delete[data.file];
    zone.FREE[@data];
    zone.FREE[@s];
    };

}.