
<<FileWriter.Mesa>>
<<written by Paxton.  March 1981>>
<<last written by Paxton. August 24, 1982 9:31 am>>
<<Russ Atkinson, July 22, 1983 10:21 am>>
<<Doug Wyatt, January 17, 1984 5:40:23 pm PST>>

DIRECTORY
FS USING [OpenFile],
IO USING [STREAM],
MonitoredQueue USING [MQ],
Rope USING [ROPE],
RopeEditingBLT USING [StringToStringBlt],
RopeReader USING [GetString, Ref, SetPosition];

FileWriter: CEDAR DEFINITIONS
IMPORTS RopeEditingBLT, RopeReader
= BEGIN

ROPE: TYPE = Rope.ROPE;
Offset: TYPE = INT;

Ref: TYPE = REF FileWriterBody;
FileWriterBody: PRIVATE TYPE = RECORD [
block: REF TEXT, -- current block of characters
blockList: BlockList, -- list of blocks
blockQueue: MonitoredQueue.MQ, -- monitored queue of blocks
blockCount: NAT _ 0, -- number added to queue/list
stream: IO.STREAM, -- file being written
toRope: BOOL, -- true if output to rope instead of file
closeStream: BOOL, -- true if should close stream after write
consumer: PROCESS, -- removes blocks from queue
kind: OfWriter _ unused
];
OfWriter: TYPE = {control, comment, data, unused};
BlockList: TYPE = REF BlockListBody;
BlockListBody: TYPE = RECORD[block: REF TEXT, next: BlockList];
blockSize: NAT = 512; 

OpenC: PROC [capability: FS.OpenFile, start: Offset _ 0, makeControl: BOOL _ TRUE]
RETURNS [control,comment,data: Ref];

ToRope: PROC [makeControl: BOOL _ TRUE] RETURNS [control,comment,data: Ref];

ToStream: PROC [stream: IO.STREAM, makeControl: BOOL _ TRUE]
RETURNS [control,comment,data: Ref];

Close: PROC [control,comment,data: Ref, textOnly: BOOL]
RETURNS [dataLen, count: Offset, output: ROPE];

WriteChar: PROC [c: CHAR, writer: Ref] = INLINE {
loc: NAT;
block: REF TEXT _ writer.block;
IF (loc_block.length) >= blockSize THEN -- buffer is full
{ block _ BumpWriter[writer]; loc _ 0 };
block[loc] _ c; block.length _ loc+1 };

WriteRope: PROC
[r: ROPE, size: Offset, writer: Ref, reader: RopeReader.Ref] = INLINE {
cnt: NAT;
block: REF TEXT _ writer.block;
RopeReader.SetPosition[reader,r,0];
UNTIL size=0 DO
IF block.length >= blockSize THEN -- buffer is full
block _ BumpWriter[writer];
cnt _ RopeReader.GetString[reader:reader, str:block];
size _ size-cnt;
ENDLOOP };

WriteText: PROC [txt: REF READONLY TEXT, writer: Ref] = INLINE {
cnt, loc, txtLoc: NAT;
size: NAT _ txt.length;
block: REF TEXT _ writer.block;
txtLoc _ 0;
UNTIL size=0 DO
IF (loc_block.length) >= blockSize THEN -- buffer is full
{ block _ BumpWriter[writer]; loc _ block.length };
cnt _ MIN[blockSize-loc,size];
RopeEditingBLT.StringToStringBlt[txt,txtLoc,block,loc,cnt];
size _ size-cnt; txtLoc _ txtLoc+cnt; block.length _ loc+cnt;
ENDLOOP };

BumpWriter: PRIVATE PROC [writer: Ref] RETURNS [REF TEXT];
<<-- move chars to end of list and allocate a new one>>

Start: PROC; -- for initialization only

END.