
<<CDOpsImpl.mesa       (part of Chipndale)>>
<<by Christian Jacobi   July 12, 1983 10:56 am >>
<<last edited by Christian Jacobi   February 16, 1984 1:57 pm>>

DIRECTORY
Atom,
CD,
CDApplications,
CDCommands,
CDCells,
CDDraw,
CDEvents,
CDInline,
CDOps,
CDOrient,
CDValue,
Rope USING [ROPE],
SymTab;

CDOpsImpl: CEDAR MONITOR 
IMPORTS Atom, CD, CDApplications, CDCells, CDCommands, CDDraw, CDEvents, CDInline, CDOps, CDOrient, CDValue, SymTab
EXPORTS CDOps
SHARES CD  = 
BEGIN
createEvent: CDEvents.EventRegistration=CDEvents.RegisterEventType[$CreateNewDesign];
resetDesignEvent: CDEvents.EventRegistration=CDEvents.RegisterEventType[$ResetDesign];

DelRec: TYPE = RECORD [
delayedList: LIST OF REF Remember_NIL
];

GetDelRec: PROC [design: CD.Design] RETURNS [REF DelRec] =
BEGIN
x: REF _ CDValue.Fetch[boundTo: design, key: $CDxDeleted, propagation: design];
IF x#NIL AND ISTYPE[x, REF DelRec] THEN RETURN [NARROW[x]]
ELSE {
dr: REF DelRec = NEW[DelRec_[NIL]];
CDValue.Store[design, $CDxDeleted, dr];
 RETURN [dr]
}
END;

Remember: TYPE = RECORD [area: CD.DesignRect, clear: BOOL];

InternalResetDesign: PROC[design: CD.Design] = 
<<--is local since it does not cause a redraw>>
BEGIN
dummy: CD.ObPtr _ CDCells.CreateEmptyCell[];
design.cellDirectory _ SymTab.Create[];
design^.actual _ LIST[CD.PushRec[
dummyCell: CDApplications.NewApplicationI[ob: dummy],
mightReplace: NIL,
specific: NARROW[dummy.specificRef]
]];
END;

CreateDesign: PUBLIC PROC [technology: CD.Technology] RETURNS [design: CD.Design] =
BEGIN
design _ NEW[CD.DesignRec];
design.technology _ technology;  
InternalResetDesign[design]; -- must not cause redraw since event not yet processed
[] _ CDEvents.ProcessEvent[createEvent, design]; 
END;

ResetDesign: PUBLIC PROC [design: CD.Design] =
BEGIN
InternalResetDesign[design];
[] _ CDEvents.ProcessEvent[resetDesignEvent, design]; 
CDValue.Store[design, $CDxDeleted, NIL];
Redraw[design];
END;

RemoveApplication: PUBLIC PROC [design: CD.Design, aptr: CD.ApplicationPtr, draw: BOOL_TRUE] =
BEGIN
al: CD.ApplicationList _ CDOps.AppList[design];
IF al#NIL THEN 
IF al.first=aptr THEN CDOps.SetAppList[design, al.rest]
ELSE
FOR l: CD.ApplicationList _ al, l.rest WHILE l.rest#NIL DO
IF l.rest.first=aptr THEN {l.rest_l.rest.rest; EXIT}
ENDLOOP;
IF draw THEN DelayedRedraw[design, CDApplications.ARectO[aptr]];
END;

SelectNewMode: PROC[design: CD.Design] RETURNS [BOOL] =
BEGIN
mode: INT = CDValue.FetchInt[boundTo: design, key: $CDxSelectNewMode, propagation: technology, ifNotFound: 0];
RETURN [mode=1]
END;

AddAnObject: PUBLIC PROC[design: CD.Design, ob: CD.ObPtr, location: CD.DesignPosition, orientation: CD.Orientation] =
BEGIN
aptr: CD.ApplicationPtr;
IF ob#NIL THEN {
aptr _ CDApplications.NewApplicationI[
ob: ob, 
location: location, 
orientation: orientation 
];
IF SelectNewMode[design] THEN {
CDCommands.DeselectAll[design];
aptr.selected _ TRUE;
};
IncludeApplication[design, aptr];
}
END;

IncludeApplication: PUBLIC PROC [design: CD.Design, aptr: CD.ApplicationPtr, draw: BOOL_TRUE] =
BEGIN
IF aptr=NIL THEN ERROR CD.Error[callingError, "Include of NIL application"];
IF aptr.ob=NIL THEN ERROR CD.Error[callingError, "Include application with NIL object"];
CDOps.SetAppList[design, CONS[aptr, CDOps.AppList[design]]];
IF draw THEN DelayedRedraw[design, CDApplications.ARectO[aptr], TRUE];
END;

IncludeApplicationList: PUBLIC PROC [design: CD.Design, al: CD.ApplicationList, draw: BOOL_TRUE] =
BEGIN
FOR list: CD.ApplicationList _ al, list.rest WHILE list#NIL DO
IncludeApplication[design, list.first, draw];
ENDLOOP;
END;

Redraw: PUBLIC PROC [design: CD.Design, r: CD.DesignRect_CDOps.all, eraseFirst: BOOL_TRUE] =
BEGIN
CDDraw.InsertCommandAll[design, 
CDDraw.Comm[cmd: rect, erase: eraseFirst, rect: r, ref: NIL]];
END;

DelayedRedraw: PUBLIC ENTRY PROC [design: CD.Design, r: CD.DesignRect, eraseFirst: BOOL_TRUE] =
BEGIN
ENABLE UNWIND => NULL;
IF design#NIL THEN {
rem: REF Remember _ NEW[Remember_Remember[area: r, clear: eraseFirst]];
dl: REF DelRec = GetDelRec[design];
dl.delayedList _ CONS[rem, dl.delayedList]
}
END;

DoTheDelayedRedraws: PUBLIC ENTRY PROC [design: CD.Design] =
BEGIN
ENABLE UNWIND => NULL;
sq: REF DelRec = GetDelRec[design];
UNTIL sq.delayedList=NIL DO
CDDraw.InsertCommandAll[design, CDDraw.Comm[
cmd: rect, 
erase: sq.delayedList.first.clear, 
rect: sq.delayedList.first.area, 
ref: NIL
]];
sq.delayedList _ sq.delayedList.rest
ENDLOOP;
END;

DrawDesign: PUBLIC PROC[design: CD.Design, pr: CD.DrawRef] =
BEGIN
FOR w: LIST OF CD.PushRec _ design^.actual, w.rest WHILE w#NIL DO
IF pr.stopFlag^ THEN EXIT;
pr.drawChild[w.first.dummyCell, [0, 0], CDOrient.original, pr];
pr.pushLevel _ pr.pushLevel+1;
ENDLOOP;
END; 

QuickDrawDesign: PUBLIC PROC[design: CD.Design, pr: CD.DrawRef] =
BEGIN

SomeCommon: PROC[ob: CD.ObPtr, pos: CD.DesignPosition, orient: CD.Orientation,
pr: CD.DrawRef] RETURNS [BOOLEAN] =
INLINE BEGIN
RETURN CDInline.Intersect[CDOrient.RectAt[pos, ob.size, orient], pr.worldClip] 
END; 

DrawAndShowSelectionList: PROC [list: CD.ApplicationList, pr: CD.DrawRef] =
BEGIN
FOR w: CD.ApplicationList _ list, w.rest WHILE w#NIL DO
IF SomeCommon[w.first.ob, w.first.location, w.first.orientation, pr] THEN
BEGIN
IF pr.stopFlag^ THEN EXIT;
w.first.ob.p.quickDrawMe[w.first, w.first.location, w.first.orientation, pr];
IF w.first.selected THEN
w.first.ob.p.showMeSelected[w.first, w.first.location, w.first.orientation, pr];
END;
ENDLOOP;
END; 

<<-- drawDesign>>
DrawAndShowSelectionList[CDOps.AppList[design], pr];
IF pr.suppressOutsidePushedCell THEN RETURN; 
FOR w: LIST OF CD.PushRec _ design^.actual.rest, w.rest WHILE w#NIL DO
IF pr.stopFlag^ THEN EXIT;
pr.pushLevel _ pr.pushLevel+1;
w.first.dummyCell.ob.p.quickDrawMe[w.first.dummyCell, [0, 0], CDOrient.original, pr];
ENDLOOP;
END; 

PointedApplication: PUBLIC PROC  [design: CD.Design, pos: CD.DesignPosition] 
RETURNS [CD.ApplicationPtr] =
BEGIN
RETURN [ CDApplications.AplicationAt[CDOps.AppList[design], pos] ];
END;

SelectedApplication: PUBLIC PROC [design: CD.Design] 
RETURNS [first: CD.ApplicationPtr_NIL, multiple: BOOL_FALSE] =
<<--first: returns ref to any selected application if there is one or more, otherwise nil.>>
<<--multiple: more than one application is selected>>
BEGIN
FOR w: CD.ApplicationList _ CDOps.AppList[design], w.rest WHILE w#NIL DO
IF w.first.selected THEN
IF first=NIL THEN first_w.first
ELSE {multiple_TRUE; RETURN}
ENDLOOP;
END;

Info: PUBLIC PROC[ob: CD.ObPtr] RETURNS [Rope.ROPE] =
BEGIN
IF ob=NIL THEN RETURN ["nil object"]
ELSE IF ob.p.describe#NIL THEN RETURN [ob.p.describe[ob]] 
ELSE RETURN [Atom.GetPName[ob.p.objectType]]
END;

ReOrderApplication: PUBLIC PROC [design: CD.Design, aptr: CD.ApplicationPtr] =
<<--on return: design has exactly one occurrence of aptr, and it is at the end. >>
<<--(includes aptr if necessary and removes double occurences)>>
BEGIN
al: CD.ApplicationList _ CDOps.AppList[design];
found: BOOL _ FALSE;
IF aptr=NIL THEN ERROR CD.Error[callingError, "Reorder of NIL application"];
WHILE al#NIL AND al.first=aptr DO {found_TRUE; al _ al.rest} ENDLOOP;
IF al=NIL THEN {
IF found THEN al_LIST[aptr] 
ELSE ERROR CD.Error[callingError, "Reorder of application not in design"];
}
ELSE 
FOR l: CD.ApplicationList _ al, l.rest DO
<<-- l#NIL AND l.first#aptr holds at this point>>
WHILE l.rest#NIL AND l.rest.first=aptr DO {found_TRUE; l.rest _ l.rest.rest} ENDLOOP;
IF l.rest=NIL THEN {
IF found THEN l.rest _ LIST[aptr]
ELSE ERROR CD.Error[callingError, "Reorder of application not contained in design"];
EXIT
}
ENDLOOP;
CDOps.SetAppList[design, al];
END;

END.