CDVTicksImpl.mesa (part of ChipNDale)
Copyright © 1984 by Xerox Corporation. All rights reserved.
by Christian Jacobi, August 30, 1984 10:21:27 am PDT
last edited by Christian Jacobi, September 4, 1985 2:32:15 pm PDT
DIRECTORY
Basics USING [bitsPerWord, LongMult],
CD,
CDBasics,
CDDraw,
CDProperties,
CDSequencer USING [Command],
CDVPrivate,
CDVScale,
CDVTicks,
PrincOps USING [BBptr, BitAddress, BitBltFlags, SrcDesc, GrayParm],
PrincOpsUtils USING [BITBLT],
RuntimeError USING [UNCAUGHT],
Terminal,
ViewerClasses USING [Viewer];
CDVTicksImpl: CEDAR MONITOR
IMPORTS Basics, CDDraw, CDBasics, CDProperties, CDVPrivate, CDVScale, PrincOpsUtils, RuntimeError, Terminal
EXPORTS CDVTicks =
BEGIN
-- implement ticks for ChipNDale viewers
black: REF CARDINAL = NEW[CARDINAL←LAST[CARDINAL]];
virtual: Terminal.Virtual = Terminal.Current[];
PaintTicks: CDVPrivate.PainterProc =
-- PROC [me: MyGraphicRef, paintRef: REF PainterRec, interrestRect: CD.Rect];
BEGIN
ENABLE RuntimeError.UNCAUGHT => {
IF CDVPrivate.catchAny THEN GOTO SomeError ELSE REJECT
};
ModUp: PROC [x, md: CD.Number] RETURNS [CD.Number] = INLINE {
RETURN [( IF x>0 THEN (x+md-1) ELSE (x) ) / md * md]
}; -- division rounds towards 0
ModDown: PROC [x, md: CD.Number] RETURNS [CD.Number] = INLINE {
RETURN [( IF x>=0 THEN (x) ELSE (x-md+1) ) / md * md]
}; -- division rounds towards 0
dTicks: CD.Number = NARROW[paintRef.data, REF CD.Number]^;
IF dTicks>0 THEN {
vTicks: CD.Number = CDVScale.DesignToViewerScalar[me.scale, dTicks];
IF vTicks>6 AND vTicks<=512 THEN TRUSTED {
x, xStop, xMod, xInc: INT;
yStart, yStop, yInc, yCur: LONG CARDINAL;
dr: CD.Rect = CDBasics.Intersection[me.deviceDrawRef.interestClip, paintRef.rect]; -- design coords
vr: CD.Rect ← CDVScale.DesignToViewerRect[me.scale, CD.Rect[ -- viewer coords
x1: ModDown[dr.x1, dTicks],
y1: ModDown[dr.y1, dTicks],
x2: ModUp[dr.x2, dTicks],
y2: ModUp[dr.y2, dTicks]
]];
vx1, vy1, vx2, vy2: CARDINAL; -- rect in V-coords; snapped to tick positions
vx1 ← IF vr.x1>=0 THEN vr.x1 ELSE vr.x1 + ModUp[-vr.x1, vTicks];
vy1 ← IF vr.y1>=0 THEN vr.y1 ELSE vr.y1 + ModUp[-vr.y1, vTicks];
vx2 ← IF vr.x2<=me.viewer.cw THEN vr.x2 ELSE vr.x2-ModUp[vr.x2-me.viewer.cw, vTicks];
vy2 ← IF vr.y2<=me.viewer.ch THEN vr.y2 ELSE vr.y2-ModUp[vr.y2-me.viewer.ch, vTicks];
-- Now v.. denotes area for ticks; vTicks denote increment; in viewer coordinates
me.xBBptr.width ← me.bpp;
me.xBBptr.height ← 1;
me.xBBptr.src ← [LOOPHOLE[black],,0];
me.xBBptr.srcDesc ← PrincOps.SrcDesc[gray[PrincOps.GrayParm[
yOffset: 0,
widthMinusOne: 0, --words
heightMinusOne: 0 --lines
]]];
me.xBBptr.flags ← PrincOps.BitBltFlags[
direction: forward,
disjoint: TRUE,
disjointItems: TRUE,
gray: TRUE,
srcFunc: null,
dstFunc: or
];
xInc ← vTicks*me.bpp;
x ← Basics.LongMult[vx1+me.vx, me.bpp]; --x start
xStop ← Basics.LongMult[vx2+me.vx, me.bpp];
yInc ← vTicks*me.scWidthWords;
yStart ← LOOPHOLE[me.screen + Basics.LongMult[(me.vy-vy2), me.scWidthWords] ];
yStop ← LOOPHOLE[me.screen + Basics.LongMult[(me.vy-vy1), me.scWidthWords] + xStop/Basics.bitsPerWord];
BEGIN
DoIt: PROC [] =
TRUSTED BEGIN
WHILE x<=xStop DO
yCur ← yStart+LOOPHOLE[(x/Basics.bitsPerWord), LONG CARDINAL];
xMod ← x MOD Basics.bitsPerWord;
WHILE yCur<=yStop DO
me.xBBptr.dst ← [LOOPHOLE[yCur],, xMod];
PrincOpsUtils.BITBLT[me.xBBptr];
yCur ← yCur+yInc
ENDLOOP;
x ← x+xInc;
ENDLOOP;
END;
IF me.bpp=1 THEN DoIt[] ELSE Terminal.ModifyColorFrame[virtual, DoIt];
END;
};
}
EXITS SomeError => NULL
END;
ShowTicks: PUBLIC PROC [onto: REF, value: INT𡤀] =
--called from client
BEGIN
me: CDVPrivate.MyGraphicRef;
WITH onto SELECT FROM
x: CDVPrivate.MyGraphicRef => me ← x;
c: CDSequencer.Command => {ShowTicks[onto: c.ref, value: value]; RETURN};
v: ViewerClasses.Viewer => {ShowTicks[onto: v.data, value: value]; RETURN};
ENDCASE => RETURN;
IF me#NIL THEN {
pr: REF CDVPrivate.PainterRec = GetAPainterRec[me];
value ← MIN[4096, MAX[0, value]];
pr.data ← NEW[CD.Number←value];
IF value=0 THEN CDVPrivate.RemoveAPainterRec[me, pr]
ELSE CDVPrivate.IncludeAPainterRec[me, pr];
CDDraw.InsertCommand[me.ct,
CDDraw.Comm[cmd: rect, erase: TRUE, rect: CDBasics.universe, ref: NIL]]
}
END;
GetAPainterRec: ENTRY PROC [me: CDVPrivate.MyGraphicRef] RETURNS [pr: REF CDVPrivate.PainterRec] =
BEGIN ENABLE UNWIND => NULL;
x: REF = CDProperties.GetPropFromList[me.properties, $CDxTickProc];
IF x#NIL THEN pr ← NARROW[x]
ELSE {
pr ← NEW[CDVPrivate.PainterRec←[proc: PaintTicks, rect: CDBasics.universe]];
me.properties ← Atom.PutPropOnList[me.properties, $CDxTickProc, pr]
}
END;
END.