-- Tajo.TIP; Created by System
-- Version of 13-Feb-85 11:54:49

OPTIONS
  Fast,
  DefaultKeys;

[DEF,CTRL,(CONTROL Down)]

-- Top-level trigger case
SELECT TRIGGER FROM

  -- Standard Function Keys
  
  [DEF,IfShift,(SELECT ENABLE FROM
    LeftShift Down | RightShift Down => ~1;
    ENDCASE => ~2)]
  
  BS Down => [IfShift,BackWord,BackSpace];
  
  COPY Down => CopyDown;
  
  COPY Up => CopyUp;
  
  DELETE Down => [IfShift,Replace,Delete];
  
  DOIT Down => DoIt;
  
  EXPAND Down => [IfShift,DefineAbbreviation,ExpandAbbreviation];
    
  FIND Down => [IfShift,{COORDS SearchBackwards},{COORDS SearchForwards}];
  
  HELP Down => {Help Editor};
  
  JFIRST Down => [IfShift,{COORDS JLast},{COORDS JFirst}];
  
  JSELECT Down => [IfShift,{COORDS JInsert},{COORDS JSelect}];
  
  MOVE Down => MoveDown;
  
  MOVE Up => MoveUp;
  
  [DEF,Field,(SELECT ENABLE FROM
    [CTRL] => {COORDS ~1PreviousField};
    ENDCASE => {COORDS ~1NextField})]
    
  NEXT Down => [IfShift,[Field,Find],[Field,Replace]];
  
  PASTE Down => Paste;
  
  STUFF Down => Stuff;
  
  AGAIN Down => Again;
  
  TAB Down => [IfShift,Complete,CHAR];
 
  COMPLETE Down => Complete;
 
  UNDO Down => Undo;
  
  -- Standard COM-key combinations
  
  [DEF,COM,(~1 Down WHILE COMMAND Down => ~2)]
  
  [COM,B,InsertFieldBrackets];
  
  [COM,C,CopyDown];
  
  C Up WHILE COMMAND Down => CopyUp;
  
  [COM,D,Delete];
  
  [COM,E,ExpandAbbreviation];
  
  [COM,F,{COORDS SearchForwards}];
  
  [COM,J,{COORDS JSelect}];
  
  [COM,K,{COORDS ReplaceNextField}];
  
  [COM,L,[IfShift,MakeUpperCase,MakeLowerCase]];
  
  Case Down => [IfShift,MakeUpperCase,MakeLowerCase];
  
  [COM,N,{COORDS FindNextField}];
  
  [COM,R,Replace];
  
  [COM,S,Stuff];
  
  [COM,T,DefineAbbreviation];
  
  [COM,U,Undo];
  
  [COM,V,Paste];
  
  [COM,W,MoveDown];
  
  W Up WHILE COMMAND Down => MoveUp;
  
  [COM,X,DoIt];
  
  [COM,One,{COORDS JFirst}];
  
  [COM,Five,{COORDS JInsert}];
  
  [COM,Nine,[IfShift,InsertParens,{COORDS JLast}]];
  
  Comma Down => SELECT ENABLE FROM
    COMMAND Down => InsertAngleBrackets;
    CONTROL Down => "«";
    ENDCASE;
  
  [COM,Quote,[IfShift,InsertDoubleQuotes,InsertSingleQuotes]];
  
  [COM,LeftBracket,[IfShift,InsertCurlyBrackets,InsertSquareBrackets]];
  
  -- typing
  
  RESERVED Down => SELECT ENABLE FROM
    LeftShift Down | RightShift Down => "\137";
    ENDCASE => "\136";
  
  Eight Down WHILE [CTRL] => "´";
  
  Slash Down WHILE [CTRL] => "¸";
  
  Period Down WHILE [CTRL] => "»";
  
  ENDCASE...