{
File name Kiku2MWrite.mc
Description: Mesa Write op-codes
Author: don charnley
Created: February 16, 1980
Fasnacht 21-Jul-83 11:02:18 Fix stack problem during page fault on second word of double writes
Daniels 15-Jun-83 18:39:26 New Instruction Set
Sandman November 2, 1981  4:11 PM New Instruction Set
Last edited: Charnley, March 28, 1980  5:09 PM
Last edited: R. Garner, April 2, 1980  10:34 PM
Last edited: Johnsson, January 14, 1981  11:04 AM
Last edited: I. Yamaura  1-Nov-84 10:44:07 Change for 2M word at {+++}
}


{
Wn	Write n = 0
WB	Write Byte
WLB	Write Long Byte
WDB	Write Double Byte
WDLB	Write Double Long Byte

PSB	Put Swapped Byte
PSDn	Put Swapped Double n = 0
PSDB	Put Swapped Double Byte
PSLB	Put Swapped Long Byte
PSDLB	Put Swapped Double Long Byte

WLIP	Write Local Indirect Pair
WLILP	Write Local Indirect Long Pair
WLDILP	Write Local Double Indirect Long Pair

WOB	Write Overhead Byte
}


{*****************************************************************************
	WB
*****************************************************************************}

@W0:	TT _ TOS, push, L1_L1.PushDec,			c1, opcode[111'b];
	STK _ TOS, pop, PC _ PC + PC16, GOTO[Wa],	c2;

@WB:	TT _ TOS + ib, push, L1_L1.PushDec2,		c1, opcode[112'b];
	STK _ TOS, pop, PC _ PC + 1,			c2;
Wa:	Noop,						c3;

WMpc1:	Map _ Q _ [rhMDS, TT],				c1;
WMpc2:	T _ STK, pop,					c2;
WMpc3:	Rx _ rhRx _ MD, XwdDisp, 			c3;			{+++ Change for 2M +++}

{W:}	MAR _ [rhRx, Q + 0], DISP2[WMUD],		c1,WMFRet[L0.W];	{+++ Change for 2M +++}
Wb:	MDR _ T, IBDisp, GOTO[SLa],			c2,at[1,4,WMUD];	{+++ Change for 2M +++}
{WMUD:}	CALL[WMapFix1], L0_L0.W,			c2,at[0,4,WMUD];	{+++ Change for 2M +++}
	CALL[WMapFix1], L0_L0.W,			c2,at[2,4,WMUD];	{+++ Change for 2M +++}
	CALL[WMapFix1], L0_L0.W,			c2,at[3,4,WMUD];	{+++ Change for 2M +++}


{*****************************************************************************
	PSB
*****************************************************************************}

@PSB:	TT _ STK{ptr}, fXpop, fZpop, push,			c1, opcode[113'b];
	TT _ TT + ib, push, L1_L1.Dec2,					c2;
	STK _ TOS, PC _ PC + 1, GOTO[WMpc1],				c3;


{*****************************************************************************
	WLB
*****************************************************************************}

@WLB:	TT _ STK{ptrL}, pop, L1_L1.Push,			c1, opcode[114'b];
	TT _ TT + ib, CarryBr, L2_L2.WL,				c2;
	rhTT _ TOS{ptrH} LRot0, BRANCH[WLMpc1, WLa],			c3;

WLa:	CALL[VAHiInc],							c1;

WLMpc1:	Map _ Q _ [rhTT, TT],			 	       		c1, VAHiRet[L2.WL];
WLMpc2:	T _ STK,							c2;
WLMpc3:	Rx _ rhRx _ MD,XwdDisp,			c3;				{+++ Change for 2M +++}

{WL:}	MAR _ [rhRx, Q + 0],DISP2[WLMUD],		 c1, WLMFRet[L0.WL];	{+++ Change for 2M +++}
{WLc:}	MDR _ T{data}, IBDisp, PC _ PC + 1, pop, GOTO[SLa],c2,at[1,4,WLMUD];	{+++ Change for 2M +++}

{WLMUD:}CALL[WLMapFix1],L0 _ L0.WL,			c2,at[0,4,WLMUD];	{+++ Change for 2M +++}
	CALL[WLMapFix1],L0 _ L0.WL,			c2,at[2,4,WLMUD];	{+++ Change for 2M +++}
	CALL[WLMapFix1],L0 _ L0.WL,			c2,at[3,4,WLMUD];	{+++ Change for 2M +++}




{*****************************************************************************
	PSLB
*****************************************************************************}

@PSLB:	rhTT _ STK, pop,						c1, opcode[115'b];
	TT _ STK, fXpop, fZpop, push,					c2;
	TT _ TT + ib, CarryBr, push,					c3;

PSLc:	Map _ Q _ [rhTT, TT], push, BRANCH[PSLa, PSLb],			c1;
PSLa:	STK _ T _ TOS, L1_L1.Pop, GOTO[WLMpc3],				c2;
PSLb:	Q _ rhTT + 1, pop, LOOPHOLE[byteTiming],			c2;
	rhTT _ Q LRot0, GOTO[PSLc],					c3;
	

{*****************************************************************************
	WDB
*****************************************************************************}

@WDB:	Q _ TOS + ib, L1_L1.Push2,			c1, opcode[116'b];
	T _ STK{data1}, pop,				c2;
WDd:	Noop,						c3;

WDMpc1:	Map _ [rhMDS, Q],			c1;
WDMpc2:	TT _ STK{data0}, pop,			c2;
WDMpc3:	Rx _ rhRx _ MD,XwdDisp, 		c3;			{+++ Change for 2M +++}

{WD:}	MAR _ [rhRx,Q + 0],  DISP2[WDMUD],		c1, WMFRet[L0.WD];	{+++ Change for 2M +++}
{WDc:}	MDR _ TT, TT _ Q + 1, PgCarryBr,		c2,at[1,4,WDMUD];	{+++ Change for 2M +++}
	rhTT _ UvMDS, push, BRANCH[WDLd, WDb],		c3;

WDb:	Map _ Q _ [rhTT, Q + 1], L0_L0.WDB		c1;
WDe:	Noop,								c2;
	Rx _ rhRx _ MD, XwdDisp,			c3;			{+++ Change for 2M +++}
	MAR _ [rhRx, Q + 0], DISP2[WLMUD1],		c1, WLMFRet[L0.WDB];	{+++ Change for 2M +++}

{WDMUD:}CALL[WMapFix2], L0_L0.WD,			c2,at[0,4,WDMUD];	{+++ Change for 2M +++}
	CALL[WMapFix2], L0_L0.WD,			c2,at[2,4,WDMUD];	{+++ Change for 2M +++}
	CALL[WMapFix2], L0_L0.WD,			c2,at[3,4,WDMUD];	{+++ Change for 2M +++}

	MDR _ T{data}, IBDisp, PC _ PC + 1, pop, GOTO[SLa],c2,at[1,4,WLMUD1];	{+++ Change for 2M +++}
{WLMUD1:}CALL[WLMapFix2],				c2,at[0,4,WLMUD1];	{+++ Change for 2M +++}
	CALL[WLMapFix2],				c2,at[2,4,WLMUD1];	{+++ Change for 2M +++}
	CALL[WLMapFix2],				c2,at[3,4,WLMUD1];	{+++ Change for 2M +++}



{*****************************************************************************
	PSD0 and PSDB
*****************************************************************************}

@PSD0:	Q _ 0, pop, L1_L1.PushInc,				c1, opcode[117'b];
	T _ STK, fXpop, fZpop, push,					c2;
	PC _ PC - PC16, push, GOTO[PSDa],				c3;

@PSDB:	Q _ ib, pop,						c1, opcode[120'b];
	T _ STK, fXpop, fZpop, push,					c2;
	L1_L1.Push, push,						c3;

PSDa:	Q _ T + Q, push,						c1;
	STK _ T _ TOS, pop, GOTO[WDd],					c2;


{*****************************************************************************
	WDLB
*****************************************************************************}

@WDLB:	TT _ STK{ptrL}, pop, L1_L1.Push2,			c1, opcode[121'b];
	TT _ TT + ib, CarryBr, L2_L2.WDL,			c2;
	rhTT _ TOS{ptrH} LRot0, BRANCH[WDLMc1, WDLa],		c3;

WDLa:	CALL[VAHiInc],						c1;

WDLMc1:	Map _ Q _ [rhTT,TT],					c1, VAHiRet[L2.WDL];
WDLMc2:	T _ STK{data1}, pop, L0_ L0.WDL,			c2;
WDLMc3:	Rx _ rhRx _ MD, XwdDisp,				c3;			{+++ Change for 2M +++}

	MAR _ [rhRx,Q + 0], DISP2[WDLMUD],			c1, WLMFRet[L0.WDL];	{+++ Change for 2M +++}
	MDR _ STK{data0},					c2,at[1,4,WDLMUD];	{+++ Change for 2M +++}
	[] _ TT + 1, PgCarryBr,					c3;

WDLd:	MAR _ [rhRx,Q + 1], BRANCH[WDLb, WDLc],			c1;
WDLb:	MDR _ T{data1}, PC _ PC + 1, IBDisp, pop, CANCELBR[SLa,0],	c2;

WDLc:	[] _ Q + 1, CarryBr, CANCELBR[$,2],			c2;
	Q _ rhTT + 1, LOOPHOLE[byteTiming], BRANCH[WDLe, WDLf],	c3;

WDLe:	Map _ Q _ [rhTT, TT + 1], GOTO[WDe],			c1;

WDLf:	rhTT _ Q LRot0, GOTO[WDLc],				c1;

WDLMUD:	CALL[WLMapFix],						c2,at[0,4,WDLMUD];	{+++ Change for 2M +++}
	CALL[WLMapFix],						c2,at[2,4,WDLMUD];	{+++ Change for 2M +++}
	CALL[WLMapFix],						c2,at[3,4,WDLMUD];	{+++ Change for 2M +++}


{*****************************************************************************
	PSDLB
*****************************************************************************}

@PSDLB:	pop, L1_L1.None,					c1, opcode[122'b];
	rhTT _ STK, pop,						c2;
	TT _ STK, fXpop, fZpop, push,					c3;

	TT _ TT + ib, CarryBr, push,					c1;
	Q _ rhTT + 1, push, LOOPHOLE[byteTiming], BRANCH[PSDLa, PSLDb],	c2;
PSDLa:	GOTO[PSDLc],							c3;
PSLDb:	rhTT _ Q LRot0,GOTO[PSDLc],					c3;

PSDLc:	Map _ Q _ [rhTT, TT], push,					c1;
	STK _ T _ TOS, pop, L0_L0.WDL, GOTO[WDLMc3],			c2;


{*****************************************************************************
	WLIP
*****************************************************************************}

@WLIP:	MAR _ Q _ [rhL, L+alpha.left], L0_L0.WLIP, push,	c1, opcode[136'b];
	STK _ TOS, PC _ PC + 1, L2_L2.LIP, BRANCH[LIPa,LIPb,1],	c2;

	Map _ Q _ [rhMDS, TT], L1_L1.Dec2, GOTO[WMpc2],		c1, IPRet[L0.WLIP];


{*****************************************************************************
	WLILP
*****************************************************************************}

@WLILP:	MAR _ Q _ [rhL, L+alpha.left], L0_L0.WLILP, push,	c1, opcode[137'b];
	STK _ TOS, PC _ PC + 1, L2_L2.LILP0, BRANCH[LILPa,LILPb,1],	c2;

	PC _ PC - 1, L1_L1.Pop,					c3, ILPRet[L0.WLILP];

	Map _ Q _ [rhTT, TT], GOTO[WLMpc2],				c1;


{*****************************************************************************
	WLDILP
*****************************************************************************}

@WLDILP:
	MAR _ Q _ [rhL, L+alpha.left], L0_L0.WLDILP, push,	c1, opcode[140'b];
	STK _ TOS, PC _ PC + 1, L2_L2.LILP0, BRANCH[LILPa,LILPb,1],	c2;

	PC _ PC - 1, L1_L1.None, GOTO[WDLMc1],			c3, ILPRet[L0.WLDILP];



{*****************************************************************************
	WOB	Write Overhead Byte
*****************************************************************************}

@WOB:	TT _ TOS - ib, L1_L1.PushDec3,			c1, at[0F,10,ESC1n];
	PC _ PC + PC16, GOTO[Wa],					c2;

	{ E N D }