InputFocusImpl.mesa
Copyright © 1983, 1984 Xerox Corporation. All rights reserved.
McGregor, June 3, 1983 3:48 pm
Maxwell, January 24, 1983 3:06 pm
Paul Rovner, June 15, 1983 5:14 pm
Russ Atkinson, November 18, 1983 1:29 pm
Doug Wyatt, September 4, 1984 3:03:02 pm PDT
DIRECTORY
AMEvents USING [Debugging],
ClassIncreek USING [Increek],
Cursors USING [CursorType, GetCursor, SetCursor],
IconManager USING [IconModify, IconNotify, iconTIP],
ImplErrors USING [UserErrorQuery],
InputFocus USING [Focus, FocusRec],
Interminal USING [terminal],
Process USING [GetPriority, Priority, SetPriority],
Terminal USING [BlinkBWDisplay],
TIPUser USING [CreateParseInfo, CreateClient, DestroyClient, DiscardTypeAhead,
InstantiateNewTIPTable, ParseOneEvent, ResetTIPContext, stdCoords,
TIPButtonProc, TIPClient, TIPNotifyProc, TIPParseInfo, TIPScreenCoords, TIPTable],
ViewerEvents USING [ProcessEvent],
ViewerOps USING [MouseInViewer],
ViewerClasses USING [Viewer, ModifyAction, NotifyProc],
ViewersStallNotifier USING [],
WindowManager USING [waitCount],
WindowManagerPrivate USING [ProcessWindowResults, VMgrPriority];
InputFocusImpl: CEDAR MONITOR
IMPORTS AMEvents, Cursors, IconManager, ImplErrors, Interminal, Process, TIPUser, Terminal, ViewerEvents, ViewerOps, WindowManager, WindowManagerPrivate
EXPORTS InputFocus, ViewersStallNotifier
SHARES InputFocus, TIPUser, ViewerEvents
= BEGIN
Focus: TYPE ~ InputFocus.Focus;
FocusRec: TYPE ~ InputFocus.FocusRec;
Viewer: TYPE ~ ViewerClasses.Viewer;
captureProc: ViewerClasses.NotifyProc ← NIL;  -- client preempting all button events
captureTIP: TIPUser.TIPTable ← NIL; -- TIP Table associated with the capture.
captureViewer: Viewer ← NIL;  -- focus data private to the capture.
SetInputFocus: PUBLIC ENTRY PROC [self: Viewer ← NIL, info: REF ← NIL] =
BEGIN
ENABLE UNWIND => NULL; -- release lock
ModifyInputFocus[kill];
currentFocus.owner ← self; -- note that we don't flush any CaptureButtons!
currentFocus.info ← info;
currentFocus.link ← NIL;
ModifyInputFocus[set];
IF currentFocus.owner#NIL THEN ChangeTIPContext[currentFocus.owner];
END;
ModifyInputFocus: PROC [action: ViewerClasses.ModifyAction] =
BEGIN
ENABLE ANY => {IF ImplErrors.UserErrorQuery[] THEN CONTINUE};
IF action=set THEN
IF ViewerEvents.ProcessEvent[setInputFocus, currentFocus.owner, TRUE] THEN RETURN;
IF action=kill THEN
IF ViewerEvents.ProcessEvent[killInputFocus, currentFocus.owner, TRUE] THEN RETURN;
IF currentFocus.owner # NIL THEN BEGIN
IF currentFocus.owner.iconic THEN IconManager.IconModify[currentFocus.owner, action]
ELSE IF currentFocus.owner.class.modify#NIL THEN
currentFocus.owner.class.modify [currentFocus.owner, action];
END;
IF action=set THEN [] ← ViewerEvents.ProcessEvent[setInputFocus, currentFocus.owner, FALSE];
IF action=kill THEN [] ← ViewerEvents.ProcessEvent[killInputFocus, currentFocus.owner, FALSE];
END;
GetInputFocus: PUBLIC PROC RETURNS [Focus] = {RETURN[currentFocus]} ;
PushInputFocus: PUBLIC ENTRY PROC [self: Viewer ← NIL, info: REF ← NIL] = BEGIN
ENABLE UNWIND => NULL; -- release lock
ModifyInputFocus[push];
currentFocus ← NEW[FocusRec ← [owner: self, info: info, link: currentFocus]];
ModifyInputFocus[set];
ChangeTIPContext[currentFocus.owner];
END;
CaptureButtons: PUBLIC ENTRY PROC[proc: ViewerClasses.NotifyProc, tip: TIPUser.TIPTable, viewer: Viewer ← NIL] =
BEGIN
ENABLE UNWIND => NULL; -- release lock
captureProc ← proc;
captureTIP ← tip;
captureViewer ← viewer;
END;
PopInputFocus: PUBLIC ENTRY PROC = BEGIN
ENABLE UNWIND => NULL; -- release lock
IF currentFocus.link = NIL THEN RETURN;
ModifyInputFocus[kill];
currentFocus ← currentFocus.link;
ModifyInputFocus[pop];
ChangeTIPContext[currentFocus.owner];
END;
ChangeTIPContext: PROC [self: Viewer, interrupt: BOOLEAN ← FALSE] =
{TIPUser.ResetTIPContext[focusTIP,
IF self=NIL THEN NIL ELSE IF self.iconic THEN IconManager.iconTIP ELSE self.tipTable,
MasterNotifyProc, interrupt]};
MapCoordinateResults: PROC[results: LIST OF REF ANY, coords: TIPUser.TIPScreenCoords ← NIL] =
BEGIN
FOR lst: LIST OF REF ANY ← results, lst.rest UNTIL lst = NIL DO
SELECT lst.first FROM
TIPUser.stdCoords => IF coords#NIL THEN TIPUser.stdCoords^ ← coords^
ELSE [] ← ViewerOps.MouseInViewer[TIPUser.stdCoords];
ENDCASE;
ENDLOOP;
END;
MasterNotifyProc: TIPUser.TIPNotifyProc -- [results: LIST OF REF ANY] -- = BEGIN
convert a TIPNotify into an InputFocusNotify.
ENABLE AMEvents.Debugging => PrivateUnWedgeNotifier[];
IF inputEnabled AND currentFocus.owner#NIL THEN BEGIN
ENABLE ANY => {IF ImplErrors.UserErrorQuery[] THEN CONTINUE};
IF currentFocus.owner.iconic THEN IconManager.IconNotify[currentFocus.owner, results]
ELSE BEGIN
MapCoordinateResults[results];
currentFocus.owner.class.notify[currentFocus.owner, results];
END;
END;
END;
MasterButtonProc: TIPUser.TIPButtonProc = BEGIN
[screenXY: TIPScreenCoords, button: Interminal.KeyName, state: ClassIncreek.Increek]
RETURNS [consume: BOOL ← FALSE]
ENABLE AMEvents.Debugging => PrivateUnWedgeNotifier[];
results: LIST OF REF ANY;
viewer: ViewerClasses.Viewer;
client: BOOL;
TIPParse: PROC [table: TIPUser.TIPTable, mapCoords: BOOLEAN ← TRUE] = BEGIN
parseInfo.inCreek ← state; -- OK since we only ever do one parse
parseInfo.tableHead ← table;
results ← TIPUser.ParseOneEvent[parseInfo];
IF mapCoords THEN MapCoordinateResults[results, screenXY];
END;
IF ~inputEnabled THEN RETURN;
IF captureProc#NIL THEN BEGIN
TIPParse[captureTIP, FALSE];
IF results#NIL THEN captureProc[captureViewer, results
! ANY => {IF ImplErrors.UserErrorQuery[] THEN CONTINUE}];
RETURN[TRUE];
END;
[viewer, client] ← ViewerOps.MouseInViewer[screenXY];
IF viewer=NIL THEN BEGIN
IF WindowManager.waitCount=0 AND Cursors.GetCursor[]#textPointer THEN
Cursors.SetCursor[textPointer];
TIPParse[NIL, FALSE] -- consume event
END
ELSE IF viewer.iconic THEN BEGIN
TIPParse[IconManager.iconTIP, FALSE];
IF results#NIL THEN IconManager.IconNotify[viewer, results
! ANY => {IF ImplErrors.UserErrorQuery[] THEN CONTINUE}];
END
ELSE IF client THEN BEGIN
IF WindowManager.waitCount=0 AND viewer.class.cursor#Cursors.GetCursor[] THEN
Cursors.SetCursor[viewer.class.cursor];
TIPParse[viewer.tipTable];
IF results#NIL THEN viewer.class.notify[viewer, results
! ANY => {IF ImplErrors.UserErrorQuery[] THEN CONTINUE}];
END
ELSE BEGIN
TIPParse[WindowManagerTIPTable];
IF results#NIL THEN WindowManagerPrivate.ProcessWindowResults[viewer, results
! ANY => {IF ImplErrors.UserErrorQuery[] THEN CONTINUE}];
END;
RETURN[TRUE];
END;
UnWedgeNotifier: PUBLIC PROC [process: PROCESS, kind: ATOM] = BEGIN
NOP since handled by informational signals in MasterNotify and MasterButton procs
END;
PrivateUnWedgeNotifier: PROC = BEGIN
exciting code to make a new notifier when ours is dying
TRUSTED {Interminal.terminal.BlinkBWDisplay[]};
currentFocus ← NEW[FocusRec];
TIPUser.DestroyClient[focusTIP]; -- destroy old notifier
StartTIP[]; -- make a new notifier
END;
EnableInput: PUBLIC PROC = BEGIN
TIPUser.DiscardTypeAhead[focusTIP];
inputEnabled ← TRUE;
END;
inputEnabled: PUBLIC BOOLEAN ← FALSE; -- procs above will ignore TIP input while FALSE
parseInfo: TIPUser.TIPParseInfo ← TIPUser.CreateParseInfo[];
currentFocus: Focus ← NEW[FocusRec]; -- this is the head of the focus stack
WindowManagerTIPTable: PUBLIC TIPUser.TIPTable ←
TIPUser.InstantiateNewTIPTable["WindowMgr.tip"];
focusTIP: PUBLIC TIPUser.TIPClient;
StartTIP: PROC = TRUSTED BEGIN
oldPriority: Process.Priority = Process.GetPriority[];
Process.SetPriority[WindowManagerPrivate.VMgrPriority]; -- so TIP forked at VMgrPriority
focusTIP ← TIPUser.CreateClient[buttons: MasterButtonProc, notify: MasterNotifyProc];
TIPUser.DiscardTypeAhead[focusTIP];
Process.SetPriority[oldPriority];
END;
StartTIP[];
END.