CDVArrowImpl.mesa (part of ChipNDale)
Copyright © 1984 by Xerox Corporation. All rights reserved.
by Christian Jacobi, August 30, 1984 10:21:27 am PDT
last edited by Christian Jacobi, January 2, 1986 11:50:59 am PST
DIRECTORY
CedarProcess,
CD,
CDBasics,
CDDrawQueue,
CDProperties,
CDValue,
CDVArrow,
CDVPrivate,
CDVScale,
CDVFurtherPainters,
Imager,
Process,
ViewerEvents;
CDVArrowImpl:
CEDAR
MONITOR
IMPORTS CedarProcess, CDDrawQueue, CDBasics, CDProperties, CDValue, CDVPrivate, CDVScale, CDVFurtherPainters, Imager, Process, ViewerEvents
EXPORTS CDVArrow =
BEGIN
-- implements arrows on ChipNDale viewers
-- we have to distribute the command to the separate viewers because
-- arrows have different sizes in design coordinates, depending on scale
-- of the viewer.
-- we do store the arrow position twice!
-- 1: on a per design basis (using CDValue); this is used to reeinstall arrows
-- when viewers are opened
-- 2: on a per viewer basis (in the PainterRec); this allows erasing the arrows
-- however we need a flag in the PainterRec if it is valid ($on)
ShowArrow:
PUBLIC
PROC [design:
CD.Design, pos:
CD.Position] =
--called from client
BEGIN
CDValue.Store[boundTo: design, key: $arrow, value: NEW[CD.Position←pos]];
CDDrawQueue.InsertDrawCommand[design, CDDrawQueue.Request[$PutArrowXXX, [pos.x, pos.y, 0, 0]]]
END;
RemoveArrow:
PUBLIC
PROC[design:
CD.Design] =
--called from client
BEGIN
CDValue.Store[boundTo: design, key: $arrow, value: NIL];
CDDrawQueue.InsertDrawCommand[design, CDDrawQueue.Request[$RemoveArrowXXX, [0, 0, 0, 0]]];
END;
GetAPainterRec:
ENTRY PROC [me: CDVPrivate.VRef]
RETURNS [pr: REF CDVPrivate.PainterRec] =
BEGIN ENABLE UNWIND => NULL;
x: REF = CDProperties.GetProp[me.properties, $CDxArrowPaintProc];
IF x#NIL THEN pr ← NARROW[x]
ELSE {
pr ← NEW[CDVPrivate.PainterRec←[proc: PaintArrow]];
CDProperties.PutProp[me.properties, $CDxArrowPaintProc, pr]
}
END;
PaintArrow: CDVPrivate.PainterProc =
-- PROC [me: VRef, paintRef: REF PainterRec, interrestRect: CD.Rect];
BEGIN
vp: CD.Position ← CDVScale.DesignToViewerPosition[me.scale, [paintRef.rect.x1, paintRef.rect.y1]];
vp ← CDBasics.AddPoints[vp, [1, 1]];
Imager.SetColor[me.viewContext, Imager.black];
Imager.MaskVector[me.viewContext, [vp.x+10, vp.y], [vp.x, vp.y]];
Imager.MaskVector[me.viewContext, [vp.x, vp.y], [vp.x, vp.y+10]];
Imager.MaskVector[me.viewContext, [vp.x, vp.y], [vp.x+18, vp.y+18]];
END;
PaintTheArrow: CDVFurtherPainters.FurtherPaintProc =
--PROC [me: CDVPrivate.VRef, key: REF]
--eg. former paints ticks
--called through ProtectedRepaint only
--called in viewers paint proc
BEGIN
pr: REF CDVPrivate.PainterRec = GetAPainterRec[me];
comm: REF CDDrawQueue.Request = NARROW[key];
arrowSize: CD.Number = MAX[CDVScale.UngriddedViewerToDesignScalar[me.scale, 20], 1];
aRect:
CD.Rect ← [x1: comm.rect.x1, y1: comm.rect.y1,
x2: comm.rect.x1+arrowSize, y2: comm.rect.y1+arrowSize];
IF pr.data = $on
THEN {
oldRect: CD.Rect;
IF pr.rect=aRect THEN RETURN;
oldRect ← pr.rect;
pr.rect ← aRect;
CDDrawQueue.QueueInsertDrawCommand[me.ct, CDDrawQueue.Request[$redraw, oldRect]];
}
ELSE {
pr.rect ← aRect;
CDVPrivate.IncludeAPainterRec[me, pr];
pr.data ← $on;
};
CDDrawQueue.QueueInsertDrawCommand[me.ct, CDDrawQueue.Request[$draw, aRect]];
END;
RemoveTheArrow: CDVFurtherPainters.FurtherPaintProc =
--PROC [me: CDVPrivate.VRef, key: REF]
--eg. former paints ticks
--called through ProtectedRepaint only
--called in viewers paint proc
BEGIN
pr: REF CDVPrivate.PainterRec = GetAPainterRec[me];
IF pr.data = $on
THEN {
oldRect: CD.Rect ← pr.rect;
pr.rect ← CDBasics.empty;
pr.data ← NIL;
CDDrawQueue.QueueInsertDrawCommand[me.ct, CDDrawQueue.Request[$redraw, oldRect]];
CDVPrivate.RemoveAPainterRec[me, pr];
}
END;
CallOnOpenOrCreate: ViewerEvents.EventProc =
-- PROC [viewer: ViewerClasses.Viewer, event: ViewerEvent, before: BOOL] RETURNS[abort: BOOL ← FALSE]
TRUSTED BEGIN
--crazy: we fork, because we want to wait
Process.Detach[FORK ReInstallTheArrow[NARROW[viewer.data]]];
END;
ReInstallTheArrow:
PROC [me: CDVPrivate.VRef] =
BEGIN
--crazy: we wait, to increase propability of the commandtable beeing initialized
CedarProcess.SetPriority[CedarProcess.Priority[background]];
Process.Pause[Process.MsecToTicks[500]];
IF me.ct#
NIL
THEN {
-- which now certainly is true
WITH CDValue.Fetch[boundTo: me.actualDesign, key: $arrow, propagation: design]
SELECT
FROM
pos:
REF
CD.Position => {
CDDrawQueue.QueueInsertDrawCommand[me.ct, CDDrawQueue.Request[$PutArrowXXX, [pos.x, pos.y, 0, 0]]]
};
ENDCASE => {
CDDrawQueue.QueueInsertDrawCommand[me.ct, CDDrawQueue.Request[$RemoveArrowXXX, [0, 0, 0, 0]]]
};
}
END;
Init:
PROC [] =
BEGIN
CDValue.RegisterKey[$arrow];
CDVFurtherPainters.InstallFurtherPaint[keyValue: $PutArrowXXX, proc: PaintTheArrow];
CDVFurtherPainters.InstallFurtherPaint[keyValue: $RemoveArrowXXX, proc: RemoveTheArrow];
[] ← ViewerEvents.RegisterEventProc[proc: CallOnOpenOrCreate, event: open, filter: $ChipNDale, before: FALSE];
[] ← ViewerEvents.RegisterEventProc[proc: CallOnOpenOrCreate, event: create, filter: $ChipNDale, before: FALSE];
END;
Init[];
END.