-- UnpackedBasicHeadsDLion.config
-- Last Edited by: Taft, February 27, 1983 3:28 pm

-- Everything in this configuration must be PACKed, because UnpackedBasicHeadsDLion is
-- bound directly to UtilityPilot-based programs, and MakeBoot/UtilityPilot require that
-- every module either be mentioned in UtilityPilotDLion.bootmesa or be in some PACK
-- containing some module so mentioned.
-- Note that for ordinary uses, the heads are Packaged, so this PACK statement is
-- effectively a no-op.

PACK -- resident
  ColorDisplayHeadDLion,
  DESSoft,
  EthernetHeadDLion,
  EthernetOneHeadDLion,
  IntervalTimerHeadDummy,
  ProcessorHeadDLion,
  RealMemoryImplDLion,
  SA4000HeadDLion,
  SA800HeadDLion,
  SetGMTUsingEthernet,
  TextBltImpl,
  UserTerminalHeadDLion;
  
BasicHeadsDLion: CONFIGURATION LINKS: CODE
  IMPORTS DeviceCleanup, Inline, PageMap, PilotDisk, Process, ResidentHeap,
    Runtime, RuntimeInternal, Space, SpecialSpace, Utilities
  EXPORTS ColorDisplayFace, DESFace, DisplayFace, DisplayFaceExtras, DLionInputOutput,
    EthernetFace, EthernetOneFace, EthernetOneFaceExtras, HeadStartChain1, IntervalTimerFace,
    KeyboardFace, MicrocodeBooting, MouseFace, ProcessorFace, RealMemory, SA4000Face,
    SA800Face, SoundGenerator, TemporarySetGMT =
  BEGIN
  
  TextBltImpl;
  
  DESSoft;
  
  [EthernetOneFace, EthernetOneFaceExtras, HeadStartChain1] _
    EthernetOneHeadDLion[HeadStartChain2];
    
  [EthernetFace, HeadStartChain2] _ EthernetHeadDLion[
    DLionInputOutput, DeviceCleanup, HeadStartChain3, Inline];
    
  [HeadStartChain3, SA4000Face] _ SA4000HeadDLion[
    DLionInputOutput, DeviceCleanup, HeadStartChain4, Inline, PageMap,
    PilotDisk, Utilities];
    
  [HeadStartChain4, SA800Face] _ SA800HeadDLion[
    DLionInputOutput, DeviceCleanup, HeadStartChain5, Inline];
  
  [DisplayFace, DisplayFaceExtras, HeadStartChain5, KeyboardFace, MouseFace,
    SoundGenerator] _
    UserTerminalHeadDLion[DeviceCleanup, DLionInputOutput, Inline,
    HeadStartChain6, PageMap, Process, Utilities];
      
  [DLionInputOutput, HeadStartChain6, RealMemory] _
    RealMemoryImplDLion[DeviceCleanup, Inline, PageMap, HeadStartChain7,
    Runtime, RuntimeInternal, Space, SpecialSpace];

  [ColorDisplayFace, HeadStartChain7] _
    ColorDisplayHeadDLion[HeadStartChain8, RuntimeInternal];

  [HeadStartChain8, IntervalTimerFace] _
    IntervalTimerHeadDummy[HeadStartChain];

  ProcessorHeadDLion; -- Exports the HeadStartChain plug

  SetGMTUsingEthernet;
  
  END....

LOG

Time: January 23, 1981  12:33 PM	By: Gobbel
	Action: Renamed file, BasicHeadsForPupDLion -> BasicHeadsDLion.
	Added export of SoundGenerator.
August 26, 1982 3:43 pm  Taft  Version for Cedar.
September 24, 1982 8:58 am  Taft  EthernetOneHeadDLion exports EthernetOneFaceExtras
February 24, 1983 1:51 pm  Taft  Add IntervalTimerHeadDummy
February 27, 1983 2:38 pm  Taft  HeadStartChainPlug and TrapSupportImpl removed; exports DisplayFaceExtras