Flat:
PROC[v1, v2, v3: Pair, epsilon:
REAL]
RETURNS[b:
BOOL] = {
Three point flatness test.
dx, dy: REAL;
d1, d, bl, bh: Pair;
oh: Pair = [0.5, 0.5];
bh ← Add[Max[v1, v3], oh];
bl ← Sub[Min[v1, v3], oh];
IF NOT In[v2, bl, bh] THEN RETURN[FALSE];
d1 ← Sub[v2, v1];
d ← Sub[v3, v1];
dx ← ABS[d.x]; dy ← ABS[d.y];
IF dx + dy < 1 THEN RETURN[TRUE];
IF dy < dx THEN { dydx: REAL ← d.y / d.x; RETURN[ABS[d1.y - d1.x * dydx] < epsilon] }
ELSE { dxdy: REAL ← d.x / d.y; RETURN[ABS[d1.x - d1.y * dxdy] < epsilon] };
};
GenerateStroke:
PUBLIC
PROC[
gen: PROC[move: PROC[Pair], line: PROC[Pair], curve: PROC[Pair, Pair, Pair]],
T: Transformation, width: REAL, closed: BOOLEAN, ends: StrokeEnds,
move: PROC[Pair], line: PROC[Pair], curve: PROC[Pair, Pair, Pair]
] = {
map: PROC[p: Pair] RETURNS[Pair] = INLINE { RETURN[IPTransform.Transform[T, p]] };
h: REAL = ABS[width]/2; -- half width
hsq: REAL = h*h;
smallSin: REAL = 0.001*hsq;
SegType: TYPE = {line, curve};
type: SegType; -- is current segment a line or curve?
b0, b1, b2, b3: Pair; -- control points for current segment
u0, u3: Pair; -- half width normal vectors at b0, b3
p0, q0, p3, q3: Pair; -- corners of stroke boundary for current segment
MiterFlags: TYPE = RECORD[p, q: BOOLEAN];
m0, m3: MiterFlags;
fb0, fb1, fb2, fb3, fu0, fu3, fp3, fq3: Pair; -- saved values for deferred segment
ftype: SegType; fm3: MiterFlags; -- ditto
begin, defer: BOOLEAN;
Cap:
PROC[b, d, p, q: Pair] = {
SELECT ends
FROM
butt => { };
square => {
v0: Pair ← [b.x-d.y, b.y+d.x];
v3: Pair ← [b.x+d.y, b.y-d.x];
v1: Pair ← [v0.x+d.x, v0.y+d.y];
v2: Pair ← [v3.x+d.x, v3.y+d.y];
move[p]; line[map[v1]]; line[map[v2]]; line[q];
};
round => {
tolerance: REAL = 1.0;
bz: Bezier;
v0, v1, v2, v3: Pair;
f: REAL = 0.5522848; -- 4*(sqrt2-1)/3
a: Pair ← [f*d.x, f*d.y];
v0 ← [b.x-d.y, b.y+d.x];
v3 ← [b.x+d.x, b.y+d.y];
v1 ← [v0.x+a.x, v0.y+a.y];
v2 ← [v3.x-a.y, v3.y+a.x];
bz.b0 ← p; bz.b1 ← map[v1]; bz.b2 ← map[v2]; bz.b3 ← map[v3];
move[p]; Subdivide[bz, line, tolerance];
v0 ← v3;
v3 ← [b.x+d.y, b.y-d.x];
v1 ← [v0.x+a.y, v0.y-a.x];
v2 ← [v3.x+a.x, v3.y+a.y];
bz.b0 ← bz.b3; bz.b1 ← map[v1]; bz.b2 ← map[v2]; bz.b3 ← q;
Subdivide[bz, line, tolerance];
};
ENDCASE => ERROR;
};
HNormal:
PROC[a, b: Pair]
RETURNS[Pair] = {
returns a vector of length halfWidth normal to the direction from a to b
d: Pair ← Sub[b, a];
u: Pair ← Normalize[d];
RETURN[[-u.y*h, u.x*h]];
};
ComputeP: PROC[b, u: Pair] RETURNS[Pair] = INLINE { RETURN[map[[b.x+u.x, b.y+u.y]]] };
ComputeQ: PROC[b, u: Pair] RETURNS[Pair] = INLINE { RETURN[map[[b.x-u.x, b.y-u.y]]] };
tolerance: REAL = 1.0;
DoCurve:
PROC[b0, b1, b2, b3: Pair, p0, p3: Pair, depth:
NAT ← 0] = {
b01: Pair = Midpoint[b0, b1];
b12: Pair = Midpoint[b1, b2];
b23: Pair = Midpoint[b2, b3];
b11: Pair = Midpoint[b01, b12];
b22: Pair = Midpoint[b12, b23];
bm: Pair = Midpoint[b11, b22]; -- middle point on curve (at t=1/2)
um: Pair = HNormal[b11, b22]; -- half width normal at bm
pm: Pair = map[Add[bm, um]]; -- point on stroke edge
IF depth>0
-- always divide at least once --
AND Flat[p0, pm, p3, tolerance] THEN line[p3]
ELSE {
DoCurve[b0, b01, b11, bm, p0, pm, depth+1]; -- first half
DoCurve[bm, b22, b23, b3, pm, p3, depth+1]; -- second half
};
};
EmitSegment:
PROC = {
IF NOT m0.p THEN p0 ← ComputeP[b0, u0];
IF NOT m0.q THEN q0 ← ComputeQ[b0, u0];
IF NOT m3.p THEN p3 ← ComputeP[b3, u3];
IF NOT m3.q THEN q3 ← ComputeQ[b3, u3];
move[p0];
IF type=line THEN line[p3] ELSE DoCurve[b0, b1, b2, b3, p0, p3];
line[q3];
IF type=line THEN line[q0] ELSE DoCurve[b3, b2, b1, b0, q3, q0];
};
EmitPreviousSegment:
PROC[u4: Pair, miter:
BOOLEAN ←
TRUE] = {
IF begin
THEN {
IF closed
THEN {
fb0 ← b3; fu0 ← u4;
defer ← TRUE }
ELSE {
u3 ← u4;
p3 ← ComputeP[b3, u3]; q3 ← ComputeQ[b3, u3];
m3 ← [TRUE,TRUE];
Cap[b3, [-u3.y, u3.x], q3, p3];
defer ← FALSE };
begin ← FALSE }
ELSE {
IF miter
THEN {
sin: REAL ← u3.x*u4.y-u3.y*u4.x;
IF
ABS[sin]<smallSin
THEN {
cos: REAL ← u3.x*u4.x+u3.y*u4.y;
IF cos>0
THEN {
p3 ← ComputeP[b3, u3]; q3 ← ComputeQ[b3, u3];
m3 ← [TRUE,TRUE] }
ELSE m3 ← [FALSE,FALSE];
}
ELSE {
f: REAL ← hsq/sin;
r: Pair ← [f*(u4.y-u3.y), f*(u3.x-u4.x)];
IF sin<0 THEN { p3 ← map[[b3.x+r.x, b3.y+r.y]]; m3 ← [p: TRUE, q: FALSE] }
ELSE { q3 ← map[[b3.x-r.x, b3.y-r.y]]; m3 ← [p: FALSE, q: TRUE] };
};
}
ELSE m3 ← [FALSE,FALSE];
IF defer
THEN {
fb1 ← b1; fb2 ← b2; fb3 ← b3; ftype ← type;
fu3 ← u3; fp3 ← p3; fq3 ← q3; fm3 ← m3;
defer ← FALSE }
ELSE EmitSegment[];
};
b0 ← b3; u0 ← u4; p0 ← p3; q0 ← q3; m0 ← m3;
};
started: BOOL ← FALSE;
Move:
PROC[v: Pair] = {
IF started THEN Close[] ELSE started ← TRUE;
b3 ← v; begin ← TRUE;
};
Line:
PROC[v: Pair] = {
u0: Pair;
IF NOT started THEN Move[[0,0]];
EmitPreviousSegment[u0 ← HNormal[b3, v]];
b3 ← v; u3 ← u0; type ← line;
};
Curve:
PROC[v1, v2, v3: Pair] = {
u0: Pair;
IF NOT started THEN Move[[0,0]];
EmitPreviousSegment[u0 ← IF v1#b3 THEN HNormal[b3, v1] ELSE HNormal[b3, v2]];
b1 ← v1; b2 ← v2; b3 ← v3; type ← curve;
u3 ← (IF b2#b3 THEN HNormal[b2, b3] ELSE HNormal[b1, b2]);
};
Close:
PROC = {
IF begin
THEN {
trajectory is a single point
IF closed THEN { --ignore-- }
ELSE {
-- just pick an arbitrary direction for end caps
u3 ← [0, h];
p3 ← ComputeP[b3, u3];
q3 ← ComputeQ[b3, u3];
Cap[b3, [-h, 0], q3, p3];
Cap[b3, [h, 0], p3, q3];
};
}
ELSE
IF closed
THEN {
IF b3#fb0 THEN Line[fb0]; -- if necessary, extend a line to the first point
EmitPreviousSegment[fu0]; -- emit the segment ending at the first point
b1 ← fb1; b2 ← fb2; b3 ← fb3; type ← ftype;
u3 ← fu3; p3 ← fp3; q3 ← fq3; m3 ← fm3;
EmitSegment[]; -- emit the deferred first segment
}
ELSE { EmitPreviousSegment[u3, FALSE]; Cap[b3, [u3.y, -u3.x], p3, q3] };
};
gen[Move, Line, Curve];
IF started THEN Close[];
};