LoginWork.cm
Mike Spreitzer March 12, 1987 1:26:28 pm PST
We're gonna do some BringOvers of some of the files maintained by AutoBackup; we don't want confusion while that's happening.
AutoBackup off
Set up the Watch tool tastefully:
← IF (&watch ← ViewerOps.FindViewer["Watch"]) # NIL THEN Watch.ForceSample[parent: NIL, mouseButton: yellow] ELSE NIL
← IF &watch # NIL THEN ViewerOps.OpenIcon[icon: &watch, bottom: FALSE] ELSE NIL
Sprinkle your ancilliary files around the local file name space:
cd ///
Bringover [User]<YourName>6.1>YourNameRoot.DF
cd
Bringover [User]<YourName>Top>YourNameHome.DF
cd 6.1
Bringover [User]<YourName>6.1>YourNameHomeV.DF
cd ///Commands/
Now that all your ancilliary files are where they live on the workstation, turn on AutoBackup. Thereafter, you can just edit an ancilliary file and save it, and AutoBackup will SModel the appropriate DF file for you.
AutoBackup on
Run a nice package that's not nice enough to have an install file.
Run GmtDebug
DFTools do not change themselves when the user profile changes. So you have to destroy the recalcitrant old ones. Also, you create a new one, customized according to your taste, almost ready to BringOver Environment.DF into ///Commands/.
DeleteDFTools
DFTool
Establish some useful aliases:
Alias OpenD (arg) Openr argDoc.Tioga
Alias lscc (arg) List [Cedar]<CedarChest6.1>arg
Alias lsc (arg) List [Cedar]<Cedar6.1>arg
Alias lsccd (arg) List [Cedar]<CedarChest6.1>Documentation>arg
Alias lscd (arg) List [Cedar]<Cedar6.1>Documentation>arg
Alias ! Redo
Alias BRCM (pkg) pushr Commands; Bringover -mp pkg.DF; pop
Alias GFR GetFromRelease
Alias TP (file) TiogaToInterpress file.ip ← file; PreView file.ip
cd
Get some good packages going:
FastMouse On
Statistics off
STPServer start
Install TiogaDWIM WorkingDirectory Remember CommandToolProcedures BasicFingerPackage EditorComforts
SpellingTool
Set up the edit tool more sensibly.
DoTiogaOps SaveSelectionA MatchCase MatchLiterally LeaveInitCap SubstituteInSel MatchAnywhere EqualLooksTest DoReplace TypeName "code" StyleName "Cedar" PropName "Comment" RestoreSelectionA
← ViewerOps.SetOpenHeight[viewer: ViewerOps.FindViewer["EditTool"], clientHeight: 195]
Make Tioga pay attention to your profile, so that if the previous user of this machine had unusual TIP tables for Tioga, you won't have to deal with them.
DoTiogaOps SaveSelectionA ReadProfile RestoreSelectionA
Enable yourself as both a client and server for the Summoner.
PseudoServerPrint
SummonerClientOn
SummonerServerOn
← IF ViewerOps.FindViewer["Compute Server \"Server\" Event Log"] = NIL THEN &cmd["SummonerServerTypescript"] ELSE NIL
Tweak some parameters that are wrong in the release:
← RopeEditImpl.defaultPagesPerStreamBuffer ← 32
← RopeEditImpl.defaultStreamBuffers ← 4