-- Dir.Mesa, last edit 14-Feb-82 14:23:21
-- Pilot 6.0/ Mesa 7.0
-- definitions file for the disk cache of the modeller


DIRECTORY
  CompilerOps: TYPE USING [LetterSwitches],
  File: TYPE USING [Capability, nullCapability],
  FileParms: TYPE USING [nullSymbolSpace, SymbolSpace],
  LowLoader: TYPE USING [LoadInfoSeq],
  TimeStamp: TYPE USING [Null, Stamp];
			
Dir: DEFINITIONS = {

-- used by MDModel LOC to point to local files 
-- rule:
-- 	bcd may not correspond to src
--	src and bcd may not correspond to version listed in model
-- 	DepSeq's, Capabilities always correspond to file create dates
--	if not present, can't use Capabilities, DepSeq's, Create dates
--	(bcdVers may have time field set independently)
FileInfo: TYPE = LONG POINTER TO FileInfoRecord;
FileInfoRecord: TYPE = RECORD[
	isBcd: BOOL _ FALSE,	-- LOC is a "Bcd", rather than normal Mesa
	--
	bcdPresent: BOOL _ FALSE,	-- T => is on local disk
	bcdFileName: LONG STRING _ NIL,	-- for this LOC
	bcdVers: TimeStamp.Stamp _ TimeStamp.Null,	-- version stamp, not create
	bcdCreate: LONG CARDINAL _ 0,	-- file create time
	bcdDepSeq: DepSeq _ NIL,	-- for the Bcd
	bcdCap: File.Capability _ File.nullCapability,
	loadInfoSeq: LowLoader.LoadInfoSeq _ NIL,	-- for the loaded bcd
	--
	srcPresent: BOOL _ FALSE,	-- T => is on local disk
	srcFileName: LONG STRING _ NIL,	-- for this LOC
	srcCreate: LONG CARDINAL _ 0,	-- file create time
	srcDepSeq: DepSeq _ NIL,	-- for the Bcd
	srcCap: File.Capability _ File.nullCapability,
	srcNotSaved: BOOL _ FALSE,	-- used by Permanent
	--
	moduleName: LONG STRING _ NIL,
	alreadyLookedFor: BOOL _ FALSE
	];
	
-- be sure to examine LoadDB and DumpDB in DBStashImpl before
-- changing this record
DepSeq: TYPE = LONG POINTER TO DepSeqRecord;
DepSeqRecord: TYPE = RECORD[
	bcdFileName: LONG STRING _ NIL,	-- ends in ".bcd"
	-- this is the version stamp, not the create time
	bcdVers: TimeStamp.Stamp _ TimeStamp.Null,
	srcFileName: LONG STRING _ NIL,	-- ends in ".mesa"
	srcCreate: LONG CARDINAL _ 0,	-- source file create time
	moduleName: LONG STRING _ NIL,
	CopyString: PROC[LONG STRING, UNCOUNTED ZONE _ NIL] 
		RETURNS[LONG STRING]_ NIL,	-- use to allocate strings
	-- compiler switch /a, etc.
	switches: CompilerOps.LetterSwitches _ ALL[FALSE],
	isdefns: BOOL _ FALSE,
	isconfig: BOOL _ FALSE,
	fromsource: BOOL _ FALSE,	-- T => info from source file
	istablecompiled: BOOL _ FALSE,
	symbolSpace: FileParms.SymbolSpace _ FileParms.nullSymbolSpace,
	size: CARDINAL _ 0,
	body: SEQUENCE maxsize: CARDINAL OF ADepRecord
	];

ModType: TYPE = MACHINE DEPENDENT {errortype(0), imports(1), 
	exports(2), directory(3), last(64000)};
ADepRecord: TYPE = RECORD[
	relation: ModType _ errortype,
	moduleName: LONG STRING _ NIL,
	bcdFileName: LONG STRING _ NIL,
	bcdVers: TimeStamp.Stamp _ TimeStamp.Null -- this is the version stamp, not the create time
	];

MaximumDepSize: CARDINAL = 160;	-- biggest is CoPilotDorado.Config (165)

-- procedures 

-- if src = TRUE, then see if there is a new version of source file
-- else look for new version of bcd file
NewVersion: PROC[fi: FileInfo, src: BOOL] RETURNS[newVersion: BOOL];

-- utilities for depseq's
AddToDep: PROC[depseq: DepSeq, padeprecord: POINTER TO ADepRecord];

}.