-- compiler FigureOps/n
--m.stone November 6, 1980  11:03 AM
--Tiberi November 19, 1979  5:48 PM

DIRECTORY
	GriffinDefs: FROM "GriffinDefs",
	GriffinStartDefs: FROM "GriffinStartDefs",
	MenuDefs: FROM "MenuDefs",
	PointDefs: FROM "PointDefs",
	ObjectDefs: FROM "ObjectDefs",
	ImageDefs: FROM "ImageDefs",
	GriffinFileDefs: FROM "GriffinFileDefs",
	AltoDisplay: FROM "AltoDisplay",
	DirectoryDefs: FROM "DirectoryDefs"
		USING [EnumerateDirectory],
	RefreshDefs: FROM "RefreshDefs",
	ScreenDefs: FROM "ScreenDefs";

FigureOps: PROGRAM
	IMPORTS GriffinDefs, MenuDefs, ScreenDefs, ObjectDefs,
		GriffinFileDefs, DirectoryDefs,RefreshDefs
	EXPORTS GriffinDefs, GriffinStartDefs = 
BEGIN
gridX: INTEGER _ 8; gridY: INTEGER _ 8;
gridOn: BOOLEAN _ FALSE;
X: CARDINAL = PointDefs.X;
Y: CARDINAL = PointDefs.Y;


Refresh: MenuDefs.MenuProc =
BEGIN
ScreenDefs.ClearScreen[];
ObjectDefs.ReplotAllObjects[];
END;

Press: MenuDefs.MenuProc =
BEGIN OPEN ObjectDefs,AltoDisplay;
name: STRING;
newfile: BOOLEAN;
[name,newfile] _ GetName[];
IF name.length=0 THEN RETURN;
ExpungeObjects[];
ObjectDefs.PressAllObjects[name];
END;

saveFileName: STRING;

Save: MenuDefs.MenuProc =
BEGIN OPEN ObjectDefs;
newfile: BOOLEAN;
[saveFileName,newfile] _ GetName[];
IF saveFileName.length=0 THEN RETURN;
IF newfile THEN BEGIN
	ExpungeObjects[];
	[] _ GriffinFileDefs.OpenPortfolio [saveFileName, TRUE];
	[] _ GriffinFileDefs.AddFigure [1];
	GriffinFileDefs.ClosePortfolio;
	END
ELSE {MenuDefs.ShowMenu[filewriteMenu]; RefreshDefs.RestoreScreen[]};
END;

YesFile: MenuDefs.MenuProc =
BEGIN
ObjectDefs.ExpungeObjects[];
[] _ GriffinFileDefs.OpenPortfolio [saveFileName, TRUE];
[] _ GriffinFileDefs.ReplaceFigure [1];
GriffinFileDefs.ClosePortfolio;
MenuDefs.HideMenu[filewriteMenu];
RefreshDefs.RestoreScreen[];
END;

NoFile: MenuDefs.MenuProc =
BEGIN
MenuDefs.HideMenu[filewriteMenu];
RefreshDefs.RestoreScreen[];
END;

Restore: MenuDefs.MenuProc =
BEGIN OPEN ObjectDefs;
name: STRING;
newfile: BOOLEAN;
[name,newfile] _ GetName[];
IF name.length=0 THEN RETURN;
ExpungeObjects[];
IF  GriffinFileDefs.OpenPortfolio [name, FALSE] THEN
	BEGIN
	GriffinFileDefs.ReadFigure [1];
	GriffinFileDefs.ClosePortfolio;
	ObjectDefs.ReplotAllObjects[];
	END;
END;

TypeIntoFileName: MenuDefs.MenuProc =
BEGIN
MenuDefs.SelectOnly[item];
GriffinDefs.TypeIntoMenuItem[item];
END;

GetName: PROCEDURE RETURNS[string: STRING, newname: BOOLEAN]=
BEGIN OPEN MenuDefs;
nameItem: MenuItemHandle _ NIL;
FindLastSelected: MenuProc =
	BEGIN
	IF IsSelected[item] THEN nameItem _ item;
	END;
ForAllMenuItems[filesMenu, FindLastSelected];
IF nameItem = fileName THEN BEGIN
	nameItem _ AddPortfolioName[MenuString[fileName]];
	RETURN[MenuString[nameItem], TRUE];
	END
ELSE  RETURN[MenuString[nameItem], FALSE];
END;

AddPortfolioName: PROCEDURE[string: STRING]
	RETURNS [item: MenuDefs.MenuItemHandle] =
BEGIN OPEN MenuDefs, GriffinDefs;
i: CARDINAL;
IF string.length = 0
	THEN UserMessage["First select or type a file name."];
FOR i IN [0..string.length) DO
   IF string[i] = '   THEN UserMessage["Invalid file name."];
ENDLOOP;
item _ AddMenuItem[filesMenu, string, SelectOnly];
SetMenuString[fileName, ""];
SelectOnly[item];
RefreshDefs.RestoreScreen[];
END;

GridMenuProc: MenuDefs.MenuProc =
BEGIN
gridOn _ ~gridOn;
IF ~gridOn THEN BEGIN
	MenuDefs.Deselect[item];
	ObjectDefs.GridOff[];
	END
ELSE BEGIN
	MenuDefs.Select[item];
	ObjectDefs.GridOn[];
	END;
END;

Grid: PUBLIC PROCEDURE[pt: PointDefs.ScrPt] RETURNS[PointDefs.ScrPt]=
BEGIN
dx,dy: INTEGER;
IF NOT gridOn THEN RETURN[pt];
--will be unconvincing if grid < 2;
dx _ pt[X] MOD gridX;
pt[X] _ pt[X]-dx;
IF dx > gridX/2 THEN pt[X] _ pt[X] +gridX;
dy _ pt[Y] MOD gridY;
pt[Y] _ pt[Y]-dy;
IF dy > gridY/2 THEN pt[Y] _ pt[Y] +gridY;
RETURN[pt];
END;

Merge: MenuDefs.MenuProc =
BEGIN OPEN ObjectDefs;
view: View _  viewMenu.view;
Mark: ObjectProc = BEGIN
	IF obj.view=view THEN RETURN;
	obj.view _ view;
	RefreshDefs.MarkBox[obj.tl,obj.br,obj];
	END;
ForAllObjects[Mark];
RefreshDefs.RestoreScreen[];
END;

Switch: MenuDefs.MenuProc =
BEGIN OPEN ObjectDefs;
newView: View _ IF viewMenu.view=main THEN alternate ELSE main;
Mark: ObjectProc = BEGIN
	WITH foo: obj SELECT FROM
	menu => obj.view _ newView;
	token => IF foo.tokenType#selected AND foo.tokenType#open THEN obj.view _ newView;
	ENDCASE;
	END;
ForAllObjects[Mark];
SetCurrentView[newView];
ScreenDefs.ClearScreen[];
ObjectDefs.ReplotAllObjects[];
END;

EachFile: PROCEDURE [fp: POINTER, s: STRING]
	RETURNS [BOOLEAN] =
BEGIN
s.length _ GriffinFileDefs.IsTail[s, ".Griffin."];
IF s.length # 0
	THEN []_AddPortfolioName[s];
RETURN[FALSE];
END;

promptMenu: MenuDefs.MenuHandle_NIL;
displayMenu,filesMenu,viewMenu, filewriteMenu: PUBLIC MenuDefs.MenuHandle_NIL;

fileName: MenuDefs.MenuItemHandle;

promptMenu _ MenuDefs.CreateMenu[horizontal, [60,70], "Type File Name >"];

viewMenu _ MenuDefs.CreateMenu[horizontal, [100,50], NIL];
[]_MenuDefs.AddMenuItem[viewMenu,"Refresh",Refresh];
[]_MenuDefs.AddMenuItem[viewMenu,"Grid",GridMenuProc];
[]_MenuDefs.AddMenuItem[viewMenu,"Merge",Merge];
[]_MenuDefs.AddMenuItem[viewMenu,"Switch",Switch];

filesMenu _ MenuDefs.CreateMenu[vertical, [100,75], NIL];
[]_MenuDefs.AddMenuItem[filesMenu,"Save", Save];
[]_MenuDefs.AddMenuItem[filesMenu,"Restore", Restore];
[]_MenuDefs.AddMenuItem[filesMenu,"Press", Press];
fileName _ MenuDefs.AddMenuItem[filesMenu, "", TypeIntoFileName];

filewriteMenu _ MenuDefs.CreateMenu[horizontal, [100,75], "Overwrite Exisiting File? [Confirm]"];
[]_MenuDefs.AddMenuItem[filewriteMenu,"Yes",YesFile];
[]_MenuDefs.AddMenuItem[filewriteMenu,"No",NoFile];

DirectoryDefs.EnumerateDirectory [EachFile];
MenuDefs.SelectOnly[fileName];

END.