% Special slanted characters for ``extended ASCII character set'' fonts

% These characters were copied from {\tt greekl.mf} and {\tt italms.mf}
% with character positions changed and italic corrections added to the width.

% Codes \0002--\0003, \0007--\0012, and \0017 are generated.

cmchar "Lowercase Greek alpha for extended ASCII";
beginchar(oct"002",11u#,x←height#,0);
italcorr max(1/3x←height#*slant+.5hair#+.5u#,x←height#*slant-.5u#);
adjust←fit(0,ic#); charic:=0; pickup fine.nib;
pos0(hair,0); pos1(vair,-90); pos2(curve,-180); pos3(vair,-270);
z4=(w-3.25u,9/16h); z5=(w-2.75u,.5[vair,y4]);
numeric theta; theta=angle(z4-z5)-90;
pos4(stem,theta); pos5(stem,theta);
pos6(vair,90); pos7(hair,180);
rt x0r=hround(w-u); x1=x3=.5w-u; lft x2r=hround(1.5u-.5curve);
x6=w-u; x7+.5hair=hround(w+.5hair-eps);
top y0=vround .8[bar←height,h]; bot y1r=bot y6l=-oo;
y2=.5[y1,y3]; top y3r=h+oo; y7=1/4bar←height;
filldraw stroke z0e{down}...pulled←arc.e(1,2) & pulled←arc.e(2,3)
 ...z4e---z5e...z6e{right}...{up}z7e; % diagonal, bowl, and hook
penlabels(0,1,2,3,4,5,6,7); endchar;

cmchar "Lowercase Greek beta for extended ASCII";
beginchar(oct"003",9.5u#,asc←height#,desc←depth#);
italcorr .5[x←height#,asc←height#]*slant-u#;
adjust←fit(0,ic#); charic:=0; pickup fine.nib;
pos0(hair,180); pos1(hair,180); pos2(vair,90);
pos3(stem,0); pos4(vair,-90); pos5(hair,-180);
pos6(vair,-270); pos7(curve,-360); pos8(vair,-450); pos9(hair,-540);
x0=x1=x9; lft x0l=hround(1.5u-.5hair); x2=x4=x6=x8=.5w+.25u;
rt x3r=hround(w-1.5u); rt x7r=hround(w-1.5u+.5curve); rt x5l=hround(x4-u);
bot y0=-d; y1=top y6r=x←height; top y2r=h+oo; y3=.5[y2,y4];
y5=.5[y4,y6]; top y6r-bot y4r=vstem+eps; bot y8=-oo; y7=y9=.5[y6,y8];
if y6l<y4l: y6l:=y4l:=y5; fi
filldraw stroke z0e---z1e...pulled←arc.e(2,3)
 & pulled←arc.e(3,4)...{up}z5e;  % stem and upper bowl
filldraw stroke z5e{up}...pulled←arc.e(6,7)
 & pulled←arc.e(7,8)...{up}z9e;  % lower bowl
penlabels(0,1,2,3,4,5,6,7,8,9); endchar;

cmchar "Lowercase Greek pi for extended ASCII";
beginchar(oct"007",10u#,x←height#,0);
italcorr x←height#*slant+.5stem#-u#;
adjust←fit(0,ic#); charic:=0; pi←stroke; % hook and bar
pos4(hair,0); pos6(hair,0); x4=3.5u; x6=w-4u; y4=y6=y2;
x5=3u; x7=w-2.5u; y5=y7=.5stem-oo;
pair v[]; v1=(z4-z5) xscaled 3.14159; v2=(z6-z7) xscaled 3.14159;
pos5(stem,angle v1-90); pos7(stem,angle v2-90);
filldraw circ←stroke z5e{v1}...{up}z4e;  % left stem
filldraw circ←stroke z7e{v2}...{up}z6e;  % right stem
penlabels(1,2,3,4,5,6,7); endchar;

cmchar "Lowercase Greek lambda for extended ASCII";
beginchar(oct"010",10.5u#,asc←height#,0);
adjust←fit(0,0); pickup fine.nib;
pos1(vair,90); lft x1=hround .1u; top y1r=h;
x2=x1+2u; y2=.7[x←height,h]; x3=w-2u; bot y4=-oo; y3=max(.07h,y4+eps);
z4-(.25u,0)=whatever[z2,z3]; numeric theta; theta=angle(z2-z3)-90;
pos2(stem,theta); pos3(stem,theta); pos4(stem,0);
filldraw circ←stroke z1e{right}...z2e---z3e
 ...{2(x4e-x3e),y4e-y3e}z4e;  % long diagonal
y5=.5[bar←height,x←height]; z5=whatever[z2,z3];
x6=1.5u; y6-.5stem=-oo; pos5(hair,theta-90); pos6(stem,angle(z5-z6)-90);
filldraw circ←stroke z6e--z5e; % short diagonal
penlabels(1,2,3,4,5,6); endchar;

cmchar "Lowercase Greek gamma for extended ASCII";
beginchar(oct"011",10u#,x←height#,desc←depth#);
italcorr x←height#*slant-.5u#;
adjust←fit(0,ic#); charic:=0; pickup fine.nib;
pos1(hair,180); pos2(vstem+dw,90);
pos4(hair,0); pos5(vair,-90); pos6(hair,-180); pos7(hair,-180);
bot y1=.5772156649h; top y2r=h+oo; y4=y6=-.5d;
bot y5r=-d-o; top y7=h;
lft x1r=hround(.5u-.5hair); x2=3u; rt x4r=hround(w-2u); x5=.5[x4,x6];
rt x4r-lft x6r=hround 1/3[hair,stem]+eps; rt x7l=hround(w-u);
if x4l<x6l: x4l:=x6l:=x5; fi
pos3(hair,angle(z4-z2)+90); x3=superness[x2,x4]; y3=superness[y4,y2];
filldraw stroke z1e{up}...z2e{right}...z3e{z4-z2}
 ...z4e{down}...{left}z5e; % arc
filldraw stroke z5e{left}...z6e{up}..{2(x7-x6),y7-y6}z7e;  % stem
penlabels(1,2,3,4,5,6,7); endchar;

cmchar "Lowercase Greek delta for extended ASCII";
beginchar(oct"012",8u#,asc←height#,0);
italcorr .9asc←height#*slant+.5hair#-1.5u#;
adjust←fit(0,ic#); charic:=0; pickup fine.nib;
pos1(hair,-180); pos2(vair,-90);
numeric theta; theta=angle(18u,-h);
pos3(stem,theta+90); pos4(stem,theta+90); pos5(1/4[hair,stem],20);
pos6(vair,-90); pos7(curve,-180); pos8(vair,-270);
rt x1l=hround(w-2u+.5hair); x2=.5w; x3r=3u; rt x5r=hround(w-u);
x4=x6=x8=.5w+.5u; lft x7r=hround(1.5u-.5curve);
y1=.9h; top y2l=h+oo; top y8r=x←height+oo; y4=y8;
z4-z3=whatever*(18u,-h); y5=y7=.5[y6,y8]; bot y6=-oo;
filldraw stroke z1e{x2-x1,3(y2-y1)}...z2e{left}...z3e---z4e
 ....z5e{down}...pulled←arc.e(6,7) & pulled←arc.e(7,8);  % hook and bowl
penlabels(1,2,3,4,5,6,7,8); endchar;

cmchar "Partial differential sign for extended ASCII";
beginchar(oct"017",10u#,asc←height#,0);
italcorr .7asc←height#*slant+.5curve#-1.5u#;
adjust←fit(0,ic#); charic:=0;
numeric top←thickness,bot←thickness,side←thickness,pull;
top←thickness=max(fine.breadth,vround(slab-2vair←corr));
bot←thickness=max(fine.breadth,vround(slab-vair←corr));
side←thickness=max(fine.breadth,hround 1/3[curve,cap←curve]);
pull=min(.25,1.5superpull);
pickup fine.nib; pos2(top←thickness,90);
pos3(side←thickness,0); pos4(bot←thickness,-90);
pos5(side←thickness,-180); pos6(vair,-270);
lft x5r=w-rt x3r=hround max(.75u,1.5u-.5side←thickness);
x4=x6+.1u=x2+u=.5w;
top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
y5=.5[y4,y6]; top y6=vround 5/8h+o;
path p; p=pulled←super←arc.l(3,4)(pull);
numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
pos7(thin←join,0); z7l=point t of p;
(x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
filldraw stroke pulled←super←arc.e(2,3)(pull)
 & {{interim superness:=more←super; pulled←super←arc.e(3,4)(pull)}}
 & {{less←tense; pulled←super←arc.e(4,5)(pull) & pulled←super←arc.e(5,6)(pull)}}
 & z6e{right}...{direction t of p}z7e;  % arc and bowl
pos1(hair,180); pos0(flare,180);
lft x0r=min(lft x2-eps,hround 1.2u);
y0=vround min(.85h-.5flare,.8h+.5flare)+o;
{{less←tense; bulb(2,1,0)}};  % arc and bulb
math←fit(-.3x←height#*slant+.5curve#-u#,ic#-u#);
penlabels(0,1,2,3,4,5,6,7); endchar;