-- file Pass4B.Mesa
-- last modified by Satterthwaite, September 10, 1982 1:12 pm
-- last modified by Sweet, Jan 20, 1981 12:32 PM

DIRECTORY
  Alloc: TYPE USING [Notifier, Top],
  BcdDefs: TYPE USING [
    BCD, CodeDesc, EPIndex, EVIndex, EVRecord, EXPRecord, FTIndex, FTRecord,
    GFTIndex, IMPIndex, IMPRecord, Link, LFIndex, MTRecord, Namee, NameRecord,
    NTRecord, PackedString, RefLitIndex, RFIndex, SGIndex, SGRecord, TFIndex, TMRecord,
    TypeIndex, TYPIndex, TYPRecord, VarIndex, VersionID,
    CTNull, EVNull, FTSelf, LFNull, RFNull, TFNull, NullLink, NullName],
  BcdOps: TYPE USING [BcdBase, EVHandle, NameString],
  ComData: TYPE USING [
    codeSeg, compilerVersion, definitionsOnly, fixupLoc, importCtx, linkCount,
    mainCtx, moduleCtx, mtRoot, mtRootSize, nBodies, nSigCodes, objectVersion,
    ownSymbols, pattern, source, switches, symSeg, table, textIndex],
  CompilerUtil: TYPE USING [
    AppendBCDString, AppendBCDWord, AppendBCDWords, EndBCD, FillBCDPage,
    ReadBCDIndex, ReadBCDOffset, RTTableOut, StartBCD, UpdateBCDWords],
  Copier: TYPE USING [FreeSymbolTable, GetSymbolTable, MapSymbols, UnmapSymbols],
  Environment: TYPE USING [wordsPerPage],
  Heap: TYPE USING [FreeNode, MakeNode],
  Log: TYPE USING [ErrorN, ErrorSei, WarningSei, WarningSubString],
  P4: TYPE USING [OwnGfi, DefaultBasicOps, OperandType],
  Pass4: TYPE USING [resident],
  PrincOps: TYPE USING [MaxNGfi],
  ReplOps: TYPE USING [MatchedBodies, Unmatched],
  Strings: TYPE USING [
    SubString, SubStringDescriptor,
    AppendChar, AppendString, AppendSubString, EqualSubStrings, EquivalentSubStrings],
  Symbols: TYPE USING [
    bodyType, ctxType, mdType, seType,
    Base, HTIndex, SEIndex, ISEIndex, CSEIndex, RecordSEIndex, CTXIndex,
    IncludedCTXIndex, BitAddress, Linkage, MDRecord, MDIndex, BTIndex,
    HTNull, SENull, ISENull, CTXNull, MDNull, BTNull, NullFileIndex,
    OwnMdi, RootBti, typeTYPE],
  SymbolOps: TYPE USING [
    FindString, FirstCtxSe, NextSe, SearchContext, SubStringForHash,
    TypeForm, UnderType, XferMode],
  SymbolTable: TYPE USING [Base],
  SymLiteralOps: TYPE USING [
    RefLitItem,
    DescribeRefLits, DescribeTypes, EnumerateRefLits, EnumerateTypes,
    UTypeId, TypeIndex],
  Tree: TYPE USING [Base, Index, Link, Map, Scan, NullIndex, treeType],
  TreeOps: TYPE USING [GetNode, GetSe, ListLength, ScanList],
  Types: TYPE USING [SymbolTableBase, Assignable, Equivalent];
  
Pass4B: PROGRAM
    IMPORTS
      Alloc, CompilerUtil, Copier, Heap, Log, P4, ReplOps, Strings,
      SymbolOps, SymLiteralOps, TreeOps, Types,
      dataPtr: ComData, passPtr: Pass4
    EXPORTS P4 = {
  OPEN SymbolOps, Symbols;
  
  tb: Tree.Base;	-- tree base address (local copy)
  seb: Symbols.Base;	-- se table base address (local copy)
  ctxb: Symbols.Base;	-- context table base address (local copy)
  mdb: Symbols.Base;	-- body table base address (local copy)
  bb: Symbols.Base;	-- body table base address (local copy)
  
  zone: UNCOUNTED ZONE _ NIL;
  
  BCDNotify: PUBLIC Alloc.Notifier = {
    -- called by allocator whenever table area is repacked
    tb _ base[Tree.treeType];
    seb _ base[seType];  ctxb _ base[ctxType];  mdb _ base[mdType];
    bb _ base[bodyType]};
    
    
-- shared variables

  bcdHeader: BcdOps.BcdBase;
  BcdHeaderPage: CARDINAL = 1;		-- page 0 is reserved
  bcdOffset, mtOffset: CARDINAL;
  
  nString: BcdOps.NameString;
  
  firstPorted: MDIndex = FIRST[MDIndex] + SIZE[MDRecord];
  lastPorted: MDIndex;	-- im/exported files in [firstPorted..lastPorted)
  
-- service routines

  GFTIndex: TYPE = BcdDefs.GFTIndex;
  EPIndex: TYPE = BcdDefs.EPIndex;
  EPLimit: CARDINAL = LAST[EPIndex]+1;
  VarLimit: CARDINAL = LAST[BcdDefs.VarIndex]+1;
  BcdLink: TYPE = BcdDefs.Link;
  
  OwnGfi: GFTIndex = P4.OwnGfi;
  
  
  GFSlots: PROC [epMax: EPIndex] RETURNS [nGfi: [1..4]] = {
    nGfi _ epMax/EPLimit + 1; RETURN};
    
  MakeEPLink: PUBLIC PROC [ep: CARDINAL, gfi: GFTIndex] RETURNS [BcdLink] = {
    RETURN [[procedure[tag: TRUE, ep: ep MOD EPLimit, gfi: gfi + ep/EPLimit]]]};
    
  MakeFrameLink: PROC [ep: CARDINAL, gfi: GFTIndex] RETURNS [BcdLink] = {
    RETURN [[variable[vtag: var, var: ep MOD VarLimit, vgfi: gfi + ep/VarLimit]]]};
    
  MakeTypeLink: PROC [index: BcdDefs.TYPIndex] RETURNS [BcdLink] = INLINE {
    RETURN [[type[typeID: index, type: TRUE, proc: FALSE]]]};
    
    
  MdiForCtx: PROC [ctx: CTXIndex] RETURNS [MDIndex] = {
    RETURN [WITH c: ctxb[ctx] SELECT FROM
      included => c.module,
      imported => ctxb[c.includeLink].module,
      ENDCASE => OwnMdi]};
      
  PortedCtx: PROC [ctx: CTXIndex] RETURNS [BcdDefs.FTIndex] = {
    RETURN [PortedFile[MdiForCtx[ctx]]]};
      
  PortedFile: PROC [mdi: MDIndex] RETURNS [fti: BcdDefs.FTIndex] = {
    n: CARDINAL;
    IF mdi = OwnMdi THEN fti _ BcdDefs.FTSelf
    ELSE {
      IF mdi IN [firstPorted .. lastPorted) THEN
        n _ LOOPHOLE[mdi-firstPorted, CARDINAL]/SIZE[MDRecord]
      ELSE {
	n _ LOOPHOLE[lastPorted-firstPorted, CARDINAL]/SIZE[MDRecord];
	SwapMdi[mdi, lastPorted];
	lastPorted _ lastPorted + SIZE[MDRecord]};
      fti _ LOOPHOLE[n*SIZE[BcdDefs.FTRecord]]};
    RETURN};
    
  SwapMdi: PROC [mdi1, mdi2: MDIndex] = {
    ctx: IncludedCTXIndex;
    t: MDRecord;
    IF mdi1 # mdi2 THEN {
      FOR ctx _ mdb[mdi1].ctx, ctxb[ctx].chain UNTIL ctx = CTXNull DO
	ctxb[ctx].module _ mdi2 ENDLOOP;
      FOR ctx _ mdb[mdi2].ctx, ctxb[ctx].chain UNTIL ctx = CTXNull DO
	ctxb[ctx].module _ mdi1 ENDLOOP;
      t _ mdb[mdi1];  mdb[mdi1] _ mdb[mdi2];  mdb[mdi2] _ t}};
	
	
  SubString: TYPE = Strings.SubString;
  SubStringDescriptor: TYPE = Strings.SubStringDescriptor;
  
  EnterId: PROC [id: SubString, ignoreCase: BOOLEAN] RETURNS [BcdDefs.NameRecord] = {
    i: CARDINAL;
    desc: SubStringDescriptor;
    s: SubString = @desc;
    t: BcdOps.NameString;
    i _ 0;  s.base _ @nString.string;
    UNTIL i = nString.string.length DO
      s.offset _ i _ i+1;  s.length _ nString.size[i];
      IF (IF ignoreCase
	    THEN Strings.EquivalentSubStrings[id, s]
	    ELSE Strings.EqualSubStrings[id, s]) THEN EXIT;
      i _ i + s.length;
      REPEAT
	FINISHED => {
	  IF nString.string.length + (id.length+1) > nString.string.maxlength THEN {
	    -- rewrite if nString is in table area
	    t _ LOOPHOLE[
	     zone.NEW[StringBody[nString.string.maxlength + MAX[(id.length+1), 32]]]];
	    Strings.AppendString[@t.string, @nString.string];
	    zone.FREE[@nString];  nString _ t};
	  i _ nString.string.length _ nString.string.length + 1;
	  nString.size[i] _ id.length;
	  FOR j: CARDINAL IN [0..id.length) DO
	    Strings.AppendChar[@nString.string, id.base[id.offset+j]] ENDLOOP};
      ENDLOOP;
    RETURN [[i]]};
    
  EnterSymbolId: PROC [sei: ISEIndex] RETURNS [BcdDefs.NameRecord] = {
    s: Strings.SubStringDescriptor;
    SubStringForHash[@s, seb[sei].hash];
    RETURN [EnterId[@s, FALSE]]};
    
  EnterFileId: PROC [mdi: MDIndex] RETURNS [BcdDefs.NameRecord] = {
    s: Strings.SubStringDescriptor;
    extLength: CARDINAL = (".bcd"L).length;
    SubStringForHash[@s, mdb[mdi].fileId];
    IF s.base[s.offset+s.length-1] = '. THEN s.length _ s.length - 1;
    IF s.length > extLength THEN {
      t: Strings.SubStringDescriptor _ [
        base: s.base, offset: s.offset+s.length-extLength, length: extLength];
      ext: Strings.SubStringDescriptor _ [base:".bcd"L, offset:0, length:extLength];
      IF Strings.EquivalentSubStrings[@t, @ext] THEN s.length _ s.length - extLength};
    RETURN [EnterId[@s, TRUE]]};
    
    
-- processing directory entries (to file table)

  ProcessDirectory: PUBLIC Tree.Scan = {

    DirectoryItem: Tree.Scan = {
      node: Tree.Index = TreeOps.GetNode[t];
      sei: ISEIndex = TreeOps.GetSe[tb[node].son[1]];
      type: CSEIndex = UnderType[seb[sei].idType];
      WITH t: seb[type] SELECT FROM
	definition => [] _ PortedCtx[t.defCtx];
	transfer => {
	  bti: BTIndex = seb[sei].idInfo;
	  IF bti # BTNull THEN [] _ PortedCtx[bb[bti].localCtx]};
	ENDCASE};
    
    TreeOps.ScanList[t, DirectoryItem]};
    
    
-- relocating imported control links

  ScanImports: PROC [action: PROC [ISEIndex]] = {
    FOR sei: ISEIndex _ FirstCtxSe[dataPtr.importCtx], NextSe[sei] UNTIL sei = ISENull DO
      action[sei] ENDLOOP};
      
  RelocateImports: PROC [ctx: CTXIndex, gfi: GFTIndex] RETURNS [epMax: EPIndex] = {
    epMax _ 0;
    FOR sei: ISEIndex _ FirstCtxSe[ctx], NextSe[sei] UNTIL sei = ISENull DO
      IF ~seb[sei].constant THEN {
	epN: CARDINAL = seb[sei].idValue;
	seb[sei].idValue _ MakeEPLink[epN, gfi];  epMax _ MAX[epN, epMax]};
      ENDLOOP;
    RETURN};
    
  AssignImports: PUBLIC Tree.Scan = {
    gfi: GFTIndex;
    saveIndex: CARDINAL = dataPtr.textIndex;
    
    ImportItem: PROC [sei: ISEIndex] = {
      node: Tree.Index = seb[sei].idValue;
      type: CSEIndex = UnderType[seb[sei].idType];
      epMax: EPIndex;
      IF node # Tree.NullIndex THEN dataPtr.textIndex _ tb[node].info;
      WITH t: seb[type] SELECT FROM
	definition => {
	  IF ctxb[t.defCtx].seList = ISENull THEN Log.WarningSei[unusedImport, sei];
	  epMax _ RelocateImports[t.defCtx, gfi];
	  gfi _ gfi + (seb[sei].idInfo _ t.nGfi)};
	ref => {seb[sei].idValue _ MakeEPLink[ep:0, gfi:gfi]; gfi _ gfi + 1};
	ENDCASE;
      seb[sei].mark4 _ TRUE};
      
    dataPtr.mtRoot.gfi _ OwnGfi;
    dataPtr.mtRoot.ngfi _ GFSlots[MAX[dataPtr.nBodies, dataPtr.nSigCodes]-1];
    gfi _ bcdHeader.firstdummy _ OwnGfi + PrincOps.MaxNGfi;
    IF ~dataPtr.definitionsOnly THEN ScanImports[ImportItem];
    bcdHeader.nDummies _ gfi - bcdHeader.firstdummy;
    dataPtr.textIndex _ saveIndex};
    
    
-- writing frame fragments (link fragment written by Pass4L)

  ProcessSymLiterals: PUBLIC PROC = {
    offset, length: CARDINAL;
    bcdHeader.rfOffset _ CompilerUtil.ReadBCDOffset[];
    bcdHeader.lfLimit _ LOOPHOLE[bcdHeader.rfOffset - bcdHeader.lfOffset];
    IF ~dataPtr.definitionsOnly THEN {
      rfi: BcdDefs.RefLitIndex _ [0];
      
      AppendLitItem: PROC [SymLiteralOps.RefLitItem] = {
        CompilerUtil.AppendBCDWords[@rfi, SIZE[BcdDefs.RefLitIndex]];
	rfi _ [rfi + 1]};
	
      [offset, length] _ SymLiteralOps.DescribeRefLits[];
      IF length # 0 THEN {
        WITH m: dataPtr.mtRoot SELECT FROM
	  multiple => m.refLiterals _ FIRST[BcdDefs.RFIndex];
	  ENDCASE;
	CompilerUtil.AppendBCDWord[offset];  CompilerUtil.AppendBCDWord[length];
	SymLiteralOps.EnumerateRefLits[AppendLitItem]}};
    bcdHeader.tfOffset _ CompilerUtil.ReadBCDOffset[];
    bcdHeader.rfLimit _ LOOPHOLE[bcdHeader.tfOffset - bcdHeader.rfOffset];
    IF ~dataPtr.definitionsOnly THEN {
      tfi: BcdDefs.TypeIndex _ [0];

      AppendTypeIndex: PROC [canonical: BOOLEAN, type: SEIndex] = {
        CompilerUtil.AppendBCDWords[@tfi, SIZE[BcdDefs.TypeIndex]];
	tfi _ [tfi + 1]};
	
      [offset, length] _ SymLiteralOps.DescribeTypes[];
      IF length # 0 THEN {
        WITH m: dataPtr.mtRoot SELECT FROM
	  multiple => m.types _ FIRST[BcdDefs.TFIndex];
	  ENDCASE;
	CompilerUtil.AppendBCDWord[offset];  CompilerUtil.AppendBCDWord[length];
	SymLiteralOps.EnumerateTypes[AppendTypeIndex]}};
    bcdHeader.tfLimit _ LOOPHOLE[CompilerUtil.ReadBCDOffset[] - bcdHeader.tfOffset]};
  
  
-- writing import records

  ProcessImports: PUBLIC Tree.Scan = {
    -- N.B. nextGfi must be regenerated to match AssignImports
    nImports: CARDINAL;
    impi: BcdDefs.IMPIndex;
    nextGfi: GFTIndex;
    anyNamed: BOOLEAN;
    
    ProcessSei: PROC [sei, tSei: ISEIndex] = {
      type: CSEIndex = UnderType[seb[sei].idType];
      entry: BcdDefs.IMPRecord _ [
		name: EnterSymbolId[tSei],
		port: interface,
		namedInstance: seb[sei].hash # seb[tSei].hash,
		file: ,
		gfi: nextGfi, ngfi: ];
      WITH t: seb[type] SELECT FROM
	definition => {
	  entry.file _ PortedCtx[t.defCtx];  entry.ngfi _ seb[sei].idInfo;
	  nextGfi _ (seb[sei].idValue _ nextGfi) + seb[sei].idInfo};
	ref => {
	  rType: RecordSEIndex = LOOPHOLE[UnderType[t.refType]];
	  entry.port _ module;
	  entry.file _ PortedCtx[seb[rType].fieldCtx];  entry.ngfi _ 1;
	  nextGfi _ nextGfi + 1};
	ENDCASE;
      nImports _ nImports + 1;
      IF entry.namedInstance THEN anyNamed _ TRUE;
      CompilerUtil.AppendBCDWords[@entry, SIZE[BcdDefs.IMPRecord]]};
      
    sei: ISEIndex;	-- updated by ImportItem
    
    ImportItem: Tree.Scan = {
      node: Tree.Index = TreeOps.GetNode[t];
      ProcessSei[sei, TreeOps.GetSe[tb[node].son[2]]];
      sei _ NextSe[sei]};
      
    NameItem: Tree.Scan = {
      node: Tree.Index = TreeOps.GetNode[t];
      sei: ISEIndex = TreeOps.GetSe[tb[node].son[1]];
      tSei: ISEIndex = TreeOps.GetSe[tb[node].son[2]];
      entry: BcdDefs.NTRecord;
      IF  seb[sei].hash # seb[tSei].hash THEN {
	entry _ [name: EnterSymbolId[sei], item: BcdDefs.Namee[import[impi]]];
	CompilerUtil.AppendBCDWords[@entry, SIZE[BcdDefs.NTRecord]]};
      impi _ impi + SIZE[BcdDefs.IMPRecord]};
      
    offset: CARDINAL;
    bcdHeader.impOffset _ offset _ CompilerUtil.ReadBCDOffset[];
    nImports _ 0;  impi _ FIRST[BcdDefs.IMPIndex];
    nextGfi _ bcdHeader.firstdummy;  anyNamed _ FALSE;
    IF ~dataPtr.definitionsOnly THEN {
      sei _ FirstCtxSe[dataPtr.importCtx];
      TreeOps.ScanList[t, ImportItem];
      UNTIL sei = ISENull DO ProcessSei[sei, sei]; sei _ NextSe[sei] ENDLOOP};
    bcdHeader.nImports _ nImports;
    bcdHeader.impLimit _ LOOPHOLE[CompilerUtil.ReadBCDOffset[]-offset];
    bcdHeader.ntOffset _ offset _ CompilerUtil.ReadBCDOffset[];
    IF anyNamed THEN TreeOps.ScanList[t, NameItem];	-- matches importCtx prefix
    bcdHeader.ntLimit _ LOOPHOLE[CompilerUtil.ReadBCDOffset[]-offset]};
    
    
-- writing export records

  maxEVLength: CARDINAL;
  evList: BcdOps.EVHandle;
  
  EnterEVOffset: PROC [offset: CARDINAL] RETURNS [index: CARDINAL] = {
    IF offset = 0 THEN index _ 0
    ELSE
      FOR index IN [1 .. evList.length] DO
	IF offset = evList.offsets[index] THEN EXIT;
	REPEAT
	  FINISHED => {
	    index _ evList.length _ evList.length + 1;
	    IF index <= maxEVLength THEN evList.offsets[index] _ offset};
	ENDLOOP;
    RETURN};
    
    
  TypeMap: TYPE = RECORD [SEQUENCE length: CARDINAL OF
    RECORD [opaque: BcdDefs.TMRecord, concrete: BcdDefs.TYPRecord]];
  typeMap: LONG POINTER TO TypeMap;
  mapIndex: CARDINAL;
  typeIndex: BcdDefs.TYPIndex;
  
  EnterType: PROC [mdi: MDIndex, offset: CARDINAL, sei: ISEIndex]
      RETURNS [typeId: BcdDefs.TYPIndex] = {
    entry: BcdDefs.TYPRecord = MakeTypeId[sei];
    IF typeMap = NIL OR mapIndex >= typeMap.length THEN AdjustTypeMap[8];
    FOR i: CARDINAL IN [0..mapIndex) DO
      IF typeMap[i].concrete = entry THEN GO TO matched;
      REPEAT
	matched => typeId _ typeMap[i].opaque.map;
	FINISHED => {typeId _ typeIndex; typeIndex _ typeIndex + SIZE[BcdDefs.TYPRecord]};
      ENDLOOP;
    typeMap[mapIndex] _ [
	opaque: [version: mdb[mdi].stamp, offset: offset, map: typeId],
	concrete: entry];
    mapIndex _ mapIndex + 1;
    RETURN};
    
  MakeTypeId: PROC [id: ISEIndex] RETURNS [BcdDefs.TYPRecord] = {
    sei: ISEIndex _ id;
    next: SEIndex;
    mdi: MDIndex;
    DO
      next _ seb[sei].idInfo;
      WITH seb[next] SELECT FROM
	id => sei _ LOOPHOLE[next];
	ENDCASE => EXIT;
      ENDLOOP;
    mdi _ MdiForCtx[seb[sei].idCtx];
    RETURN [[id: [seb[sei].idValue], version: mdb[mdi].stamp]]};
    
  AdjustTypeMap: PROC [delta: CARDINAL] = {
    oldN: CARDINAL = IF typeMap = NIL THEN 0 ELSE typeMap.length;
    newMap: LONG POINTER TO TypeMap = zone.NEW[TypeMap[oldN+delta]];
    FOR i: CARDINAL IN [0 .. oldN) DO newMap[i] _ typeMap[i] ENDLOOP;
    IF typeMap # NIL THEN zone.FREE[@typeMap];
    typeMap _ newMap};
    
  WriteTypeTable: PROC = {
    i, offset: CARDINAL;
    next: BcdDefs.TYPIndex _ FIRST[BcdDefs.TYPIndex];
    bcdHeader.typOffset _ offset _ CompilerUtil.ReadBCDOffset[];
    FOR i IN [0 .. mapIndex) DO
      FOR j: CARDINAL IN [0..i) DO
	IF typeMap[i].opaque.map = typeMap[j].opaque.map THEN EXIT
	REPEAT
	  FINISHED => {
	    CompilerUtil.AppendBCDWords[@typeMap[i].concrete, SIZE[BcdDefs.TYPRecord]];
	    next _ next + SIZE[BcdDefs.TYPRecord]};
	ENDLOOP;
      ENDLOOP;
    bcdHeader.typLimit _ LOOPHOLE[CompilerUtil.ReadBCDOffset[]-offset];
    bcdHeader.tmOffset _ offset _ CompilerUtil.ReadBCDOffset[];
    FOR i IN [0 .. mapIndex) DO
      CompilerUtil.AppendBCDWords[@typeMap[i].opaque, SIZE[BcdDefs.TMRecord]];
      ENDLOOP;
    bcdHeader.tmLimit _ LOOPHOLE[CompilerUtil.ReadBCDOffset[]-offset]};
    
    
  ExportId: Tree.Map = {
    expType: CSEIndex = P4.OperandType[t];
    ctx: IncludedCTXIndex;
    iBase: Types.SymbolTableBase;
    id, sei, iSei: ISEIndex;
    epN: CARDINAL;
    used: BOOLEAN;
    id _ TreeOps.GetSe[t];
    WITH v: seb[expType] SELECT FROM
      definition => {
	ctx _ LOOPHOLE[v.defCtx];
	iBase _ Copier.GetSymbolTable[ctxb[ctx].module];
	IF iBase # NIL THEN {
	  BEGIN
	  header: BcdDefs.EXPRecord _ [
		  name: EnterSymbolId[id],
		  size: 0,
		  port: interface,
		  namedInstance: FALSE,
		  typeExported: FALSE,
		  file: PortedCtx[v.defCtx],
		  links: ];
	  FOR iSei _ iBase.FirstCtxSe[ctxb[ctx].map], iBase.NextSe[iSei] UNTIL iSei = ISENull DO
	    SELECT iBase.LinkMode[iSei] FROM
	      val, ref => header.size _ header.size + 1;
	      type => {header.typeExported _ TRUE; header.size _ header.size + 1};
	      ENDCASE;
	    ENDLOOP;
	  CompilerUtil.AppendBCDWords[@header, SIZE[BcdDefs.EXPRecord]];
	  END;
	  used _ FALSE;  epN _ 0;
	  FOR iSei _ iBase.FirstCtxSe[ctxb[ctx].map], iBase.NextSe[iSei] UNTIL iSei = ISENull DO
	    mode: Linkage = iBase.LinkMode[iSei];
	    link: BcdLink _ BcdDefs.NullLink;
	      BEGIN
	      ss: SubStringDescriptor;
	      hti: HTIndex;
	      iBase.SubStringForHash[@ss, iBase.seb[iSei].hash];
	      hti _ FindString[@ss];
	      IF hti = HTNull THEN sei _ ISENull
	      ELSE {
		sei _ SearchContext[hti, dataPtr.mainCtx];
		IF sei = ISENull THEN sei _ SearchContext[hti, dataPtr.moduleCtx]};
	      END;
	    IF sei # SENull THEN {
	      public: BOOLEAN = seb[sei].public;
	      iType: CSEIndex = iBase.UnderType[iBase.seb[iSei].idType];
	      SELECT mode FROM
		val => {
		  IF ~Types.Assignable[
			[iBase, iType], [dataPtr.ownSymbols, UnderType[seb[sei].idType]]] THEN {
		    IF public THEN Log.ErrorSei[exportClash,sei]}
		  ELSE IF ~public AND seb[sei].idCtx = dataPtr.mainCtx THEN
		    Log.WarningSei[privateExport, sei];
		  IF public THEN {
		    IF ~seb[sei].constant OR seb[sei].extended THEN Log.ErrorSei[varExport, sei];
		    link _ IF XferMode[seb[sei].idType] = program
				THEN MakeFrameLink[ep:EnterEVOffset[0], gfi:OwnGfi]
				ELSE seb[sei].idValue}};
		ref => {
		  iTarget: CSEIndex _ iType;
		  iConst: BOOLEAN _ iBase.seb[iSei].immutable;
		  WITH t: iBase.seb[iType] SELECT FROM
		    ref =>
		      IF t.var THEN {iTarget _ iBase.UnderType[t.refType]; iConst _ t.readOnly}; 
		    ENDCASE;
		  IF ~Types.Equivalent[
			[iBase, iTarget], [dataPtr.ownSymbols, UnderType[seb[sei].idType]]] THEN {
		    IF public THEN Log.ErrorSei[exportClash,sei]}
		  ELSE IF ~public AND seb[sei].idCtx = dataPtr.mainCtx THEN
		    Log.WarningSei[privateExport, sei];
		  IF public THEN {
		    SELECT TRUE FROM
		      seb[sei].constant => Log.ErrorSei[varExport, sei];
		      seb[sei].immutable AND ~iConst => Log.ErrorSei[exportClash, sei];
		      ENDCASE;
		  link _ MakeFrameLink[
			   ep: EnterEVOffset[LOOPHOLE[seb[sei].idValue, BitAddress].wd],
			   gfi: OwnGfi]}};
		type =>
		  IF seb[sei].idType # typeTYPE OR TypeForm[sei] = opaque THEN {
		    IF public THEN Log.ErrorSei[exportClash, sei]}
		  ELSE {
		    iValue: CSEIndex = iBase.UnderType[iSei];
		    IF (~public AND seb[sei].idCtx = dataPtr.mainCtx) THEN
		      Log.WarningSei[privateExport, sei]
		    ELSE
		      WITH it: iBase.seb[iValue] SELECT FROM
			opaque =>
			  IF it.lengthKnown AND ~P4.DefaultBasicOps[sei, it.length] THEN
			    Log.ErrorSei[exportAttr, sei];
			ENDCASE => ERROR;
		    IF public THEN {
		      link _ MakeTypeLink[EnterType[ctxb[ctx].module, epN, sei]];
		      bcdHeader.typeExported _ TRUE}};
		manifest =>
		  IF public
		    AND (seb[sei].idType # typeTYPE OR iBase.seb[iSei].idType # typeTYPE) THEN
		     Log.WarningSei[voidExport, sei];
		ENDCASE};
	    IF link # BcdDefs.NullLink THEN used _ TRUE;
	    IF mode # manifest THEN {CompilerUtil.AppendBCDWord[link]; epN _ epN + 1};
	    ENDLOOP;
	Copier.FreeSymbolTable[iBase];
	IF ~used THEN Log.WarningSei[unusedExport, id]}};
      ENDCASE;
    RETURN [t]};
    
  ExportItem: Tree.Scan = {
    node: Tree.Index = TreeOps.GetNode[t];
    saveIndex: CARDINAL = dataPtr.textIndex;
    dataPtr.textIndex _ tb[node].info;
    tb[node].son[2] _ ExportId[tb[node].son[2]];
    dataPtr.textIndex _ saveIndex};
    
  ProcessExports: PUBLIC Tree.Map = {
    offset: CARDINAL;
    bcdHeader.nExports _ TreeOps.ListLength[t];
    bcdHeader.expOffset _ offset _ CompilerUtil.ReadBCDOffset[];
    maxEVLength _ PrincOps.MaxNGfi*VarLimit - 1;
    evList _ Heap.MakeNode[zone, SIZE[BcdDefs.EVRecord]+maxEVLength];
    evList^ _ [length:0, offsets:];
    typeIndex _ FIRST[BcdDefs.TYPIndex];  mapIndex _ 0;  typeMap _ NIL;
    TreeOps.ScanList[t, ExportItem];
    bcdHeader.expLimit _ LOOPHOLE[CompilerUtil.ReadBCDOffset[]-offset];
    bcdHeader.evOffset _ offset _ CompilerUtil.ReadBCDOffset[];
    IF evList.length > maxEVLength THEN Log.ErrorN[exportedVars, evList.length-maxEVLength];
    IF evList.length = 0 THEN dataPtr.mtRoot.variables _ BcdDefs.EVNull
    ELSE {
      dataPtr.mtRoot.ngfi _ MAX[dataPtr.mtRoot.ngfi, evList.length/VarLimit+1];
      dataPtr.mtRoot.variables _ FIRST[BcdDefs.EVIndex];
      CompilerUtil.AppendBCDWords[evList,
	  SIZE[BcdDefs.EVRecord] + MIN[evList.length, maxEVLength]]};
    bcdHeader.evLimit _ LOOPHOLE[CompilerUtil.ReadBCDOffset[]-offset];
    Heap.FreeNode[zone, evList];
    WriteTypeTable[];
    IF typeMap # NIL THEN zone.FREE[@typeMap];
    RETURN [t]};
    

-- initialization/finalization

  ProcessFiles: PROC = {
    ftEntry: BcdDefs.FTRecord;
    mdi: MDIndex;
    limit: MDIndex = (dataPtr.table).Top[mdType];

    EnterCanonicalFile: PROC [canonical: BOOLEAN, type: SEIndex] = {
      IF ~canonical THEN {
        mdi: MDIndex;
	[mdi, ] _  SymLiteralOps.UTypeId[type];
	IF mdi # MDNull THEN [] _ PortedFile[mdi]}};
	
    offset: CARDINAL = CompilerUtil.ReadBCDOffset[];
    FOR mdi _ lastPorted, mdi + SIZE[MDRecord] UNTIL mdi = limit DO
      IF mdb[mdi].file # NullFileIndex THEN
        [] _ PortedFile[mdi];	-- add any files opened during compilation
      ENDLOOP;
    bcdHeader.ftOffset _ offset;
    SymLiteralOps.EnumerateTypes[EnterCanonicalFile];
    FOR mdi _ firstPorted, mdi + SIZE[MDRecord] UNTIL mdi = lastPorted DO
      ftEntry _ [name: EnterFileId[mdi], version: mdb[mdi].stamp];
      CompilerUtil.AppendBCDWords[@ftEntry, SIZE[BcdDefs.FTRecord]];
      ENDLOOP;
    bcdHeader.ftLimit _ LOOPHOLE[CompilerUtil.ReadBCDOffset[] - offset]};
    
    
  InitBCD: PUBLIC PROC [ids: Tree.Link, scratchZone: UNCOUNTED ZONE] = {
    OPEN BcdDefs;
    nIds: CARDINAL;
    zone _ scratchZone;
    nIds _ TreeOps.ListLength[ids];
    IF nIds > 1 AND ~dataPtr.definitionsOnly THEN {Log.ErrorN[listLong, nIds-1]; nIds _ 1};
    lastPorted _ firstPorted;
    nString _ LOOPHOLE[zone.NEW[StringBody[64]]];
    -- allocate the null name
      nString.string.length _ BcdDefs.NullName;
      nString.size[BcdDefs.NullName] _ 0;
    mdb[OwnMdi].stamp _ dataPtr.objectVersion;	-- update from DIRECTORY processing
    CompilerUtil.StartBCD[];
    bcdHeader _ zone.NEW[BCD];
      bcdHeader.versionIdent _ VersionID;
      bcdHeader.version _ dataPtr.objectVersion;
      bcdHeader.creator _ dataPtr.compilerVersion;
      bcdHeader.sourceVersion _ dataPtr.source.version;
      bcdHeader.nConfigs _ 0;
      bcdHeader.nModules _ nIds;
      bcdHeader.nImports _ bcdHeader.nExports _ 0;
      bcdHeader.definitions _ dataPtr.definitionsOnly;
      bcdHeader.typeExported _ FALSE;
      bcdHeader.repackaged _ bcdHeader.tableCompiled _ FALSE;
      bcdHeader.versions _ FALSE;
      bcdHeader.extended _ TRUE;
      bcdHeader.spare1 _ TRUE;	-- large eval stack
      bcdHeader.spare2 _ FALSE;
      bcdHeader.ctOffset _ 0;  bcdHeader.ctLimit _ LOOPHOLE[0];
      bcdHeader.spOffset _ 0;  bcdHeader.spLimit _ LOOPHOLE[0];
      bcdHeader.fpOffset _ 0;  bcdHeader.fpLimit _ LOOPHOLE[0];
      nString.string.length _ nString.string.length + 1;
      bcdHeader.source _ NameRecord[nString.string.length];
	nString.size[bcdHeader.source] _ dataPtr.source.locator.length;
	Strings.AppendSubString[@nString.string, @dataPtr.source.locator];
    bcdOffset _ CompilerUtil.ReadBCDOffset[];
    CompilerUtil.AppendBCDWords[bcdHeader, SIZE[BCD]];
    dataPtr.fixupLoc _ CompilerUtil.ReadBCDIndex[];
    bcdHeader.sgOffset _ CompilerUtil.ReadBCDOffset[];
    CompilerUtil.AppendBCDWords[@dataPtr.codeSeg, SIZE[SGRecord]];
    CompilerUtil.AppendBCDWords[@dataPtr.symSeg, SIZE[SGRecord]];
    bcdHeader.mtOffset _ mtOffset _ CompilerUtil.ReadBCDOffset[];
    bcdHeader.sgLimit _ LOOPHOLE[mtOffset - bcdHeader.sgOffset];
    IF dataPtr.definitionsOnly THEN {
      dataPtr.mtRootSize _ SIZE[indirect BcdDefs.MTRecord];
      dataPtr.mtRoot _ Heap.MakeNode[zone, SIZE[indirect BcdDefs.MTRecord]];
      dataPtr.mtRoot.extension _ indirect[links: BcdDefs.LFNull]}
    ELSE {
      dataPtr.mtRootSize _ SIZE[multiple BcdDefs.MTRecord];
      dataPtr.mtRoot _ Heap.MakeNode[zone, SIZE[multiple BcdDefs.MTRecord]];
      dataPtr.mtRoot.extension _ multiple[
          links: FIRST[BcdDefs.LFIndex],
	  refLiterals: BcdDefs.RFNull,
	  types: BcdDefs.TFNull]};
    FOR i: CARDINAL IN [0..nIds) DO
      CompilerUtil.AppendBCDWords[dataPtr.mtRoot, dataPtr.mtRootSize]
      ENDLOOP;
    bcdHeader.lfOffset _ CompilerUtil.ReadBCDOffset[];
    bcdHeader.mtLimit _ LOOPHOLE[bcdHeader.lfOffset-bcdHeader.mtOffset]};
      
  FinishBCD: PUBLIC PROC [ids: Tree.Link] = {
    OPEN BcdDefs;
    PageSize: CARDINAL = Environment.wordsPerPage;
    Alignment: CARDINAL = 4;  -- Code Segments must start at 0 MOD Alignment
    nLinks: CARDINAL = dataPtr.linkCount;
    codeLinks: BOOLEAN = dataPtr.switches['l];
    gfType: RecordSEIndex = bb[RootBti].type;
    -- fill MTRecord
      IF TreeOps.ListLength[ids] > 1 THEN {	-- complete nString now

	EnterId: Tree.Scan = {[] _ EnterSymbolId[TreeOps.GetSe[t]]};

	TreeOps.ScanList[ids, EnterId]};
      dataPtr.mtRoot.name _ EnterSymbolId[bb[RootBti].id];
      dataPtr.mtRoot.namedInstance _ FALSE;
      dataPtr.mtRoot.initial _ ~dataPtr.switches['s];
      dataPtr.mtRoot.file _ dataPtr.codeSeg.file _ dataPtr.symSeg.file _ 
        PortedCtx[dataPtr.mainCtx];
      dataPtr.mtRoot.linkLoc _ IF codeLinks THEN code ELSE frame;
      dataPtr.mtRoot.config _ CTNull;
      dataPtr.mtRoot.code _ CodeDesc[
		sgi: FIRST[SGIndex],
		packed: FALSE, linkspace: codeLinks,
		offset: IF codeLinks AND nLinks # 0
		  THEN (nLinks+1) + (Alignment-1 - (nLinks MOD Alignment))
		  ELSE 0,
		length: 0];	-- will be updated
      dataPtr.mtRoot.sseg _ FIRST[SGIndex] + SIZE[SGRecord];
      dataPtr.mtRoot.frameRefs _ seb[gfType].hints.refField;
      dataPtr.mtRoot.frameType _
        IF seb[gfType].hints.refField THEN SymLiteralOps.TypeIndex[gfType] ELSE 0;
      dataPtr.mtRoot.framesize _ 0;	-- will be updated
      dataPtr.mtRoot.altoCode _  FALSE;
      dataPtr.mtRoot.tableCompiled _ FALSE;
      dataPtr.mtRoot.residentFrame _ passPtr.resident;
      dataPtr.mtRoot.boundsChecks _ dataPtr.switches['b];
      dataPtr.mtRoot.nilChecks _ dataPtr.switches['n];
      dataPtr.mtRoot.long _ dataPtr.switches['c];	-- compiled for Cedar
      dataPtr.mtRoot.crossJumped _ dataPtr.switches['j];
      dataPtr.mtRoot.packageable _ TRUE;
    ProcessFiles[];
    bcdHeader.ssOffset _ CompilerUtil.ReadBCDOffset[];
    CompilerUtil.AppendBCDString[@nString.string];
    bcdHeader.ssLimit _ LOOPHOLE[CompilerUtil.ReadBCDOffset[]-bcdHeader.ssOffset];
    IF dataPtr.definitionsOnly THEN bcdHeader.rtPages.relPageBase _ 0
    ELSE {
      CompilerUtil.FillBCDPage[];
      bcdHeader.rtPages.relPageBase _ CompilerUtil.ReadBCDOffset[]/PageSize;
      CompilerUtil.RTTableOut[dataPtr.table]};
    bcdHeader.nPages _ (CompilerUtil.ReadBCDOffset[] + (PageSize-1))/PageSize;
    bcdHeader.rtPages.pages _ bcdHeader.nPages - bcdHeader.rtPages.relPageBase;
    CompilerUtil.UpdateBCDWords[bcdOffset, bcdHeader, SIZE[BCD]];
    IF dataPtr.definitionsOnly AND TreeOps.ListLength[ids] > 1 THEN {
      offset: CARDINAL _ mtOffset;
      saveName: BcdDefs.NameRecord = dataPtr.mtRoot.name;
	
      UpdateMDEntry: Tree.Scan = {
	dataPtr.mtRoot.name _ EnterSymbolId[TreeOps.GetSe[t]];
	CompilerUtil.UpdateBCDWords[offset, dataPtr.mtRoot, dataPtr.mtRootSize];
	offset _ offset + dataPtr.mtRootSize};
	  
      offset _ mtOffset;  TreeOps.ScanList[ids, UpdateMDEntry];
      dataPtr.mtRoot.name _ saveName};
    CompilerUtil.EndBCD[];
    zone.FREE[@nString]; zone.FREE[@bcdHeader]; zone _ NIL};
    

  MatchBCD: PUBLIC PROC RETURNS [matched: BOOLEAN _ FALSE] = {
    oldSymbols: SymbolTable.Base _ Copier.MapSymbols[dataPtr.pattern];
    IF oldSymbols = NIL THEN
      Log.WarningSubString[fileName, @dataPtr.pattern.locator]
    ELSE {
      matched _ ReplOps.MatchedBodies[
	    [oldSymbols, RootBti], [dataPtr.ownSymbols, RootBti]
	! ReplOps.Unmatched => {
	    d: Strings.SubStringDescriptor;
	    id.stb.SubStringForHash[@d, id.stb.HashForSe[id.sei]];
	    SELECT attr FROM
	      strings => Log.WarningSubString[replString, @d];
	      id => Log.WarningSubString[replId, @d];
	      ENDCASE;
	    RESUME}];
      Copier.UnmapSymbols[oldSymbols]}};

  }.