DIRECTORY
Commander USING[CommandProc, Register],
GVBasics USING [MakeKey, Password],
GVNames,
IO,
IPConfig USING [validDomains, specialDomains],
IPName USING [LoadCacheFromName, NameState, NormalizeName],
Menus,
Process USING [Detach],
Rope,
UserCredentials USING [Get],
ViewerClasses,
ViewerOps,
ViewerIO USING [CreateViewerStreams, GetViewerFromStream];

FixArpaNames: CEDAR PROGRAM
IMPORTS Commander, GVBasics, GVNames, IO, IPConfig, IPName, Menus, Process, Rope, UserCredentials, ViewerIO, ViewerOps
SHARES GVNames--GetEntry-- =

BEGIN

out: IO.STREAM;
menu: Menus.Menu;
viewer: ViewerClasses.Viewer;
stop: BOOLEAN _ FALSE;
ABORTED: SIGNAL = CODE;

debug: BOOLEAN _ FALSE;
groupPattern: Rope.ROPE = "*.*";


BreakName: PROC[name: Rope.ROPE] RETURNS[sn, reg: Rope.ROPE] =
BEGIN
length: INT = name.Length[];
FOR i: INT DECREASING IN [0..length) DO
IF name.Fetch[i] = '. THEN RETURN[
sn: name.Substr[start: 0, len: i],
reg: name.Substr[start: i+1, len: length-(i+1)] ];
ENDLOOP;
RETURN[sn: NIL, reg: name];
END;

BreakNameAt: PROC[name: Rope.ROPE] RETURNS[left, right: Rope.ROPE] =
BEGIN
length: INT = name.Length[];
FOR i: INT DECREASING IN [0..length) DO
IF name.Fetch[i] = '@ THEN RETURN[
left: name.Substr[start: 0, len: i],
right: name.Substr[start: i+1, len: length-(i+1)] ];
ENDLOOP;
RETURN[left: NIL, right: NIL];
END;


Code: PROC[type: GVNames.Outcome] RETURNS[Rope.ROPE] =
{ RETURN[ SELECT type FROM
noChange => "no change",
group => "that's a group",
individual => "that's an individual",
notFound => "name not found",
protocolError => "protocol error",
wrongServer => "wrong server",
allDown => "all suitable servers are down or inaccessible",
badPwd => "incorrect password",
outOfDate => "out of date",
notAllowed => "you're not authorized to do that",
ENDCASE => "unknown return code" ] };


EnumInRegistry: PROC[pattern, registry: Rope.ROPE, work: EnumProc, out: IO.STREAM ] =
BEGIN
enumName: Rope.ROPE = Rope.Cat["Groups.",registry];
info: GVNames.MemberInfo = GVNames.GetMembers[enumName];
WITH info SELECT FROM
i: group GVNames.MemberInfo =>
BEGIN
FOR m: GVNames.RListHandle _ i.members, m.rest UNTIL m = NIL DO
sn: Rope.ROPE = BreakName[m.first].sn;
IF stop THEN SIGNAL ABORTED;
IF Rope.Match[pattern: pattern, object: sn, case: FALSE]
THEN { IF work[m.first] THEN EXIT };
ENDLOOP;
END;
ENDCASE =>
out.PutF["\nCouldn't get members of \"%g\": %g",
[rope[enumName]], [rope[Code[info.type]]] ];
END;

EnumProc: TYPE = PROC[name: Rope.ROPE] RETURNS[exit: BOOL _ FALSE];

EnumAllNames: PROC[pattern: Rope.ROPE, work: EnumProc, out: IO.STREAM] =
BEGIN
patternSN, patternReg: Rope.ROPE;
RegWork: EnumProc =
BEGIN
out.PutF["\n\n%t Enumerating names in %g . . .\n", IO.time[], [rope[name]] ];
EnumInRegistry[patternSN, BreakName[name].sn, work, out];
END;
[patternSN, patternReg] _ BreakName[pattern];
EnumInRegistry[patternReg, "GV", RegWork, out];
END;


RemoveMember: PROC[group, member: Rope.ROPE, out: IO.STREAM] RETURNS[ok: BOOLEAN _ FALSE] =
BEGIN
user: Rope.ROPE = UserCredentials.Get[].name;
pwd: GVBasics.Password = GVBasics.MakeKey[UserCredentials.Get[].password];
outcome: GVNames.Outcome =  GVNames.RemoveMember[user, pwd, group, member];
out.PutF["\n*** Removing %g from %g . . .  ", [rope[member]], [rope[group]]];
out.PutRope[IF outcome = group THEN "ok" ELSE Code[outcome]];
out.PutRope["\n\n"];
RETURN[outcome = group];
END;

AddMember: PROC[group, member: Rope.ROPE, out: IO.STREAM] RETURNS[ok: BOOLEAN _ FALSE] =
BEGIN
user: Rope.ROPE = UserCredentials.Get[].name;
pwd: GVBasics.Password = GVBasics.MakeKey[UserCredentials.Get[].password];
outcome: GVNames.Outcome =  GVNames.AddMember[user, pwd, group, member];
out.PutF["\n*** Adding %g to %g . . .  ", [rope[member]], [rope[group]]];
out.PutRope[IF outcome = group THEN "ok" ELSE Code[outcome]];
RETURN[outcome = group OR outcome = noChange];
END;


CheckGroups: PROC[pattern: Rope.ROPE, out: IO.STREAM] =
BEGIN
GroupWork: EnumProc = TRUSTED -- The silly compiler can't handle "info"
BEGIN
info: REF GVNames.GetEntryInfo;
rc: GVNames.NameType;
[rc, info] _ GVNames.GetEntry[name];
SELECT rc FROM
notFound => NULL;
group =>
WITH info^ SELECT FROM
i: group GVNames.GetEntryInfo =>
BEGIN
SubListWork[name, i.members.current];
END;
ENDCASE => ERROR;
ENDCASE =>
BEGIN
out.PutF["\nCouldn't read entry for \"%g\": %g",
[rope[name]], [rope[Code[rc]]] ];
exit _ TRUE;
END;
END;
SubListWork: PROC[group: Rope.ROPE, list: GVNames.RListHandle] =
BEGIN
UNTIL list = NIL DO
BEGIN
IF stop THEN SIGNAL ABORTED;

IF External[list.first] THEN {
left,right, new: Rope.ROPE _ NIL;
state: IPName.NameState; 
localDomain: BOOLEAN _ FALSE;

[left,right] _ BreakNameAt[list.first];

IF left#NIL AND right#NIL THEN {
localDomain _ LocalDomain[right];
IF ~localDomain THEN  {
state _ IPName.LoadCacheFromName[right, TRUE, FALSE];
IF state ~= down AND state ~= bogus THEN new _ IPName.NormalizeName[right];
};
};

SELECT TRUE FROM
localDomain =>  
out.PutF["%g is a member of %g\n", [rope[list.first]], [rope[group]]];

state = down => 
out.PutF["\n** Unable to load cache for %g on %g \n\n", [rope[list.first]], [rope[group]]];

state = bogus =>  {
out.PutF["\n*** %g is an invalid address on %g \n\n", [rope[list.first]], [rope[group]]]; 
IF debug THEN  out.PutF["\n%g would be removed from %g . . . \n", [rope[list.first]], [rope[group]]]
ELSE {
  IF ~RemoveMember[group, list.first, out] THEN 
    out.PutF["\n*** Failed to remove %g . . . \n\n", [rope[list.first]]]};
};

~Rope.Equal[right, new,FALSE] => {
IF ~ChangeName[list.first, Rope.Cat[left,"@",new], group, out] THEN
out.PutF["\n*** Failed to remove %g . . . \n\n", [rope[list.first]]];
};

ENDCASE => 
out.PutF["%g is a member of %g\n", [rope[list.first]], [rope[group]]];

};

list _ list.rest;
END;
ENDLOOP;
END;
EnumAllNames[pattern, GroupWork, out];
END;


ChangeName: PROC[oldName, newName, group: Rope.ROPE, out: IO.STREAM] RETURNS[ok: BOOLEAN] =
BEGIN
IF debug THEN {
out.PutF["\n** %g would be changed to %g . . . \n\n", [rope[oldName]], [rope[newName]]];
RETURN[TRUE]};

IF ~AddMember[group, newName, out] THEN RETURN[FALSE]
ELSE IF ~RemoveMember[group, oldName, out] THEN RETURN[FALSE];
RETURN[TRUE];
END;


LocalDomain: PROC[name: Rope.ROPE] RETURNS[BOOLEAN] =
BEGIN
FOR list: LIST OF Rope.ROPE _ IPConfig.specialDomains, list.rest UNTIL list = NIL DO
domain: Rope.ROPE _ list.first;
IF DotTailed[name, domain] THEN RETURN[TRUE];
ENDLOOP;
RETURN[FALSE];
END;


External: PROC[name: Rope.ROPE] RETURNS[BOOLEAN] =
BEGIN
IF Rope.Find[name,"@"] > -1 THEN RETURN[TRUE];
FOR list: LIST OF Rope.ROPE _ IPConfig.validDomains, list.rest UNTIL list = NIL DO
domain: Rope.ROPE _ list.first;
IF DotTailed[name, domain] THEN RETURN[TRUE];
ENDLOOP;
RETURN[FALSE];
END;

Tailed: PROC [body, tail: Rope.ROPE] RETURNS [match: BOOL] = {
bodyLength: INT = Rope.Length[body];
tailLength: INT = Rope.Length[tail];
back: Rope.ROPE;
IF bodyLength <= tailLength THEN RETURN[FALSE];
back _ Rope.Substr[body, bodyLength-tailLength, tailLength];
IF ~Rope.Equal[back, tail, FALSE] THEN RETURN[FALSE];
RETURN[TRUE]; };

DotTailed: PROC [body, tail: Rope.ROPE] RETURNS [match: BOOL] = {
IF ~Tailed[body, tail] THEN RETURN[FALSE];
IF Rope.Fetch[body, Rope.Length[body]-Rope.Length[tail]-1] # '. THEN RETURN[FALSE];
RETURN[TRUE]; };


ReallyDoit: PROC = {
out.PutRope["Checking Arpanet names on Grapevine DLs. . ."];
IF debug THEN out.PutRope["Debugging mode . . ."];
CheckGroups[pattern: groupPattern, out: out ! ABORTED => {out.PutRope["\n\nAborted.\n"]; GOTO Exit}]; 
out.PutRope["\n\nFinished\n"];
EXITS
Exit =>{};
};

DoitHit: Menus.MenuProc = TRUSTED {
stop _ FALSE;
Process.Detach[FORK ReallyDoit[]] ;
};


StopHit: Menus.MenuProc = TRUSTED {
stop _ TRUE;
};

SaveHit: Menus.MenuProc = TRUSTED {
IO.Flush[out];
IO.Close[out];
};




log: Rope.ROPE _ "///Mail/FixArpaNames.log";

MakeTool: Commander.CommandProc =
TRUSTED{ 
out _ ViewerIO.CreateViewerStreams["FixArpaNames",,log].out;
viewer _ ViewerIO.GetViewerFromStream[out];
menu _ viewer.menu;

Menus.InsertMenuEntry[menu: menu, line: 0, entry: Menus.CreateEntry[name: "SaveLog", proc: SaveHit, clientData: NIL]];
Menus.InsertMenuEntry[menu: menu, line: 0, entry: Menus.CreateEntry[name: "Doit", proc: DoitHit, clientData: NIL]];
Menus.InsertMenuEntry[menu: menu, line: 0, entry: Menus.CreateEntry[name: "STOP!", proc: StopHit, clientData: NIL]];
ViewerOps.PaintViewer[viewer, menu];
};


Commander.Register[key: "FixArpaNames", proc: MakeTool,
doc: "Fixes up Arpanet names in Grapevine DLs"];

END.
¦FixArpaNames.mesa
Copyright c 1985 by Xerox Corporation.  All rights reserved.
John Larson, July 12, 1987 2:33:08 am PDT
Sharon Johnson, June 29, 1987 3:05:32 pm PDT


Fixup Arpanet names in Grapevine DLs
Note: This program can only be run on the machine running the Arpanet mail gateway right now. (Uses NormalizeName and LoadCacheFromName from IPName, and IPConfig) 

[parent: REF, clientData: REF, mouseButton: MouseButton, shift, control: BOOL]
[parent: REF, clientData: REF, mouseButton: MouseButton, shift, control: BOOL]
[parent: REF, clientData: REF, mouseButton: MouseButton, shift, control: BOOL]
[cmd: Handle] RETURNS [result: REF _ NIL, msg: Rope.ROPE _ NIL]
Κ˜Jš
œ™Jšœ
Οm
œ1™<™)Icode™,K™—J™Jš
œ$™$Jš
ϣ
™£
J™š
Οk	˜	Jšœ
žœ˜'Jšœ	žœ˜#J˜Jšžœ
˜Jšœ	žœ ˜.Jšœžœ/˜;J˜Jšœžœ
˜Jš
œ˜Jšœžœ˜J˜Jš
œ
˜
Jšœ	žœ,˜:—J˜šΟnœžœ
ž˜JšžœžœN˜vJšžœΟcœ˜—J˜Jš
ž˜J˜Jšœžœ
žœ
˜Jš
œ˜J˜Jšœžœžœ
˜Jšžœžœžœ
˜J˜Jšœžœžœ
˜Jšœžœ	˜ J˜K˜š
Ÿ	œžœžœžœžœ˜>Jš
ž˜Jšœžœ˜š	žœžœ
ž
œ
žœ
ž˜'šžœžœ
žœ
˜"Jš
œ"˜"Jš
œ2˜2—Jšžœ
˜—Jšžœžœ
˜Jšžœ
˜—J˜š
Ÿœžœžœžœžœ˜DJš
ž˜Jšœžœ˜š	žœžœ
ž
œ
žœ
ž˜'šžœžœ
žœ
˜"Jš
œ$˜$Jš
œ4˜4—Jšžœ
˜—Jšžœžœ	žœ˜Jšžœ
˜—J˜J˜šŸœžœžœžœ˜6šœžœžœž˜Jš
œ˜Jš
œ˜Jš
œ%˜%Jš
œ˜Jš
œ"˜"Jš
œ˜Jš
œ;˜;Jš
œ˜Jš
œ˜Jš
œ1˜1Jšžœ˜%——J˜J˜š
Ÿœžœžœžœ
žœ˜UJš
ž˜Jšœžœ ˜3J˜8šžœžœ
ž˜˜Jš
ž˜Jšžœ,žœžœ
ž˜?Jšœ	žœ˜&Jšžœžœ
žœ
žœ
˜Jšžœ0žœ
˜8šžœžœžœ
žœ˜$Jšžœ
˜—Jšžœ
˜——šžœ˜
š
œ0˜0Jš
œ,˜,——Jšžœ
˜—J˜Jš
œ
žœžœžœžœžœžœ˜CJ˜š
Ÿœžœžœžœ
žœ˜HJš
ž˜Jšœžœ
˜!šŸœ˜Jš
ž˜Jšœ3žœ˜MJ˜9Jšžœ
˜—J˜-J˜/Jšžœ
˜—J˜J˜šŸœžœžœžœ
žœžœžœžœ˜[Jš
ž˜Jšœžœ˜-Jš
œJ˜JJš
œK˜KJš
œM˜MJšœžœžœžœ˜=Jš
œ˜Jšžœ˜Jšžœ
˜J˜—šŸ	œžœžœžœ
žœžœžœžœ˜XJš
ž˜Jšœžœ˜-Jš
œJ˜JJš
œH˜HJš
œI˜IJšœžœžœžœ˜=Jšžœžœ˜.Jšžœ
˜J˜—J˜š
Ÿœžœžœžœ
žœ˜7Jš
ž˜šŸ	œ
žœ
 )˜GJš
ž˜Jšœžœ˜Jš
œ˜Jš
œ$˜$šžœž˜Jšœžœ
˜˜šžœžœ
ž˜š
œ ˜ Jš
ž˜J˜%Jšžœ
˜—Jšžœžœ
˜——šžœ˜
Jš
ž˜š
œ0˜0Jš
œ!˜!—Jšœžœ
˜Jšžœ
˜——Jšžœ
˜JšŸœžœ
žœ˜@Jš
ž˜šžœžœ
ž˜Jš
ž˜Jšžœžœ
žœ
žœ
˜J˜šžœžœ˜Jšœžœžœ
˜!Jš
œ˜Jšœ
žœžœ
˜J˜Jš
œ'˜'J˜š
žœžœ
žœžœ
žœ˜ Jš
œ!˜!šžœžœ˜Jšœ(žœžœ˜5Jšžœžœžœ&˜N—Jš
œ˜—šžœ
žœ
ž˜š
œ˜Jš
œF˜FJ˜—š
œ˜Jš
œ[˜[—J˜š
œ˜š
œZ˜ZJšžœžœW˜dJšžœ˜Jšœžœ'žœ
˜0Jš
œJ˜JJš
œ˜J˜——šœžœ˜"šžœ=ž˜CJš
œE˜E—˜J˜——šžœ˜Jš
œF˜F——Jš
œ˜Jš
œ˜Jšžœ
˜—Jšžœ
˜—Jšžœ
˜—Jš
œ&˜&Jšžœ
˜—J˜J˜šŸ
œžœžœžœ
žœžœžœ˜[Jš
ž˜šžœžœ˜J˜XJšžœ
žœ˜—Jšžœ!žœ
žœ
žœ
˜5Jš
žœ
žœ$žœ
žœ
žœ˜>Jšžœ
žœ˜
šžœ
˜J˜J˜——š
Ÿœžœžœžœ
žœ˜5Jš
ž˜š
žœžœ
žœžœ&žœžœ
ž˜TJšœ
žœ˜Jšžœžœ
žœ
žœ˜-Jšžœ
˜—Jšžœ
žœ˜Jšžœ
˜J˜—J˜š
Ÿœžœžœžœ
žœ˜2Jš
ž˜Jšžœžœ
žœ˜.š
žœžœ
žœžœ$žœžœ
ž˜RJšœ
žœ˜Jšžœžœ
žœ
žœ˜-Jšžœ
˜—Jšžœ
žœ˜Jšžœ
˜—J˜
code2š
Ÿœžœžœžœ	žœ˜>Jšœžœ˜$Jšœžœ˜$Jšœžœ
˜Jšžœžœ
žœ
žœ˜/Jš
œ<˜<Jš
žœžœžœ
žœ
žœ˜5Jšžœ
žœ˜J˜—š
Ÿ	œžœž	œžœ	žœ˜AJšžœžœ
žœ
žœ˜*Jšžœ>žœ
žœ
žœ˜SJšžœ
žœ˜J˜—J˜šŸ
œžœ˜J˜<Jšžœžœ%˜2Jšœ.žœ$žœ	˜fJš
œ˜Jš
ž˜Jš
œ
˜
J˜—šΠbnœžœ˜#Kš
œN™NKšœžœ
˜
Kšœžœ˜#Kš
œ˜K˜—J˜š‘œžœ˜#Kš
œN™NKšœžœ
˜Kš
œ˜K˜—š‘œžœ˜#Kš
œN™NKšžœ˜Kšžœ˜Kš
œ˜K˜K˜K˜K˜—šœ
žœ˜,K˜—šŸœ˜!Jšœžœ
žœžœžœžœ
™?Jšžœ˜	Jš
œ<˜<Jš
œ+˜+Jš
œ˜J˜Jšœpžœ˜vJšœmžœ˜sJšœnžœ˜tJš
œ$˜$š
œ˜J˜—J˜—š
œ7˜7J˜0J˜—Jšžœ
˜—…—!/»