
    <<CorePropertiesImpl.mesa>>
        <<Copyright © 1985 by Xerox Corporation.  All rights reserved.>>
        <<Bertrand Serlet, March 16, 1987 11:01:17 pm PST>>
        <<Barth, September 24, 1986 9:49:13 am PDT>>
        <<Spreitzer, August 8, 1985 3:12:59 pm PDT>>
        <<Pradeep Sindhu February 7, 1986 5:06:44 pm PST>>
        <<Last Edited by: Louis Monier January 16, 1987 1:13:09 pm PST>>

    DIRECTORY
        Commander, Core, CoreClasses, CoreOps, CoreProperties, HashTable, IO, ProcessProps, Properties;

    CorePropertiesImpl: CEDAR PROGRAM 
        IMPORTS CoreOps, HashTable, IO, ProcessProps, ImplementationProperties: Properties 
        EXPORTS CoreProperties
        SHARES Core =
        BEGIN OPEN CoreProperties;

        CellClass: TYPE = Core.CellClass;
        CellType: TYPE = Core.CellType;
        Wire: TYPE = Core.Wire;
        ROPE: TYPE = Core.ROPE;
        Properties: TYPE = Core.Properties;

        propTable: HashTable.Table _ HashTable.Create[];
            <<Global table for putting property properties.>>
<<Operations>>
    GetProp: PUBLIC PROC [from: Properties, prop: ATOM] RETURNS [value: REF ANY _ NIL] = {
        value _ ImplementationProperties.GetProp[from, prop];
        };

    PutProp: PUBLIC PROC [on: Properties, prop: ATOM, value: REF ANY _ NIL] RETURNS [new: Properties] = {
        new _ ImplementationProperties.PutProp[on, prop, value];
        };

    Enumerate: PUBLIC PROC [props: Properties, consume: PROC [ATOM, REF ANY]] = {
        FOR pl: Properties _ props, pl.rest WHILE pl # NIL DO
            consume[NARROW [pl.first.key], pl.first.val];
            ENDLOOP;
        };

    PrintProperties: PUBLIC PROC [props: Properties, out: IO.STREAM _ NIL, indent: NAT _ 0, cr: BOOL _ TRUE, level: NAT _ 2] = {
        PrintIt: PROC [prop: ATOM, val: REF ANY _ NIL] = {
            propprops: Properties _ FetchProperties[prop];
            pp: REF PropPrintProc;
            IF propprops#NIL THEN {
                pp _ NARROW [GetProp[propprops, propPrint]];
                IF pp # NIL THEN {
                    pp^[to: out, prop: prop, val: val, indent: indent, level: level];
                    }
                };
            IF propprops=NIL OR pp=NIL THEN {
            CoreOps.PrintIndent[indent, out, cr];
                IO.PutF[out, "%g: ", IO.atom[prop]];
                WITH val SELECT FROM
                    atom: ATOM        => IO.PutF[out, "$%g", IO.atom[atom]];
                    rope: ROPE        => IO.PutF[out, "%g", IO.rope[rope]];
                refText: REF TEXT        => IO.PutF[out, "%g", IO.text[refText]];
                lor: LIST OF ROPE        => FOR l: LIST OF ROPE _ lor, l.rest UNTIL l=NIL DO
                IO.PutF[out, "%g ", IO.rope[l.first]];
                ENDLOOP;
                lor: LIST OF REF TEXT    => FOR l: LIST OF REF TEXT _ lor, l.rest UNTIL l=NIL DO
                IO.PutF[out, "%g ", IO.text[l.first]];
                ENDLOOP;
                    refInt: REF INT    => IO.PutF[out, "%g", IO.int[refInt^]];
                    refReal: REF REAL    => IO.PutF[out, "%g", IO.real[refReal^]];
                    ENDCASE        => {};
                };
            };
        IF out=NIL THEN out _ NARROW[ProcessProps.GetProp[$CommanderHandle], Commander.Handle].out;
        Enumerate[props, PrintIt];
        };

HasPrintableProp: PUBLIC PROC [props: Properties] RETURNS [hasSomePrintableProp: BOOL _ FALSE] = {
Consume: PROC [atom: ATOM, val: REF ANY] = {
propprops: Properties _ FetchProperties[atom];
IF propprops=NIL OR GetProp[propprops, propPrint]#PropDontPrint 
THEN hasSomePrintableProp _ TRUE;
};
Enumerate[props, Consume];
};
<<Registration>>
    RegisterProperty: PUBLIC PROC [prop: ATOM, properties: Properties _ NIL] RETURNS [sameProp: ATOM] = {
        [] _  HashTable.Store[propTable, prop, properties];
        sameProp _ prop;
        };

    StoreProperties: PUBLIC PROC [prop: ATOM, properties: Properties] = {
        [] _  HashTable.Store[propTable, prop, properties];
        };

    FetchProperties: PUBLIC PROC [prop: ATOM] RETURNS [properties: Properties] = {
        found: BOOL; value: HashTable.Value;
        [found, value] _ HashTable.Fetch[propTable, prop];
        IF NOT found THEN RETURN[NIL];
        properties _ NARROW [value, Properties];
        };

    propPrint: PUBLIC ATOM _ $PropPrint;

    DontPrint: PropPrintProc = {};
    PropDontPrint: PUBLIC REF PropPrintProc _ NEW [PropPrintProc _ DontPrint];

<<Inheritance of Properties>>
    InheritCellTypeProp: PUBLIC PROC [from: CellType, prop: ATOM] RETURNS [value: REF ANY _ NIL] = {
        DO
            value _ GetProp[from: from.properties, prop: prop];
        IF value=NIL THEN value _ GetProp[from: from.class.properties, prop: prop];
            IF value#NIL OR NOT from.class.layersProps THEN EXIT;
            from _ CoreOps.Recast[from];
        ENDLOOP;
        };
        <<>>
    InheritPublicProp: PUBLIC PROC [cellType: CellType, from: Wire, prop: ATOM] RETURNS [value: REF ANY _ NIL] = {
        table: HashTable.Table _ NIL;
        DO
            value _ GetProp[from: from.properties, prop: prop];
            IF value#NIL OR NOT cellType.class.layersProps THEN EXIT;
            table _ CoreOps.RecastBindingTable[cellType];
            IF table=NIL THEN LOOP;
            from _ NARROW [HashTable.Fetch[table, from].value];
            cellType _ CoreOps.Recast[cellType];
        ENDLOOP;
        };

<<Short Cuts>>
    Props: PUBLIC PROC [lit1, lit2, lit3, lit4, lit5, lit6: PropertyLiteral _ []] RETURNS [properties: Properties] = {
        properties _ PutProp[on: NIL, prop: lit1.key, value: lit1.val];
        properties _ PutProp[on: properties, prop: lit2.key, value: lit2.val];
        properties _ PutProp[on: properties, prop: lit3.key, value: lit3.val];
        properties _ PutProp[on: properties, prop: lit4.key, value: lit4.val];
        properties _ PutProp[on: properties, prop: lit5.key, value: lit5.val];
        properties _ PutProp[on: properties, prop: lit6.key, value: lit6.val];
        };

    GetWireProp: PUBLIC PROC [from: Wire, prop: ATOM] RETURNS [value: REF ANY _ NIL] = {
        value _  GetProp[from: from.properties, prop: prop];
        };

    PutWireProp: PUBLIC PROC [on: Wire, prop: ATOM, value: REF ANY _ NIL] = {
        on.properties _  PutProp[on: on.properties, prop: prop, value: value];
        };

    GetCellClassProp: PUBLIC PROC [from: CellClass, prop: ATOM] RETURNS [value: REF ANY _ NIL] = {
        value _  GetProp[from: from.properties, prop: prop];
        };

    PutCellClassProp: PUBLIC PROC [on: CellClass, prop: ATOM, value: REF ANY _ NIL] = {
        on.properties _  PutProp[on: on.properties, prop: prop, value: value];
        };

    GetCellTypeProp: PUBLIC PROC [from: CellType, prop: ATOM] RETURNS [value: REF ANY _ NIL] = {
        value _  GetProp[from: from.properties, prop: prop];
        };

    PutCellTypeProp: PUBLIC PROC [on: CellType, prop: ATOM, value: REF ANY _ NIL] = {
        on.properties _  PutProp[on: on.properties, prop: prop, value: value];
        };

    GetCellInstanceProp: PUBLIC PROC [from: CoreClasses.CellInstance, prop: ATOM] RETURNS [value: REF ANY _ NIL] = {
        value _  GetProp[from: from.properties, prop: prop];
        };

    PutCellInstanceProp: PUBLIC PROC [on: CoreClasses.CellInstance, prop: ATOM, value: REF ANY _ NIL] = {
        on.properties _  PutProp[on: on.properties, prop: prop, value: value];
        };

    END.