% TwoColumnLandscapePrint.Style
% last written by Plass, November 17, 1982 4:20 pm
% Attach this after you attach cedar.style or whatever to get two column landscape output.
BeginStyle
(root) "default type for root nodes" {
24 pt topIndent
24 pt topLeading
0 pt leftIndent
10 pt rightIndent
4 in lineLength
8.5 in pageLength
11 in pageWidth
1 in topMargin
1 in bottomMargin
} StyleRule
(pageNumbers) ".true to enable page numbers, .false to disable"
{PageCount 1 .eq .not} % supresses page number on page 1.
StyleRule
% Syntactic sugar
(bp) "big point" {72.0 .div in} StyleRule
(IF) {}.cvx .def
(THEN) {}.cvx .def
(FI) {.cvx .if}.cvx .def
(EXITifTRUE) {{.exit} .cvx .if}.cvx .def
(EXITifFALSE) {.not {.exit} .cvx .if}.cvx .def
(DO) {}.cvx .def
(ENDLOOP) {.cvx .loop}.cvx .def
% The output routine
(PageBuilder) {
StartPageCounter
DO {
.page EXITifFALSE
.fill
.page IF .not THEN {.fill} FI
3 9 in .hboxto
IF pageNumbers THEN {.fill GetPageCounter 3 6.5 in .vboxto} FI
.shipout IncrPage
} ENDLOOP
}.cvx .def
(StartPageCounter)
{(PageCount) 1 .def}.cvx .def
(GetPageCounter)
{.fill (Helvetica) 10 bp .textfont PageCount .cvs .textbox .fill 3 9 in .hboxto}.cvx .def
(IncrPage)
{(PageCount) PageCount 1 .add .def}.cvx .def
EndStyle