% This file contains punctuation marks common to roman and italic styles.

% Codes \0041, \0043, \0045, \0047--\0054,\ %
%% \0056, \0057, \0072, \0073, \0075, \0100,\par
% \0133, \0135, and \0140 are generated, as well as code |spanish←shriek|
% (for a Spanish exclamation point) if that code value is known.

cmchar "Exclamation point";
beginchar("!",5u#+width←adj#,asc←height#,0);
italcorr asc←height#*slant-2u#-.5width←adj#+.5dot←size#;
adjust←fit(0,0);
pickup tiny.nib; pos3(dot←size,0); pos4(dot←size,90);
lft x3l=hround(.5w-.5dot←size); bot y4l=0; z3=z4; dot(3,4);  % dot
numeric bot←width;
bot←width=if hefty:max(hround .8dot←size,fine.breadth) else: hair fi;
pickup fine.nib; pos1(dot←size,0); pos2(bot←width,0);
x1=x2=x3; bot y2=.25[top y4r,x←height]+1;
if square←dots: top y1=h;
 filldraw stroke z1e--z2e;  % stem
else: top z0=(x1,h+o); y1+.5dot←size=h+o;
 filldraw z1r...z0...z1l---z2l--z2r---cycle; fi  % stem and bulb
penlabels(0,1,2,3,4); endchar;

iff known spanish←shriek: cmchar "Spanish open exclamation point";
beginchar(spanish←shriek,5u#+width←adj#,asc←height#-desc←depth#,desc←depth#);
italcorr h#*slant-2u#-.5width←adj#+.5dot←size#;
adjust←fit(0,0);
pickup tiny.nib; pos3(dot←size,0); pos4(dot←size,90);
lft x3l=hround(.5w-.5dot←size); top y4r=h; z3=z4; dot(3,4);  % dot
numeric top←width;
top←width=if hefty:max(hround .8dot←size,fine.breadth) else: hair fi;
pickup fine.nib; pos1(dot←size,0); pos2(top←width,0);
x1=x2=x3; top y2=.25[bot y4l,h-x←height]-1;
if square←dots: bot y1=-d;
 filldraw stroke z1e--z2e;  % stem
else: bot z0=(x1,-d-o); y1-.5dot←size=-d-o;
 filldraw z1l...z0...z1r---z2r--z2l---cycle; fi  % stem and bulb
penlabels(0,1,2,3,4); endchar;

cmchar "Hash mark (number sign)";
if monospace: compute←spread(.6x←height#,.7x←height#);
else: compute←spread(.45x←height#,.55x←height#); fi
beginchar("#",15u#,asc←height#,asc←depth#);
italcorr (math←axis#+.5(spread#+rule←thickness#))*slant-.5u#;
adjust←fit(0,0);
pickup rule.nib; lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math←axis;
draw z1--z2;  % upper bar
draw z3--z4;  % lower bar
lft x6=hround 3u; rt x7=hround(w-3u); x5-x6=x7-x8;
x8=good.x if monospace: .6 else: .5 fi\\w;
top y5=top y7=h+eps; bot y6=bot y8=-d-eps;
y15=y1; z15=whatever[z5,z6]; y36=y3; z36=whatever[z5,z6];
y27=y2; z27=whatever[z7,z8]; y48=y4; z48=whatever[z7,z8];
draw z5--if x5>x6+1:(good.x(x15+.5),y1)--(good.x(x15-.5),y1)
 --(good.x(x36+.5),y3)--(good.x(x36-.5),y3)--fi\\z6;  % left diagonal
draw z7--if x7>x8+1:(good.x(x27+.5),y2)--(good.x(x27-.5),y2)
 --(good.x(x48+.5),y4)--(good.x(x48-.5),y4)--fi\\z8;  % right diagonal
labels(1,2,3,4,5,6,7,8,15,27,36,48); endchar;

cmchar "Per cent sign";
beginchar("%",9u#+max(6u#,2fudge*(hair#+stem#)),
  body←height#,body←height#-asc←height#);
italcorr if hefty: .4asc←height#*slant-.5u# else: h#*slant-u# fi;
adjust←fit(0,0); pickup fine.nib;
numeric left←curve,right←curve;
left←curve=hround 5/6[fudged.hair,fudged.stem];
right←curve=max(fine.breadth,hround(fudged.hair if hefty:-2stem←corr fi));
pos1(vair,90); pos2(left←curve,180); pos3(vair,270); pos4(right←curve,360);
top y1r=h; lft x2r=hround u; rt x4r=hround(.5w-1.5u);
bot y3r=floor(if monospace: .7 else: .5 fi\\ asc←height);
x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
filldraw stroke pulled←super←arc.e(1,2)(superpull)
 & pulled←super←arc.e(2,3)(superpull);  % left half of upper bowl
filldraw stroke super←arc.e(3,4) & super←arc.e(4,1); % right half of upper bowl
pos5(vair,90); pos6(left←curve,180); pos7(vair,270); pos8(right←curve,360);
bot y7r=-d; rt x8r=hround(w-u); lft x6r=hround(.5w+1.5u);
top y5r=vround(if monospace: .3 else: .5 fi\\ asc←height);
x5=x7=.5[x6,x8]; y6=y8=.5[y5,y7];
filldraw stroke pulled←super←arc.e(5,6)(superpull)
 & pulled←super←arc.e(6,7)(superpull);  % left half of lower bowl
filldraw stroke super←arc.e(7,8) & super←arc.e(8,5); % right half of lower bowl
pickup rule.nib; top y9=h; bot y10=-d;
if hefty: x9=good.x(x5-eps); x10=good.x(x1+eps);
 draw z9--z10;  % diagonal
else: rt x9=hround(w-2.5u); lft x10=hround 2.5u; draw z9--z10;  % diagonal
 pickup fine.nib; pos9(rule←thickness,angle(z9-z10)+90);
 pos11(vair,angle(z1r-z4r)-90); pos12(vair,angle(z9-z10)+90);
 path p; p=super←arc.r(1,4); z11r=point 2/3 of p; z12r=z9r;
 filldraw stroke z11e{direction 2/3 of p}...{z9-z10}z12e; fi  % link
penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;

cmchar "Apostrophe";
beginchar("'",5u#,asc←height#,0);
italcorr asc←height#*slant+.5dot←size#-2u#;
adjust←fit(0,0);
x1-.5dot←size=hround(.5w-.5dot←size); y1+.5dot←size=h;
if monospace: comma(1,a,dot←size,.28u,vround 1.5comma←depth);  % large comma
else: comma(1,a,dot←size,.25u,comma←depth); fi  % comma with increased jut
penlabels(1); endchar;

cmchar "Left parenthesis";
beginchar("(",7u# if monospace: -u# fi,body←height#,body←depth#);
italcorr body←height#*slant-.5u#;
adjust←fit(0,0); pickup fine.nib;
pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
rt x1r=rt x3r=hround(w-u); lft x2l=hround(x1-4u if monospace: +4/3u fi);
top y1=h; y2=.5[y1,y3]=math←axis;
filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
 ...{3(x3e-x2e),y3-y2}z3e;  % arc
penlabels(1,2,3); endchar;

cmchar "Right parenthesis";
beginchar(")",7u# if monospace: -u# fi,body←height#,body←depth#);
italcorr math←axis#*slant-.5u#;
adjust←fit(0,0); pickup fine.nib;
pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
lft x1l=lft x3l=hround u; rt x2r=hround(x1+4u if monospace: -4/3u fi);
top y1=h; y2=.5[y1,y3]=math←axis;
filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
 ...{3(x3e-x2e),y3-y2}z3e;  % arc
penlabels(1,2,3); endchar;

cmchar "Asterisk";
beginchar("*",9u#,
  if low←asterisk:math←axis#+.5x←height# else: body←height# fi,0);
italcorr h#*slant-.75u#;
adjust←fit(0,0);
numeric ast←flare; ast←flare=hround .7[thin←join,stem];
x0=.5w; y0=h-.5x←height;
for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x←height;
 numeric theta; theta=angle(z[d]-z0);
 fill z0+.5(0,-thin←join)rotated theta
  ---z[d]+.5(-ast←flare,-ast←flare)rotated theta
  ..z[d]..z[d]+.5(-ast←flare,ast←flare)rotated theta
  ---z0+.5(0,thin←join)rotated theta--cycle; endfor  % diagonal at angle |d|
labels(0,[-150],[-90],[-30],30,90,150); endchar;

cmchar "Plus sign";
beginarithchar("+"); pickup rule.nib;
x1=x2=good.x .5w; top y1=h+eps; .5[y1,y2]=math←axis;
lft x3=hround u-eps; x4=w-x3; y3=y4=math←axis;
draw z1--z2;  % stem
draw z3--z4;  % crossbar
labels(1,2,3,4); endchar;

cmchar "Comma";
numeric dot←diam#; dot←diam#=if monospace: 5/4 fi\\ dot←size#;
define←whole←blacker←pixels(dot←diam);
beginchar(",",5u#,dot←diam#,comma←depth#);
adjust←fit(0,0);
x1-.5dot←diam=hround(.5w-.5dot←diam); y1-.5dot←diam=0;
comma(1,a,dot←diam,.2u,comma←depth);  % dot and tail
penlabels(1); endchar;

cmchar "Period";
numeric dot←diam#; dot←diam#=if monospace: 5/4 fi\\ dot←size#;
define←whole←blacker←pixels(dot←diam);
beginchar(".",5u#,dot←diam#,0);
adjust←fit(0,0); pickup fine.nib;
pos1(dot←diam,0); pos2(dot←diam,90);
lft x1l=hround(.5w-.5dot←diam); bot y2l=0; z1=z2; dot(1,2);  % dot
penlabels(1,2); endchar;

cmchar "Virgule (slash)";
beginchar("/",9u#,body←height#,body←depth#);
italcorr body←height#*slant-.5u#;
adjust←fit(0,0); pickup rule.nib;
rt x1=hround(w-u)+eps; top y1=h+eps;
lft x2=hround u-eps; bot y2=-d-eps;
draw z1--z2;  % diagonal
penlabels(1,2); endchar;

cmchar "Colon";
numeric dot←diam#; dot←diam#=if monospace: 5/4 fi\\ dot←size#;
define←whole←blacker←pixels(dot←diam);
beginchar(":",5u#,x←height#,0);
italcorr x←height#*slant+.5dot←diam#-2u#;
adjust←fit(0,0); pickup fine.nib;
pos1(dot←diam,0); pos2(dot←diam,90);
lft x1l=hround(.5w-.5dot←diam); top y2r=h; z1=z2; dot(1,2);  % upper dot
pos3(dot←diam,0); pos4(dot←diam,90);
x3=x1; bot y4l=0; z3=z4; dot(3,4);  % lower dot
penlabels(1,2,3,4); endchar;

cmchar "Semicolon";
numeric dot←diam#; dot←diam#=if monospace: 5/4 fi\\ dot←size#;
define←whole←blacker←pixels(dot←diam);
beginchar(";",5u#,x←height#,comma←depth#);
italcorr x←height#*slant+.5dot←diam#-2u#;
adjust←fit(0,0); pickup fine.nib;
pos1(dot←diam,0); pos2(dot←diam,90);
lft x1l=hround(.5w-.5dot←diam); top y2r=h; z1=z2; dot(1,2);  % upper dot
x3-.5dot←diam=hround(.5w-.5dot←diam); y3-.5dot←diam=0;
comma(3,a,dot←diam,.05u,comma←depth);  % lower dot and tail
penlabels(1,2,3); endchar;

cmchar "Equal sign";
compute←spread(.45x←height#,.55x←height#);
beginchar("=",14u#,v←center(spread#+rule←thickness#));
italcorr h#*slant-.5u#;
adjust←fit(0,0); pickup rule.nib;
lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math←axis;
draw z1--z2;  % upper bar
draw z3--z4;  % lower bar
labels(1,2,3,4); endchar;

cmchar "At sign";
beginchar("@",14u#,asc←height#,0);
italcorr .7asc←height#*slant-.5u#;
adjust←fit(0,if hefty or monospace:-2u# else: 0 fi);
pickup fine.nib; pos0(fudged.hair,0); pos1(vair,90);
pos2(fudged.stem,180); pos3(vair,270);
pos4(fudged.stem,-180); pos5(fudged.stem,-180);
pos6(vair,-90); pos7(fudged.hair,0);
pos8(vair,90); pos9(fudged.hair,180);
pos10(vair,270); pos11(.5[vair,flare],360);
x1=x3=.5[x0,x2]; y0=y2=.5[y1,y3];
x8=x10=.5w; y7=y9=.5[y8,y10];
lft x9r=hround u; x7=w-x9; top y8r=h+oo; bot y10r=-oo;
top y1r=vround(.8[y10,y8]+.5vair); bot y3r=vround(.2[y10,y8]-.5vair);
x6l=1/3[x5l,x7l]; y6=y3; y11=good.y(.1[y10,y8]-.5);
x0=x4=x5; y4=.8[y3,y1]; y5=2/3[y7,y6];
if hefty or monospace: lft x2r=hround(5u-.5fudged.stem);
 rt x0r=hround(w-3u); x11r=x0r;
else: lft x2r=hround 3.4u; x0=w-x2; x11r=x7r; fi
filldraw stroke super←arc.e(1,2) & super←arc.e(2,3);  % left inner bowl
filldraw stroke super←arc.e(3,0) & super←arc.e(0,1);  % right inner bowl
filldraw stroke super←arc.e(8,9) & super←arc.e(9,10)
 & term.e(10,11,right,1,4);  % left outer bowl and terminal
if hefty or monospace: {{interim superness:=hein←super;
  filldraw stroke super←arc.e(0,8)}};  % link
else: (x,y6r)=whatever[z6l,z7l]; x6r:=x;
 filldraw stroke z4e---z5e...z6e{right}...{up}z7e
  & super←arc.e(7,8); fi % stem and link
penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;

cmchar "Left bracket";
numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule←thickness# fi);
beginchar("[",wd#,body←height#,body←depth#);
italcorr body←height#*slant;
adjust←fit(0,0);
numeric top←thickness,side←thickness;
if hefty: top←thickness=vair;
 side←thickness=max(crisp.breadth,stem-2stem←corr);
else: top←thickness=side←thickness=rule←thickness; fi;
pickup crisp.nib; pos1(side←thickness,0); pos2(side←thickness,0);
top y1=h; bot y2=-d; lft x1l=lft x2l=hround(2.5u-.5side←thickness)-1-eps;
filldraw stroke z1e--z2e;  % stem
pos3(top←thickness,90); pos4(top←thickness,90);
pos5(top←thickness,90); pos6(top←thickness,90);
x3=x5=x1l; rt x4=rt x6=ceiling(w-.4u)+eps; y3r=y4r=y1; y5l=y6l=y2;
filldraw stroke z3e--z4e;  % upper bar
filldraw stroke z5e--z6e;  % lower bar
penlabels(1,2,3,4,5,6); endchar;

cmchar "Right bracket";
numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule←thickness# fi);
beginchar("]",wd#,body←height#,body←depth#);
italcorr body←height#*slant-2u#+.5if hefty:stem# else:rule←thickness# fi;
adjust←fit(0,0);
numeric top←thickness,side←thickness;
if hefty: top←thickness=vair;
 side←thickness=max(crisp.breadth,stem-2stem←corr);
else: top←thickness=side←thickness=rule←thickness; fi;
pickup crisp.nib; pos1(side←thickness,0); pos2(side←thickness,0);
top y1=h; bot y2=-d; rt x1r=rt x2r=hround(w-2.5u+.5side←thickness)+1+eps;
filldraw stroke z1e--z2e;  % stem
pos3(top←thickness,90); pos4(top←thickness,90);
pos5(top←thickness,90); pos6(top←thickness,90);
x3=x5=x1r; lft x4=lft x6=floor .4u-eps; y3r=y4r=y1; y5l=y6l=y2;
filldraw stroke z3e--z4e;  % upper bar
filldraw stroke z5e--z6e;  % lower bar
penlabels(1,2,3,4,5,6); endchar;

cmchar "Reverse apostrophe";
beginchar("`",5u#,asc←height#,0);
italcorr asc←height#*slant+.5dot←size#-2u#;
adjust←fit(0,0);
x1-.5dot←size=hround(.5w-.5dot←size); y1+.5dot←size=h-comma←depth;
if monospace: ammoc(1,a,dot←size,.28u,vround 1.5comma←depth);  % large ammoc
else: ammoc(1,a,dot←size,.25u,comma←depth); fi  % normal ammoc
penlabels(1); endchar;