DIRECTORY
CD USING [ApplicationPtr, CellPtr, Design, DesignNumber, DesignPosition, DesignRect, Error, ErrorCode, lambda, Layer, ObPtr, Technology, InterestRect],
CDCells USING [CreateEmptyCell, RepositionCell],
CDDirectory USING [Include],
CDImports USING [GetReference, DoImport],
CDIO USING [MakeName, WriteDesign],
CDRects USING [CreateRect],
CDOps USING [CreateDesign],
CDSil USING [cdsil, xneutral, xred, xyellow, xgreen, xcyan, xviolet, xmagenta, xwhite, xbrown, xorange, xlime, xturquise, xaqua, xultraviolet, xpink, xsmoke],
CDSilConversion,
CDTexts USING [CreateText, FontRec, MakeFont],
CDViewer USING [CreateViewer],
CDX USING [IncludeOb, IncludeMode],
Commander USING [CommandProc, Register],
CommandTool USING [ParseToList],
Graphics USING [FontBox],
FileNames USING [CurrentWorkingDirectory],
FS USING [ComponentPositions, Error, ExpandName, Position, StreamOpen],
IO USING [Close, EndOf, EndOfStream, GetChar, STREAM, UnsafeGetBlock],
Real USING [RoundLI, Float],
Rope USING [ActionType, Cat, Concat, FromChar, FromProc, Length, Map, Replace, ROPE, SkipTo, Substr],
TerminalIO USING [WriteChar, WriteInt, WriteLn, WriteRope, UserAbort, UserSaysYes],
UserProfile USING [Token];
CDSilConversionImpl:
CEDAR PROGRAM
IMPORTS CD, CDCells, CDDirectory, CDImports, CDIO, CDOps, CDRects, CDSil, CDTexts, CDViewer, CDX, Commander, CommandTool, Graphics, FileNames, FS, IO, Real, Rope, TerminalIO, UserProfile
EXPORTS CDSilConversion =
BEGIN OPEN CDSilConversion;
debug0: BOOL ~ FALSE; -- reading file
debug1: BOOL ~ FALSE; -- converting
debug2: BOOL ~ FALSE; -- integration of macro files
debug3: BOOL ~ FALSE; -- main Sil model
debug4: BOOL ~ FALSE; -- translation of font names
debugAll: BOOL ~ debug0 OR debug1 OR debug2 OR debug3 OR debug4;
Description of the SIL file structure:
The first word in the file is a check code, that can be used to see that the file is actually a Sil format file. This word has two possible values, octal 34562 and 34563. The second value has been adopted as part of the design automation process to indicate that a Sil schematic file has been "build" into a wire-list file via the Build process.
Following this word are a secession of "item blocks" that describe the contents of the Sil drawing. An Item block has the following form:
word 0: macro-code
If this word equals a character code, then this item is to be added to the list of items for the macro Font 4 character. All items which are part of macro definitions will appear first in the file.
word 1: state and X-min
bits 0...3 are used internally to indicate the current state of an item - normal, selected, or deleted.
bits 4...15 are the minimum X coordinate bit position of the bounding box that the item occupies.
word 2: Y-min
bits 0...15 are the minimum Y coordinate bit position of the bounding box that the item occupies.
word 3: color and X-max
bits 0...3 are used to indicate the color associated with this item according to the following table:
00: Neutral 08: Brown
01: Red 09: Orange
02: Yellow 10: Lime
03: Green 11: Turquise
04: Cyan 12: Aqua
05: Violet 13: UltraViolet
06: Magenta 14: Pink
07: White 15: Smoke
bits 4...15 are the maximum X coordinate bit position of the bounding box that the item occupies.
word 4: font, face, and Y-max
bits 0...3 are used to indicate the "font" associated with this item. Font values are interpreted according to the following table:
00: Font 0
01: Font 0 with "boldness" opposite to default value in profile
02: Font 1
03: Font 1 with "boldness" opposite to default value in profile
04: Font 2
05: Font 2 with "boldness" opposite to default value in profile
06: Font 3
07: Font 3 with "boldness" opposite to default value in profile
08: Font 4 macro
09: Font 5 macro
10: Font 6 macro
11: Font 7 macro
12: Font 8 macro
13: Font 9 macro
14: A line with lingth and width indicated by preceeding coordinates
15: A background with area indicated by preceeding coordinates
bit 4 is used to indicate the "italics" opposite to default value in profile. This bit only has significance if the font value is 0 through 7.
bits 5...15 are the maximum Y coordinate bit position of the bounding box that the item occupies.
word 5 etc: optional string
If the preceeding word indicated an item of fonts 0 through 13, then additional words are required to define the characters in the item string. This is done with a BCPL string definition, that is, the left byte of word 5 is the number of characters in the string, the right byte is the first character. Additional words are appended as needed to contain the specified number of character bytes.
All coordinate value are expressed in "Alto Screen" units and are referneced to the upper left hand corner of the screen.
Notice that descriptions of library fonts 5 through 9 characters are not defined within this Sil file. A table is filled in by Sil during input, and later the library files indicated in the user profile are opened, and the front of the file is scanned for items defining the required character codes for each of the library fonts characters.
This boils down to the following Cedar declarations for reading a Sil file.
FourBits: TYPE ~ [0..17B];
TwelveBits: TYPE ~ [0..7777B];
SixteenBits: TYPE ~ [0..177777B];
OneBit: TYPE ~ [0..1];
ElevenBits: TYPE ~ [0..3777B];
bytesInSilItemBlock: NAT ~ 10;
mainElementName: CHAR ~ 377C; -- this as name of silobject means it's part of main picture
checkCodeByte1: CHAR ~ '9; -- check code indicating Sil format
unbuiltCheckCodeByte2: CHAR ~ 'r;
builtCheckCodeByte2: CHAR ~ 's;
SilBlockRef: TYPE ~ REF SilBlock;
SilBlock:
TYPE ~
MACHINE DEPENDENT RECORD [
leftChar, rightChar: CHAR,
state : FourBits,
xMin : TwelveBits,
yMin : SixteenBits,
color : FourBits,
xMax : TwelveBits,
font : FourBits,
italic : OneBit,
yMax : ElevenBits
];
For convenience we introduce the following font subranges.
TrueFonts: TYPE ~ [0..3];
MainFile: TYPE ~ [4..4];
LibraryFile: TYPE ~ [5..9]; declared in the definitions
SilFile: TYPE ~ [4..9];
InternalFonts: TYPE ~ [0..15];
InternalMacroFonts: TYPE ~ [8..13];
InternalFileMacroFonts: TYPE ~ [8..8];
InternalTrueFonts: TYPE ~ [0..7];
InternalLibraryFile: TYPE ~ [9..13];
InternalRopeFonts: TYPE ~ [0..13]; -- those fonts which do not denote boxes. See below
InternalBoxFonts: TYPE ~ [14..15];
InternalForegroundBoxFonts: TYPE ~ [14..14];
InternalBackgroundBoxFonts: TYPE ~ [15..15];
mainFile: MainFile ~ 4;
internalFileMacroFont: InternalFonts ~ 8;
foregroundBoxFont: InternalFonts ~ 14;
backgroundBoxFont: InternalFonts ~ 15;
Color: TYPE ~ [0..15];
colorTable: ARRAY Color OF CD.Layer ~ [CDSil.xneutral, CDSil.xred, CDSil.xyellow, CDSil.xgreen, CDSil.xcyan, CDSil.xviolet, CDSil.xmagenta, CDSil.xwhite, CDSil.xbrown, CDSil.xorange, CDSil.xlime, CDSil.xturquise, CDSil.xaqua, CDSil.xultraviolet, CDSil.xpink, CDSil.xsmoke];
Storage of fonts.
Font:
TYPE ~
RECORD [
name: Rope.ROPE,
descr: REF CDTexts.FontRec ← NIL
];
cellFonts: ARRAY InternalTrueFonts OF ARRAY BOOL OF Font;
Storage of macros.
ObjectName: TYPE ~ CHAR[' .. '~]; -- Only printing characters are used
MacroName: TYPE ~ CHAR['! .. '~]; -- All but <space>
mainObject: ObjectName ~ ' ; -- object whose name is <space>
SilObject:
TYPE ~
RECORD [
xMin, yMin: INTEGER, -- Upper Left boundary of box or string
xMax, yMax: INTEGER, -- Lower right boundary of box, guess for lower right of string
color: Color, -- Color used to display or print silobject
font: InternalFonts,
italic: BOOL, -- Only interesting for Ropes (fonts 0-13), TRUE for italic strings
value: Rope.ROPE ← NIL
];
SilObjectList: TYPE ~ LIST OF SilObject;
Macro:
TYPE ~
RECORD [
xMin, yMin: INTEGER ← 32767, -- Upper Left boundary of macro definition
xMax, yMax: INTEGER ← -1, -- Lower right boundary of macro definition
-- note: coordinates are Alto screen absolute, hence -1 is OK.
objects: SilObjectList ← NIL,
cdCellPtr: CD.ObPtr ← NIL -- This field used to generate recursion if a cell includes a cell not known yet.
];
LibraryDesign:
TYPE ~
RECORD [
data: CD.Design ← NIL,
imported: BOOL ← FALSE, -- Chipndale wants only a single import of the same library
written: BOOL ← FALSE -- libraries are written only once per run
];
MacroPtr: TYPE ~ REF Macro ← NIL;
MacroFile: TYPE ~ ARRAY ObjectName OF MacroPtr;
allMacros: REF MacroFile ← NIL;
silDesigns: ARRAY SilFile OF LibraryDesign; -- need all because of imports
silProfilePrefix: Rope.ROPE ~ "Sil.Font";
cdSilProfilePrefix: Rope.ROPE ~ "Chipndale.chipnsil.Library";
lambda: INTEGER ~ INTEGER[CD.lambda]; -- Sil uses integers throughout
lambdaAltoScreenHeights: INTEGER ~ lambda * 808;
File name towahboo.
CrackNames:
PROC [genericName: Rope.ROPE]
RETURNS [fullSilName: Rope.ROPE, properName: Rope.ROPE] ~ {
Takes any name in any format and produces a full Sil file names in slash convention and a proper name (base). A Chipndale name is not produced because this is already done by Chipndale.
namePos: FS.ComponentPositions;
silExtension: Rope.ROPE ~ "sil";
dummy: Rope.ROPE; -- in Cedar 5.2 FS.ExpandName does not work as documented
fullSilName ← CDIO.MakeName [base: genericName, ext: silExtension, wDir: FileNames.CurrentWorkingDirectory[]];
[fullFName: dummy, cp: namePos] ← FS.ExpandName [name: fullSilName];
properName ← Rope.Substr [base: dummy, start: namePos.base.start, len: namePos.base.length]
}; -- end CrackNames
A small utility.
TechnologyIsCdsil:
PROC [d: CD.Design]
RETURNS [b:
BOOL] ~ {
IF d = NIL THEN CD.Error [explanation: "Programming error in ReadSilLibrary"];
RETURN [d.technology = CDSil.cdsil]
}; -- end TechnologyIsCdsil
Reading a design.
ReadSilModel:
PUBLIC PROC [name: Rope.ROPE]
RETURNS [design: CD.Design ← NIL] ~ {
Reads a file containing a Sil model and makes it avalilable as a Chipndale design 'silDesign' with specific cells 'silDesignCells'.
designName: Rope.ROPE;
[fullSilName: name, properName: designName] ← CrackNames [name];
design ← CDIO.ReadDesign [from: fullCDName, check: TechnologyIsCdsil];
IF design # NIL THEN {
TerminalIO.WriteRope ["Warning: This Sil model already is available as a Chipnsil design.\n"];
silDesigns[mainFile].data ← design
}
ELSE {
Note: It has been decided that if the user wants to convert a Sil file, it is converted in any case.
FOR lib: LibraryFile IN LibraryFile
DO
Chipndale requires that the libraries be reloaded for every design.
silDesigns[lib].data ← NIL; silDesigns[lib].imported ← FALSE
ENDLOOP;
design ← CDOps.CreateDesign [technology: CDSil.cdsil];
design.name ← designName;
silDesigns[mainFile].data ← design;
ReadSilFile [fileName: name]; ConvertSilFile [file: mainFile];
IF TerminalIO.UserSaysYes [label: "CDSilConversion", text: Rope.Cat["Shall I write ", designName, " to disk ?\n"], default:
TRUE]
THEN {
IF
NOT CDIO.WriteDesign [design: design, to: designName]
THEN {
TerminalIO.WriteRope ["Warning: The design "]; TerminalIO.WriteRope [designName];
TerminalIO.WriteRope [" cannot be written. Proceeding anyway.\n"]
}
};
};
[] ← CDViewer.CreateViewer [design: design];
CDOps.Redraw [design: design]
}; -- end ReadSilModel
Reading a library file.
ReadSilLibrary:
PUBLIC
PROC [library: LibraryFile]
RETURNS [cells: CD.Design ← NIL] ~ {
Reads all macros from a macro disk file and stores them into the Chipndale cells. The design 'cells' additionally contains a synopsis of the cells it contains. For normal usage, 'cells' is not needed.
libraryPrefix: Rope.ROPE ~ "sil.lb"; -- Cedar Sil
designPrefix: Rope.ROPE ~ "SilLib"; -- Chipnsil
macroFileName, cdFileName, defaultName, designName: Rope.ROPE;
key: Rope.ROPE; -- Access key for the User Profile.
Libray may already have been converted.
IF silDesigns[library].data # NIL THEN RETURN [silDesigns[library].data];
Build Chipnsil design name.
key ← Rope.Concat [cdSilProfilePrefix, Rope.FromChar['0 + library]];
defaultName ← Rope.Cat [designPrefix, Rope.FromChar['0 + library], ".dale"];
cdFileName ← UserProfile.Token [key: key, default: defaultName];
designName ← CrackNames [cdFileName].properName;
Check whether the library file already exists in Chipndale format and read it if this is the case.
Note: It has been decided that if the user wants to convert a Sil file, it is converted in any case.
cells ← CDIO.ReadDesign [from: cdFileName, check: TechnologyIsCdsil];
IF cells # NIL THEN silDesigns[library].data ← cells
ELSE {
TerminalIO.WriteRope ["The library file "]; TerminalIO.WriteRope [cdFileName];
TerminalIO.WriteRope [" is not available. It is being converted from "];
TerminalIO.WriteRope [macroFileName]; TerminalIO.WriteLn;
Build the Sil library name and convert the library.
key ← Rope.Concat [silProfilePrefix, Rope.FromChar['0 + library]];
defaultName ← Rope.Concat [libraryPrefix, Rope.FromChar['0 + library]];
macroFileName ← UserProfile.Token [key: key, default: defaultName];
Now read in the the library file specified and convert it.
ReadSilFile [fileName: macroFileName];
cells ← CDOps.CreateDesign[technology: CDSil.cdsil];
cells.name ← designName;
silDesigns[library].data ← cells;
ConvertSilFile [file: library];
Write to disk the library if necessary.
IF TerminalIO.UserSaysYes[label: "CDSilConversion", text: Rope.Cat["Shall I write ", designName, " to disk ?\n"], default:
FALSE]
THEN {
IF
NOT silDesigns[library].written
THEN {
silDesigns[library].written ← CDIO.WriteDesign [design: cells, to: cdFileName];
IF
NOT silDesigns[library].written
THEN {
TerminalIO.WriteRope ["Warning: The design "]; TerminalIO.WriteRope [designName];
TerminalIO.WriteRope [" cannot be written. Proceeding anyway.\n"]
}
}
};
}; -- end ReadSilLibrary
SetFonts:
PROC [] ~ {
Gets from the user profile the fonts and makes the names for the Chipndale fonts. For the moment we consider only the display font, as Cedar Sil does. The chipndale fonts are made only when they are referenced the first time.
key: Rope.ROPE; -- Access key for the User Profile.
TrueFontsDefaults: TYPE ~ ARRAY TrueFonts OF Rope.ROPE;
trueFontsDefaults: TrueFontsDefaults ~ ["Helvetica10", "Helvetica7", "Template64", "Gates32"];
italic: BOOL ~ TRUE;
FixAttibutes:
PROC [coarseName: Rope.ROPE]
RETURNS [notBold, italic, both: Rope.ROPE] ~ {
Takes the coarse name as it is specified in the user profile, and produces one with the 'bold' (B) attribute reversed as well as one with the 'italic' (I) attibute. The 'narrow' (N) attribute is ignored.
properName, dummy, attributes, notBAttr: Rope.ROPE;
namePos: FS.ComponentPositions;
attributePos, bPos: INTEGER;
alreadyItalic: BOOL;
[fullFName: dummy, cp: namePos] ← FS.ExpandName [name: coarseName];
properName ← Rope.Substr [base: dummy, start: namePos.base.start, len: namePos.base.length];
attributePos ← properName.SkipTo [0, "0123456789"];
attributes ← properName.Substr [attributePos, properName.Length[]-attributePos];
Fix boldness attribute.
bPos ← attributes.SkipTo [0, "bB"];
IF bPos = attributes.Length[] THEN notBAttr ← Rope.Concat [attributes, "B"]
ELSE notBAttr ← Rope.Replace [base: attributes, start: bPos, len: 1];
Add an italic attribute if none is present.
alreadyItalic ← (attributes.SkipTo [0, "iI"] # attributes.Length []);
IF NOT alreadyItalic THEN attributes ← Rope.Concat [attributes, "I"];
Build the new font names.
notBold ← Rope.Replace [base: properName, start: attributePos, len: properName.Length[]-attributePos, with: notBAttr];
italic ← Rope.Replace [base: properName, start: attributePos, len: properName.Length[]-attributePos, with: attributes];
IF alreadyItalic THEN both ← notBold
ELSE {
notBAttr ← Rope.Concat [notBAttr, "I"];
both ← Rope.Replace [base: properName, start: attributePos, len: properName.Length[]-attributePos, with: notBAttr]
};
IF debug4
THEN {
TerminalIO.WriteRope [Rope.Cat["Original font: ", coarseName, ", notBold: "]];
TerminalIO.WriteRope [Rope.Cat[notBold, ", italic: ", italic, ", both: ", both, "\n"]]
}
}; -- end FixAttibutes
FOR i: TrueFonts
IN TrueFonts
DO
Get the true font names from the profile.
key ← Rope.Concat [silProfilePrefix, Rope.FromChar ['0 + i]];
cellFonts[2*i][~italic].name ← UserProfile.Token [key: key, default: trueFontsDefaults[i]];
[cellFonts[2*i+1][~italic].name, cellFonts[2*i][italic].name, cellFonts[2*i+1][italic].name] ← FixAttibutes [cellFonts[2*i][~italic].name];
ENDLOOP
}; -- end SetFonts
MakeCDFont:
PROC [nr: InternalTrueFonts, italic:
BOOL] ~ {
fullName: Rope.ROPE;
fullName ← CDIO.MakeName [base: cellFonts[nr][italic].name, ext: "Strike", wDir: "/Indigo/AltoFonts/"];
cellFonts[nr][italic].descr ← CDTexts.MakeFont [name: fullName, scale: Real.Float[lambda]];
IF cellFonts[nr][italic].descr =
NIL THEN { --
in case Indigo is busy or down
fullName ← CDIO.MakeName [base: cellFonts[nr][italic].name, ext: "Strike", wDir: "[ivy]<Tioga>strikefonts>"];
cellFonts[nr][italic].descr ← CDTexts.MakeFont [name: fullName, scale: Real.Float[lambda]]
};
IF cellFonts[nr][italic].descr =
NIL THEN {
TerminalIO.WriteRope [Rope.Cat["CDTexts.MakeFont returns not found on ", fullName, ". Fatal error.\n"]];
ERROR ABORTED
}
}; -- end MakeCDFont
ConvertSilFile:
PROC [file: SilFile] ~ {
Transforms all Sil macros to Chipndale cells. If a macro contains a macro from another macro file, the following policy is adopted: We try to import it an abort if we fail to do so.
MacroToObject:
PROC [sil: MacroPtr, name: ObjectName]
RETURNS [object: CD.ObPtr ←
NIL] ~ {
Produces a Chipndale object from a Sil macro. The return parameter is necessary for the recursion.
size, position: CD.DesignPosition ← [0, 0];
cdObPtr: CD.ObPtr ← NIL; -- object before it is either a cell or an application
cell: CD.ObPtr ← NIL; -- NIL when object is not a cell
boundingBox: CD.DesignRect; -- interesting rectangle
height: INTEGER ← 0; -- height of cell or main object
workingOnMainObject: BOOL;
impName: Rope.ROPE; -- global importee name assigned in FOR loop and used in CrackLibraryMacroSeq
CrackFileMacroSeq:
PROC [c:
CHAR]
RETURNS [quit:
BOOL ←
FALSE] ~ {
TYPE = ActionType. A file macro is one that is not in a library file, but rather in the file containing the Sil model. Externally it is referred to as a character of font 4.
cdObPtr: CD.ObPtr; -- object before it is either a cell or an application
boundingBox: CD.DesignRect; -- interesting rectangle
IF allMacros[c]
.cdCellPtr =
NIL THEN {
IF debug1
THEN {
TerminalIO.WriteRope [" will prepone macro "];
TerminalIO.WriteChar [c]; TerminalIO.WriteLn[]
};
cdObPtr ← MacroToObject [allMacros[c], c];
}
ELSE cdObPtr ← allMacros[c].cdCellPtr;
[] ← CDX.IncludeOb [design: silDesigns[file].data, cell: cell, ob: cdObPtr, position: position, obCSystem: interrestCoords, mode: dontPropagate];
Note that 'cell' and 'position' are one nesting layer up !
boundingBox ← CD.InterestRect[cdObPtr];
position.x ← position.x + (boundingBox.x2 - boundingBox.x1)
}; -- end CrackFileMacroSeq
CrackLibraryMacroSeq:
PROC [c:
CHAR]
RETURNS [quit:
BOOL ←
FALSE] ~ {
TYPE = ActionType. Imports a string of cells from another library. It is guaranteed that the library is already imported.
cdObPtr: CD.ObPtr;
boundingBox: CD.DesignRect; -- interesting rectangle
cdObPtr ← CDImports.GetReference [design: silDesigns[file].data, objectName: Rope.FromChar[c], importeeName: impName];
IF cdObPtr = NIL THEN CD.Error [ec: other, explanation: "CDImports.GetReference failed"];
[] ← CDX.IncludeOb [design: silDesigns[file].data, cell: cell, ob: cdObPtr, position: position, obCSystem: interrestCoords, mode: dontPropagate];
Note that 'cell' and 'position' are one nesting layer up !
boundingBox ← CD.InterestRect[cdObPtr];
position.x ← position.x + (boundingBox.x2 - boundingBox.x1)
}; -- end CrackLibraryMacroSeq
workingOnMainObject ← (name = ' );
height ←
IF workingOnMainObject
THEN lambdaAltoScreenHeights
ELSE lambda * (sil.yMax - sil.yMin);
boundingBox ← [lambda*sil.xMin, height - lambda*sil.yMax, lambda*sil.xMax, height - lambda*sil.yMin];
IF workingOnMainObject THEN cell ← NIL
ELSE {
cell ← CDCells.CreateEmptyCell [];
IF cell = NIL THEN CD.Error [ec: other, explanation: "Cannot create cell"];
We want to avoid simplification when the cell is displayed in the same size as in Cedar Sil.
NARROW [cell.specificRef, CD.CellPtr].simplifyOn ← height / (2 * lambda);
NARROW[cell.specificRef, CD.CellPtr].ir ← boundingBox;
NARROW[cell.specificRef, CD.CellPtr].useDIr ← FALSE;
[] ← CDDirectory.Include [design: silDesigns[file].data, object: cell, alternateName: Rope.FromChar[name]];
IF debug2
AND ((name = 'B)
OR (name = 'x))
THEN {
TerminalIO.WriteRope ["SetInterestRect to "];
TerminalIO.WriteInt [boundingBox.x1]; TerminalIO.WriteInt [boundingBox.y1];
TerminalIO.WriteInt [boundingBox.x2]; TerminalIO.WriteInt [boundingBox.y2];
TerminalIO.WriteLn
}
};
FOR silObj: SilObjectList ← sil.objects, silObj.rest
WHILE silObj #
NIL
DO
size.x ← lambda * (silObj.first.xMax - silObj.first.xMin);
size.y ← lambda * (silObj.first.yMax - silObj.first.yMin);
position.x ← lambda * silObj.first.xMin;
position.y ← height - lambda * silObj.first.yMax;
However, in a string of macros, the single macros are aligned by their upper edge.
SELECT silObj.first.font
FROM
IN InternalTrueFonts => {
cdFont: REF CDTexts.FontRec;
xmin, ymin, xmax, ymax: REAL; -- "ascent" is ymax; "descent" is -ymin.
IF (cellFonts[silObj.first.font][silObj.first.italic].descr =
NIL)
THEN
MakeCDFont [silObj.first.font, silObj.first.italic];
cdFont ← cellFonts[silObj.first.font][silObj.first.italic].descr;
cdObPtr ← CDTexts.CreateText [text: silObj.first.value, font: cdFont, layer: colorTable[silObj.first.color]];
IF cdObPtr = NIL THEN CD.Error [ec: other, explanation: "Cannot create text"];
[xmin, ymin, xmax, ymax] ← Graphics.FontBox[cdFont.font];
What should be done is something like
[xmin, ymin, xmax, ymax] ← Graphics.CharBox[cdFont.font, Rope.Fetch [base: silObj.first.value]];
However, Graphics.CharBox returns the ascent of the font and not that of the character in ymax. Therefore the overhead of fetching the single characters from the rope, breaking the rope in subropes with the same ascent, etc. is not done here. This should be reconsidered when Graphics will be replaced by the Imager in Cedar 5.3.
position.y ← height - lambda * (silObj.first.yMin + Real.RoundLI[ymax]);
The following statement did not bring a pixel of improvement in Cedar 5.2:
position.y ← height - lambda * silObj.first.yMin - Real.RoundLI[Real.Float[lambda]*ymax];
IF debug2
AND ((name = 'B)
OR (name = 'x))
THEN {
TerminalIO.WriteRope ["Value, scendent and y position: "];
TerminalIO.WriteRope [silObj.first.value];
TerminalIO.WriteInt [Real.RoundLI[ymax]];
TerminalIO.WriteInt [position.y];
TerminalIO.WriteLn []
};
[] ← CDX.IncludeOb [design: silDesigns[file].data, cell: cell, ob: cdObPtr, position: position, obCSystem: interrestCoords, mode: dontPropagate]
};
IN InternalFileMacroFonts => {
IF debug1
THEN {
TerminalIO.WriteChar [name];
TerminalIO.WriteRope [" calls a cell in the same design:\n"]
};
[] ← Rope.Map [base: silObj.first.value, action: CrackFileMacroSeq]
};
IN InternalLibraryFile => {
Import cell from specified design.
externalFileNr: LibraryFile; -- Since the exported procedure works with the external library file numbering, we cannot use the internal Sil numbering when we call our procedures.
IF debug1
THEN
TerminalIO.WriteRope ["Import of a cell in another design.\n"];
externalFileNr ← silObj.first.font - mainFile;
IF (silDesigns[externalFileNr].data = NIL) THEN [] ← ReadSilLibrary [externalFileNr];
IF
NOT silDesigns[externalFileNr].imported
THEN {
silDesigns[externalFileNr].imported ← CDImports.DoImport [design: silDesigns[file].data, importee: silDesigns[externalFileNr].data];
IF
NOT silDesigns[externalFileNr].imported
THEN
IF file
IN MainFile
THEN
CD.Error [ec: other, explanation: "Cannot import library"]
ELSE CD.Error [ec: other, explanation: "Library tried to import other library"]
};
impName ← silDesigns[externalFileNr].data.name; -- assigned to a global variable, so that it can be used inside CrackLibraryMacroSeq
[] ← Rope.Map [base: silObj.first.value, action: CrackLibraryMacroSeq]
};
IN InternalForegroundBoxFonts => {
cdObPtr ← CDRects.CreateRect [size: size, l: colorTable[silObj.first.color]];
IF cdObPtr = NIL THEN CD.Error [ec: other, explanation: "Cannot create rectangle"];
[] ← CDX.IncludeOb [design: silDesigns[file].data, cell: cell, ob: cdObPtr, position: position, obCSystem: interrestCoords, mode: dontPropagate]
};
IN InternalBackgroundBoxFonts => {
TerminalIO.WriteRope ["Warning: Background box attribute ignored.\n"];
Sil first displays all background rectangles, then the foreground rectangles.
cdObPtr ← CDRects.CreateRect [size: size, l: colorTable[silObj.first.color]];
IF cdObPtr = NIL THEN CD.Error [ec: other, explanation: "Cannot create rectangle"];
[] ← CDX.IncludeOb [design: silDesigns[file].data, cell: cell, ob: cdObPtr, position: position, obCSystem: interrestCoords, mode: dontPropagate]
};
ENDCASE => CD.Error [explanation: "Invalid case in CDSilConversionImpl.MacroToObject"]
ENDLOOP;
IF
NOT workingOnMainObject
THEN
[] ← CDCells.RepositionCell [cellOb: cell, design: silDesigns[file].data];
object ← IF workingOnMainObject THEN cdObPtr ELSE cell;
sil.cdCellPtr ← object;
sil.objects ← NIL; -- dispose obsolete space
IF debug1
THEN {
TerminalIO.WriteRope ["Converted object "];
TerminalIO.WriteChar [name]; TerminalIO.WriteLn[]
};
RETURN [object]
}; -- end MacroToObject
To avoid unnecessary recursion, we convert first the true macros and last the main object.
FOR obj: MacroName
IN MacroName
DO
IF ((allMacros[obj] #
NIL)
AND (allMacros[obj]
.cdCellPtr =
NIL))
THEN
The macro is not empty and has not been converted yet.
[] ← MacroToObject [allMacros[obj], obj]
ENDLOOP;
IF ((allMacros[mainObject] #
NIL)
AND (allMacros[mainObject]
.cdCellPtr =
NIL))
THEN
The mainObject is not empty and has not been converted yet.
[] ← MacroToObject [allMacros[mainObject], mainObject];
IF debugAll THEN TerminalIO.WriteRope ["Sil macro file converted to Chipndale model\n"]
}; -- end ConvertSilFile
ReadSilFile:
PROC [fileName: Rope.ROPE]
~ {
Reads a single macro file.
sBlock: SilBlockRef ← NEW [SilBlock];
AddItemBlockToMacro:
PROC [itemBlock: SilObject, name:
CHAR]
~ {
m: MacroPtr ← allMacros[name];
IF m = NIL THEN m ← NEW [Macro];
Update bounding box of macro.
m.xMin ← MIN [m.xMin, itemBlock.xMin];
m.yMin ← MIN [m.yMin, itemBlock.yMin];
m.xMax ← MAX [m.xMax, itemBlock.yMax];
m.yMax ← MAX [m.yMax, itemBlock.yMax];
Attach item block to Sil object list
m.objects ← CONS [itemBlock, m.objects];
allMacros[name] ← m
}; -- end AddItemBlockToMacro
ReadItemBlock:
PROC [s:
IO.STREAM]
RETURNS [name: CHAR, itemBlock: SilObject]
~ {
Return the Sil item block which appears next in the file being read. Also, return the item block's name, which will be ' (space) for main pictures, and a printing character for item blocks which are part of macro definitions.
ENABLE IO.EndOfStream => CD.Error [ec: other, explanation: "Unexpected End Of Stream"];
ReadChar:
PROC[]
RETURNS [c:
CHAR]
~ {
This procedure exists so it can be passed to Rope.FromProc, below.
RETURN [s.GetChar[] ];
}; -- end ReadChar
Main of ReadItemBlock
maxRecLen: INTEGER ~ 256; --the longest a record can be (1 byte for its length)
len: INTEGER;
TRUSTED {
bytesGot:
INT ← s.UnsafeGetBlock[
[base: LOOPHOLE[sBlock], startIndex: 0, count: bytesInSilItemBlock]
];
IF bytesGot # bytesInSilItemBlock
THEN
CD.Error [ec: other, explanation: "Macro file corrupted"]
};
name ←
IF sBlock.leftChar = mainElementName
THEN '
ELSE sBlock.rightChar;
-- name depends on whether is part of main picture ot macro.
-- state of item block (normal, selected, deleted) is ignored.
itemBlock.xMin ← sBlock.xMin;
itemBlock.yMin ← sBlock.yMin;
itemBlock.xMax ← sBlock.xMax;
itemBlock.yMax ← sBlock.yMax;
itemBlock.color ← sBlock.color;
itemBlock.font ← sBlock.font;
itemBlock.italic ← (sBlock.italic = 1);
IF debug0
THEN {
TerminalIO.WriteLn; TerminalIO.WriteChar [name];
TerminalIO.WriteInt [ORD[name]];
{OPEN itemBlock;
TerminalIO.WriteRope [": xMin, yMin:"];
TerminalIO.WriteInt [xMin]; TerminalIO.WriteInt [yMin];
TerminalIO.WriteRope [". xMax, yMax:"];
TerminalIO.WriteInt [xMax]; TerminalIO.WriteInt [yMax];
TerminalIO.WriteRope [". Col:"]; TerminalIO.WriteInt [color];
TerminalIO.WriteRope [". Font:"]; TerminalIO.WriteInt [font];
IF color # 0 THEN TerminalIO.WriteRope ["***"];
IF NOT italic THEN TerminalIO.WriteRope [", not"];
TerminalIO.WriteRope [" italic "];
}
};
IF itemBlock.font
IN InternalRopeFonts
THEN {
len ← s.GetChar[] - 0C;
itemBlock.value ← Rope.FromProc[len, ReadChar, maxRecLen];
IF debug0 THEN TerminalIO.WriteRope [itemBlock.value];
IF len
MOD 2 = 0
THEN
--Make sure to start next item block on a word boundary
[] ← s.GetChar[]; --Flush the extra slot for a Char
}
}; -- end ReadItemBlock
{
header1, header2: CHAR;
s:
IO.STREAM ← FS.StreamOpen [fileName !
FS.Error =>
IF error.group#bug
THEN {
TerminalIO.WriteRope [Rope.Cat [fileName, " not opened: ", error.explanation]];
ERROR ABORTED
}
];
name: CHAR; itemBlock: SilObject;
IF debugAll
THEN {
TerminalIO.WriteRope [fileName]; TerminalIO.WriteLn
};
header1 ← s.GetChar[]; header2 ← s.GetChar[];
IF (header1 = checkCodeByte1)
AND (header2 = unbuiltCheckCodeByte2)
THEN {
IF debugAll THEN TerminalIO.WriteRope ["Sil file format OK.\n"]
}
ELSE
IF (header1 = checkCodeByte1)
AND (header2 = builtCheckCodeByte2)
THEN
TerminalIO.WriteRope ["Sil schematic file has been 'build' into a wire-list file via the Build process.\n"]
ELSE TerminalIO.WriteRope ["File not in Sil format. Proceeding anyway.\n"];
allMacros ← NEW [MacroFile];
WHILE
NOT s.EndOf[]
DO
[name, itemBlock] ← ReadItemBlock [s];
The item block can now be attached to the relative macro. We cannot work directly with cells, because we need the bounding box of the entire macro to convert the y coordinate.
AddItemBlockToMacro [itemBlock, name]
Each library file contains a synopsis of all macros, stored as a main picture.
ENDLOOP;
IO.Close[s]
}
}; -- end ReadSilFile
ReadModel: Commander.CommandProc =
BEGIN
ENABLE {
TerminalIO.UserAbort => GOTO UserAbrt;
};
list: LIST OF Rope.ROPE;
length: NAT;
name: Rope.ROPE;
[list, length] ← CommandTool.ParseToList [cmd];
IF length = 1 THEN name←list.first
ELSE {
result←$Failure;
msg←"unknown arguments";
TerminalIO.WriteRope ["Read command failed\n"];
RETURN
};
TerminalIO.WriteRope ["Warning: Strings of macros as they occour in the synoptic tables are not aligned correctly.\n"];
[] ← ReadSilModel [name];
For library files this would be
synopsis ← ReadSilLibrary [5];
[] ← CDViewer.CreateViewer [design: synopsis]; CDOps.Redraw [synopsis] -- optional
EXITS
UserAbrt => {TerminalIO.WriteRope ["Read aborted\n"]};
END;
Module initialization.
SetFonts[];
Commander.Register [key: "CDReadSil", proc: ReadModel, doc: "Read a SIL model into chipndale"]
END.