JaMIViewerImpl.mesa
Last change by Bill Paxton, October 5, 1982 3:19 pm
Last change by McGregor, June 15, 1982 10:05 am
Last Edited by: Stone, September 6, 1984 3:53:00 pm PDT
DIRECTORY
Imager,
Rope USING [Concat],
TIPUser USING [InstantiateNewTIPTable, TIPScreenCoords],
Menus USING [Menu, MenuProc, CreateEntry, CreateMenu, InsertMenuEntry],
ViewerClasses USING [Viewer, ViewerClass, ViewerClassRec, NotifyProc],
ViewerOps USING [DestroyViewer, RegisterViewerClass, CreateViewer, PaintViewer],
JaM USING [State, SetAbort, Register, PushReal, Execute, ExecuteRope, Stop],
JaMImager,
JaMIPrivate,
JaMImagerContexts,
MessageWindow USING [Blink, Append];
JaMIViewerImpl:
CEDAR MONITOR
LOCKS info USING info:JaMIPrivate.Info
IMPORTS Imager, JaMIPrivate, Rope, MessageWindow, TIPUser, Menus, ViewerOps, JaM
EXPORTS JaMImager, JaMIPrivate, JaMImagerContexts =
BEGIN
jamImagerClass: ViewerClasses.ViewerClass ←
NEW[ViewerClasses.ViewerClassRec ← [
paint: JaMIPrivate.Paint,
notify: InputNotify,
destroy: AboutToDestroy,
tipTable: TIPUser.InstantiateNewTIPTable["JaMImager.TIP"]
]];
Info: TYPE = JaMIPrivate.Info;
JReloadTIP: PROC [state: State] = { ReloadTIP[] };
ReloadTIP:
PUBLIC
PROC = {
jamImagerClass.tipTable ← TIPUser.InstantiateNewTIPTable["JaMImager.TIP"] };
Create:
PUBLIC
PROC [state: State, typescript: ViewerClasses.Viewer, iconic:
BOOLEAN ←
FALSE]
RETURNS [viewer: ViewerClasses.Viewer] = {
info: Info;
menu: Menus.Menu;
{ -- extra block to make info defined in scope of UNWIND
ENABLE
UNWIND =>
-- something went wrong while creating the viewer
IF viewer#NIL THEN DestroyViewer[viewer]
ELSE IF info#NIL THEN JaMIPrivate.ForgetInfo[state];
IF (info ← JaMIPrivate.GetInfo[state]) # NIL THEN ERROR;
info ← JaMIPrivate.CreateInfo[state];
info.trajectory ← NIL;
info.font ← Imager.MakeFont["Xerox/PressFonts/Tioga/MRR", 10];
info.text ← NIL;
menu ← Menus.CreateMenu[];
Menus.InsertMenuEntry[menu, Menus.CreateEntry["Reset", Reset]];
Menus.InsertMenuEntry[menu, Menus.CreateEntry["Interrupt", InterruptButton]];
info.typescript ← typescript;
info.vdc ← Imager.Create[deviceType: $LFDisplay];
info.venabled ← TRUE;
viewer ← ViewerOps.CreateViewer[flavor: $JaMImager, info: [data: info,
name: Rope.Concat[typescript.name,"Imager "], menu: menu, iconic: iconic, scrollable: FALSE]];
info.viewer ← viewer;
Register[state];
JaMIPrivate.RegisterGraphics[state];
JaMIPrivate.RegisterImager[state];
JaMIPrivate.RegisterColor[state];
JaMIPrivate.RegisterAIS[state];
}};
Reset: Menus.MenuProc = {
viewer: ViewerClasses.Viewer ← NARROW[parent];
ViewerOps.PaintViewer[viewer: viewer, hint: client, whatChanged: NIL, clearClient: TRUE];
};
InterruptButton: Menus.MenuProc = {
viewer: ViewerClasses.Viewer ← NARROW[parent];
info: Info ← NARROW[viewer.data];
state: State ← info.state;
JaM.SetAbort[state,TRUE];
SetPlace[info,0,0];
SetBug[info,0,0] };
DestroyViewer:
PROC [viewer: ViewerClasses.Viewer] = {
AboutToDestroy[viewer];
ViewerOps.DestroyViewer[viewer];
};
AboutToDestroy:
PROC [self: ViewerClasses.Viewer] = {
info: Info ← NARROW[self.data];
JaMIPrivate.ForgetInfo[info.state];
};
InitDC:
PROCEDURE [state: State] = {
info: Info ← JaMIPrivate.GetInfo[state];
IF info.venabled
THEN {
Imager.Reset[info.vdc];
Imager.ConcatT[info.vdc, Imager.pointsToMeters];
};
FOR l: JaMImagerContexts.DCList ← info.dcList, l.next
UNTIL l=
NIL
DO
IF l.enabled THEN l.dc ← l.callMe[l.dc, initdc];
ENDLOOP;
};
EnableViewer:
PUBLIC PROC [state: State] = {
JaMIPrivate.GetInfo[state].venabled ← TRUE;
};
DisableViewer:
PUBLIC PROC [state: State] = {
JaMIPrivate.GetInfo[state].venabled ← FALSE;
};
Mouse:
PROC [state: State] = {
x,y: REAL;
[x,y] ← GetPlace[JaMIPrivate.GetInfo[state]];
JaM.PushReal[state, x];
JaM.PushReal[state, y]
};
Touch:
PROC [state: State] = {
x,y: REAL;
[x,y] ← GetBug[JaMIPrivate.GetInfo[state]];
JaM.PushReal[state, x];
JaM.PushReal[state, y]
};
GetBug:
ENTRY
PROC [info: Info]
RETURNS[x,y:
REAL] = {
OPEN info;
ENABLE UNWIND => NULL;
bugflag ← FALSE;
UNTIL viewer.destroyed OR bugflag DO WAIT bugged ENDLOOP;
IF viewer.destroyed THEN x ← y ← 0
ELSE { x ← bugX; y ← bugY; bugflag ← FALSE };
};
SetBug:
PUBLIC
ENTRY
PROC [info: Info, x,y:
REAL] = {
OPEN info;
ENABLE UNWIND => NULL;
bugflag ← TRUE; bugX ← x; bugY ← y;
NOTIFY bugged };
GetPlace:
ENTRY
PROC [info: Info]
RETURNS[x,y:
REAL] = {
OPEN info;
ENABLE UNWIND => NULL;
mouseflag ← FALSE;
UNTIL viewer.destroyed OR mouseflag DO WAIT mouse ENDLOOP;
IF viewer.destroyed THEN x ← y ← 0
ELSE { x ← mouseX; y ← mouseY; mouseflag ← FALSE };
};
SetPlace:
ENTRY
PROC [info: Info, x,y:
REAL] = {
OPEN info;
ENABLE UNWIND => NULL;
mouseflag ← TRUE; mouseX ← x; mouseY ← y; NOTIFY mouse;
};
DoAtom: PROC [state: State, atom: ATOM] = {
generic proc for TIP atoms. Normal TIP table never comes here
JaM.Execute[state, atom ! JaM.Stop => CONTINUE];
};
DoButton: PROC [state: State, button: ATOM, x,y: REAL] = {
all the *Down, *Up and *Track atoms
JaM.PushReal[state, x];
JaM.PushReal[state, y];
SELECT button
FROM
$RedDown, $CtrlRedDown,
$ShiftRedDown, $CtrlShiftRedDown => JaM.ExecuteRope[state,".reddown" ! JaM.Stop => CONTINUE];
$YellowDown, $CtrlYellowDown,
$ShiftYellowDown, $CtrlShiftYellowDown => JaM.ExecuteRope[state,".yellowdown" ! JaM.Stop => CONTINUE];
$BlueDown, $CtrlBlueDown,
$ShiftBlueDown, $CtrlShiftBlueDown => JaM.ExecuteRope[state,".bluedown" ! JaM.Stop => CONTINUE];
$Track, $CtrlTrack,
$ShiftTrack, $CtrlShiftTrack => JaM.ExecuteRope[state,".track" ! JaM.Stop => CONTINUE];
$RedUp, $CtrlRedUp,
$ShiftRedUp, $CtrlShiftRedUp => JaM.ExecuteRope[state,".redup" ! JaM.Stop => CONTINUE];
$YellowUp, $CtrlYellowUp,
$ShiftYellowUp, $CtrlShiftYellowUp => JaM.ExecuteRope[state,".yellowup" ! JaM.Stop => CONTINUE];
$BlueUp, $CtrlBlueUp,
$ShiftBlueUp, $CtrlShiftBlueUp => JaM.ExecuteRope[state,".blueup" ! JaM.Stop => CONTINUE];
ENDCASE => ERROR;
};
[self: ViewerClasses.Viewer, input: LIST OF REF ANY]
InputNotify:
PUBLIC ViewerClasses.NotifyProc = {
AdjustCoords:
PROC = {
info: Info ← NARROW[self.data];
[x,y] ← JaMIPrivate.ViewToUser[info.vdc, mx,my];
};
mx, my: INTEGER;
x, y: REAL;
FOR l:
LIST
OF
REF
ANY ← input, l.rest
UNTIL l =
NIL
DO
WITH l.first
SELECT
FROM
z:
ATOM =>
SELECT z
FROM
$RedDown, $CtrlRedDown, $ShiftRedDown, $CtrlShiftRedDown => {
info: Info ← NARROW[self.data,Info];
SetBug[info,x,y];
SetPlace[info,x,y];
DoButton[info.state,z,x,y];
};
$YellowDown, $CtrlYellowDown, $ShiftYellowDown, $CtrlShiftYellowDown,
$BlueDown, $CtrlBlueDown, $ShiftBlueDown, $CtrlShiftBlueDown,
$Track, $CtrlTrack, $ShiftTrack, $CtrlShiftTrack,
$RedUp, $CtrlRedUp, $ShiftRedUp, $CtrlShiftRedUp,
$YellowUp, $CtrlYellowUp, $ShiftYellowUp, $CtrlShiftYellowUp,
$BlueUp, $CtrlBlueUp, $ShiftBlueUp, $CtrlShiftBlueUp =>
DoButton[NARROW[self.data,Info].state,z,x,y];
$Place => SetPlace[NARROW[self.data,Info],x,y];
ENDCASE => DoAtom[NARROW[self.data,Info].state,z];
z: TIPUser.TIPScreenCoords => { [mx, ----, my] ← z^; AdjustCoords[] };
ENDCASE => {
MessageWindow.Blink[];
MessageWindow.Append["unknown TIP Atom (JaMImager)", TRUE];
};
ENDLOOP;
};
Register:
PROC[state: State] = {
JaM.Register[state,".initdc",InitDC];
JaM.Register[state,".reloadTIP",JReloadTIP];
JaM.Register[state,".enableviewer",EnableViewer];
JaM.Register[state,".disableviewer",DisableViewer];
JaM.Register[state,".mouse", Mouse];
JaM.Register[state,".touch",Touch];
};
ViewerOps.RegisterViewerClass[$JaMImager, jamImagerClass];
END...