SpyViewerImpl.mesa
Copyright © 1984, 1986 by Xerox Corporation. All rights reserved.
Maxwell, December 14, 1983 3:28 pm
Pier, June 24, 1985 2:37:30 pm PDT
Russ Atkinson (RRA) March 31, 1986 2:37:42 pm PST
DIRECTORY
AMModel USING [Section],
AMTypes USING [Error, TV],
AMViewerOps USING [SectionFromSelection],
Buttons USING [Button, ButtonProc, Create, ReLabel],
Commander USING [CommandProc, Register],
Containers USING [ChildXBound, ChildYBound, Container, Create],
Convert USING [CardFromRope],
FS USING [Error, ExpandName],
Icons USING [NewIconFromFile],
IO USING [Close, Put, RopeFromROS, ROS, STREAM],
Labels USING [Create, Label, Set],
PrincOps USING [PsbIndex, PsbNull],
Rope USING [Equal, Fetch, Flatten, Length, ROPE, Text],
Rules USING [Create],
SpyClient USING [ClearBreaks, ClearUserBreaks, DataType, DisplayData, InitializeSpy, SetStartBreak, SetStopBreak, SetTrace, SetUserBreak, StartSpy, StopSpy],
ViewerClasses USING [InitProc, Viewer, ViewerClass],
ViewerIO USING [CreateViewerStreams],
ViewerOps USING [ChangeColumn, CreateViewer, DestroyViewer, OpenIcon, PaintViewer],
ViewerTools USING [GetContents, GetSelectedViewer, GetSelectionContents, MakeNewTextViewer, SelPos, SetSelection];
SpyViewerImpl:
MONITOR
IMPORTS AMTypes, AMViewerOps, Buttons, Commander, Containers, Convert, FS, Icons, IO, Labels, Rope, Rules, SpyClient, ViewerIO, ViewerOps, ViewerTools
SHARES IO = {
ROPE: TYPE = Rope.ROPE;
STREAM: TYPE = IO.STREAM;
TV: TYPE = AMTypes.TV;
Global Variables
typescript: IO.STREAM ← NIL;
typescriptBox: ViewerClasses.Viewer ← NIL;
spyViewer: Containers.Container ← NIL;
**************************************************
spy viewer creation
**************************************************
Spy: Commander.CommandProc =
TRUSTED {
IF spyViewer =
NIL
OR spyViewer.destroyed
THEN {
spyViewer ← Containers.Create[info: [name: "Spy", icon: Icons.NewIconFromFile["/Cedar/CedarChest6.0/Spy/Spy.icon", 0], scrollable: FALSE, iconic: TRUE]];
CreateSpyViewer[spyViewer];
}
ELSE
IF spyViewer.iconic
THEN ViewerOps.OpenIcon[spyViewer]
ELSE ViewerOps.PaintViewer[spyViewer, all];
IF spyViewer.offDeskTop THEN ViewerOps.ChangeColumn[spyViewer, left];
};
CreateSpyViewer: ViewerClasses.InitProc =
TRUSTED {
rule: ViewerClasses.Viewer;
x:INTEGER = 10; -- upper left corner of commands
y:INTEGER = 10;
sp:INTEGER = 6;
line:INTEGER = 20; -- height of each line
typescript
rule ← Rules.Create[info: [parent: self, wx: 0, wy: y + 4*line, ww: 100, wh: 1]];
Containers.ChildXBound[self, rule];
typescriptBox ← ViewerOps.CreateViewer[flavor: $Typescript,
info: [wx: 0, wy: y + 4*line + 1,
ww: 70*sp+x-5, wh: 40*line,
border: FALSE,
parent: self]];
typescript ← ViewerIO.CreateViewerStreams["Spy.Log", typescriptBox].out;
Containers.ChildXBound[self, typescriptBox];
Containers.ChildYBound[self, typescriptBox];
first line
spyOnButton ← Buttons.Create[
proc: ToggleSpy,
documentation: "Spy records data only when this is 'on'.",
info: [name: "Spy: {off} ",
wx: x, wy: y,
border: FALSE,
parent: self]];
SetSpyButton[];
dataTypeButton ← Buttons.Create[
proc: ToggleType,
documentation: "Gives the resource to be monitored. Toggle through for list.",
info: [name: "Watching: {CPU} ",
wx: x + 15*sp, wy: y,
border: FALSE,
parent: self]];
SetTypeButton[];
processBoxX ← 475 - 34*sp;
processBoxY ← y + 1;
processBoxW ← 8*sp;
processBoxH ← line;
bracketLabel ← Labels.Create[
info: [name: " ",
-- used to print the trailing bracket when dataType = process
wx: processBoxX + processBoxW, wy: processBoxY,
border: FALSE, parent: self]];
tablesLabel ← Labels.Create[
info: [name: " ",
-- indicates when tables are being built
wx: processBoxX + processBoxW + 3*sp, wy: y,
border: FALSE, parent: self]];
second line
displayButton ← Buttons.Create[
fork: TRUE,
documentation: "Displays the current data on a separate typescript.",
proc: DisplayData,
info: [name: "DisplayData!",
wx: x, wy: y + line,
parent: self]];
cutoffButton ← Buttons.Create[
proc: ToggleCutoff,
documentation: "Specifies percentage cutoff for printing.",
info: [name: "cutoff: {100}",
wx: x + 15*sp, wy: y + line,
border: FALSE,
parent: self]];
SetCutoffButton[];
third line
setStartBreakButton ← Buttons.Create[
proc: SetStartBreak,
documentation: "Select a source or a rope of the form ModuleImpl.Proc.",
info: [name: "SetStartBreak!",
wx: x, wy: y + 2*line,
parent: self]];
setStopBreakButton ← Buttons.Create[
proc: SetStopBreak,
documentation: "Spy will record data as long as the number of start breaks exceeds the number of stops.",
info: [name: "SetStopBreak!",
wx: x + 15*sp, wy: y + 2*line, -- 31
parent: self]];
clearBreaksButton ← Buttons.Create[
proc: ClearBreaks,
documentation: "Clears the breaks given by user; resets the mode.",
info: [name: "ClearBreaks!",
wx: x + 31*sp, wy: y + 2*line, -- 47
parent: self]];
fourth line
setUserBreakButton ← Buttons.Create[
proc: SetUserBreak,
documentation: "Spy will count the given breaks as they are encountered.",
info: [name: "SetUserBreak!",
wx: x, wy: y + 3*line,
parent: self]];
setTraceButton ← Buttons.Create[
proc: SetUserBreak,
clientData: $Trace,
documentation: "Logs a trace whenever the break is encountered.",
info: [name: "SetTrace!",
wx: x + 15*sp, wy: y + 3*line,
parent: self]];
clearUserBreaksButton ← Buttons.Create[
documentation: "Clears the user breaks given.",
proc: ClearUserBreaks,
info: [name: "ClearUserBreaks!",
wx: x + 27*sp, wy: y + 3*line,
parent: self]];
};
**************************************************
turning the spy off and on
**************************************************
break: BOOLEAN ← FALSE;
spyOn: BOOLEAN ← FALSE;
displayButton: Buttons.Button ← NIL;
spyOnButton: Buttons.Button ← NIL;
tablesLabel: Labels.Label ← NIL;
bracketLabel: Labels.Label ← NIL;
SetSpyButton:
PROC = {
SELECT
TRUE
FROM
break
AND spyOn => {
IF ~Rope.Equal[spyOnButton.name, "Break: {on}"]
THEN typescript.Put[[character['\n]], [rope["Start breaks enabled."]], [character['\n]]];
Buttons.ReLabel[spyOnButton, "Break: {on}"]};
break
AND ~spyOn => {
IF ~Rope.Equal[spyOnButton.name, "Break: {off}"]
THEN typescript.Put[[character['\n]], [rope["Start breaks disabled."]], [character['\n]]];
Buttons.ReLabel[spyOnButton, "Break: {off}"]};
~break
AND spyOn => {
IF ~Rope.Equal[spyOnButton.name, "Spy: {on}"]
THEN typescript.Put[[character['\n]], [rope["Spy started."]], [character['\n]]];
Buttons.ReLabel[spyOnButton, "Spy: {on}"]};
ENDCASE => {
IF ~Rope.Equal[spyOnButton.name, "Spy: {off}"]
THEN typescript.Put[[character['\n]], [rope["Spy stopped."]], [character['\n]]];
Buttons.ReLabel[spyOnButton, "Spy: {off}"]};
};
ToggleSpy: Buttons.ButtonProc =
TRUSTED {
SELECT spyOn
FROM
TRUE => StopSpy[];
FALSE => StartSpy[];
ENDCASE => ERROR;
};
StopSpy:
PROC = {
spyOn ← FALSE;
SpyClient.StopSpy[];
SetSpyButton[];
};
StartSpy:
PROC = {
error: ROPE ← NIL;
process: PrincOps.PsbIndex ← PrincOps.PsbNull;
Labels.Set[tablesLabel,"initializing"];
IF dataType = breakProcess
AND ~break
THEN
error ← "Watching break process but no breaks set!";
IF dataType = process
THEN {
process ← Convert.CardFromRope[ViewerTools.GetContents[processBox], 8];
IF process = PrincOps.PsbNull THEN error ← "No process specified."};
IF error =
NIL
THEN error ← SpyClient.InitializeSpy[
dataType: dataType,
process: process];
Labels.Set[tablesLabel, NIL];
IF error #
NIL
THEN {
typescript.Put[[character['\n]], [rope[error]], [character['\n]]];
RETURN};
spyOn ← TRUE;
SetSpyButton[];
SpyClient.StartSpy[];
};
**************************************************
determine the data type
**************************************************
dataType: SpyClient.DataType ← CPU;
dataTypeButton: Buttons.Button ← NIL;
processBox: ViewerClasses.Viewer ← NIL;
processBoxX, processBoxY, processBoxW, processBoxH: CARDINAL;
SetTypeButton:
PROC = {
Buttons.ReLabel[dataTypeButton,
SELECT dataType
FROM
CPU => "Watching: {CPU}",
process => "Watching: {process number: ",
breakProcess => "Watching: {break process}",
pagefaults => "Watching: {pagefaults}",
allocations => "Watching: {allocations}",
wordsAllocated => "Watching: {wordsAllocated}",
userDefined => "Watching: {user breaks}",
ENDCASE => ERROR];
IF dataType = process
AND (processBox =
NIL
OR processBox.destroyed)
THEN {
processBox ← ViewerTools.MakeNewTextViewer[
info: [wx: processBoxX, wy: processBoxY,
ww: processBoxW, wh: processBoxH,
border: FALSE, scrollable: FALSE,
parent: spyViewer]];
Labels.Set[bracketLabel, "}"];
ViewerTools.SetSelection[processBox]};
IF dataType # process
AND processBox #
NIL
AND ~processBox.destroyed
THEN {
ViewerOps.DestroyViewer[processBox];
Labels.Set[bracketLabel, " "]};
};
ToggleType: Buttons.ButtonProc =
TRUSTED {
dataType ←
SELECT mouseButton
FROM
red =>
IF dataType =
LAST[SpyClient.DataType]
THEN FIRST[SpyClient.DataType] ELSE SUCC[dataType],
blue =>
IF dataType =
FIRST[SpyClient.DataType]
THEN LAST[SpyClient.DataType] ELSE PRED[dataType],
ENDCASE => CPU;
SetTypeButton[];
};
**************************************************
displaying data
**************************************************
cutoff: CARDINAL ← 3;
cutoffButton: Buttons.Button;
ToggleCutoff: Buttons.ButtonProc =
TRUSTED {
SELECT mouseButton
FROM
blue => IF cutoff > 0 THEN cutoff ← cutoff - 1;
yellow => cutoff ← 3;
red => IF cutoff < 100 THEN cutoff ← cutoff + 1;
ENDCASE;
SetCutoffButton[];
};
SetCutoffButton:
PROC = {
stream: IO.STREAM;
stream ← IO.ROS[];
stream.Put[[rope["cutoff: {"]], [integer[cutoff]], [rope["}"]]];
Buttons.ReLabel[cutoffButton, IO.RopeFromROS[stream]];
stream.Close[];
};
DisplayData: Buttons.ButtonProc =
TRUSTED {
IF spyOn THEN StopSpy[];
SpyClient.DisplayData[cutoff, NIL, NIL, control];
IF control THEN SpyClient.DisplayData[cutoff, "Results of spying on Spy log."];
};
**************************************************
setting and clearing start and stop breaks
**************************************************
setStartBreakButton: Buttons.Button ← NIL;
setStopBreakButton: Buttons.Button ← NIL;
clearBreaksButton: Buttons.Button ←
NIL;
set your breaks and then turn the spy on
as long as there have been more start breaks than stop breaks
the spy will keep on counting
turning the spy off will stop the counting (although not the breaks).
hit ClearBreaks to delete breaks.
ClearBreaks: Buttons.ButtonProc =
TRUSTED {
SpyClient.ClearBreaks[];
typescript.Put[[rope["\nStart and Stop Breaks cleared.\n"]]];
break ← FALSE;
StopSpy[];
};
SetStartBreak: Buttons.ButtonProc =
TRUSTED {
msg, name: ROPE;
ok: BOOLEAN ← FALSE;
section: AMModel.Section;
[section, name, msg] ← LocationFromSelection[];
IF section # NIL OR name # NIL THEN [ok, msg] ← SpyClient.SetStartBreak[section, name];
typescript.Put[[character['\n]], [rope[msg]], [character['\n]]];
IF ~ok THEN RETURN;
break ← TRUE;
dataType ← breakProcess;
SetTypeButton[];
StopSpy[];
};
SetStopBreak: Buttons.ButtonProc =
TRUSTED {
msg, name: ROPE;
ok: BOOLEAN ← FALSE;
section: AMModel.Section;
[section, name, msg] ← LocationFromSelection[];
IF section # NIL OR name # NIL THEN [ok, msg] ← SpyClient.SetStopBreak[section, name];
typescript.Put[[character['\n]], [rope[msg]], [character['\n]]];
IF ~ok THEN RETURN;
break ← TRUE;
StopSpy[];
};
**************************************************
setting and clearing user breaks
**************************************************
setTraceButton: Buttons.Button ← NIL;
setUserBreakButton: Buttons.Button ← NIL;
clearUserBreaksButton: Buttons.Button ← NIL;
ClearUserBreaks: Buttons.ButtonProc =
TRUSTED {
SpyClient.ClearUserBreaks[];
typescript.Put[[rope["\nUser Breaks cleared.\n"]]];
IF dataType = userDefined THEN StopSpy[];
};
SetUserBreak: Buttons.ButtonProc =
TRUSTED {
msg, name: ROPE;
ok: BOOLEAN ← FALSE;
section: AMModel.Section;
[section, name, msg] ← LocationFromSelection[];
IF section #
NIL
OR name #
NIL
THEN
IF clientData = $Trace
THEN [ok, msg] ← SpyClient.SetTrace[section, name]
ELSE [ok, msg] ← SpyClient.SetUserBreak[section, 1, name];
typescript.Put[[character['\n]], [rope[msg]], [character['\n]]];
IF ~ok THEN RETURN;
StopSpy[];
IF dataType = userDefined THEN RETURN;
dataType ← userDefined;
SetTypeButton[];
};
LocationFromSelection:
PROC
RETURNS[section: AMModel.Section ←
NIL, name, error:
ROPE ←
NIL] = {
viewer: ViewerClasses.Viewer;
viewer ← ViewerTools.GetSelectedViewer[];
IF viewer = NIL THEN RETURN [error: "no selected viewer"];
IF viewer.class.flavor # $Text
OR ~Rope.Equal[Split[viewer.file].ext, "mesa"]
THEN {
module, proc: ROPE;
contents: ROPE ← ViewerTools.GetSelectionContents[];
[module, proc] ← Split[contents];
IF module # NIL AND proc # NIL THEN RETURN[name: contents];
};
section ← AMViewerOps.SectionFromSelection[
! AMTypes.Error => {error ← msg; CONTINUE}].section;
};
Split:
PROC [name:
ROPE]
RETURNS [root: Rope.Text, ext: Rope.Text ←
NIL] = {
name ← FS.ExpandName[name ! FS.Error => {name ← NIL; CONTINUE}].fullFName;
IF name #
NIL
THEN {
len: INT = Rope.Length[name];
dotIndex: INT ← len;
bangIndex: INT ← len;
pos: INT ← len;
WHILE pos > 0
DO
SELECT Rope.Fetch[name, pos ← pos - 1]
FROM
'! => bangIndex ← pos;
'. => dotIndex ← pos;
'], '>, '/ => EXIT;
ENDCASE;
ENDLOOP;
IF dotIndex >= bangIndex
THEN root ← Rope.Flatten[name]
ELSE {
root ← name.Flatten[0, dotIndex];
ext ← name.Flatten[dotIndex+1, bangIndex-dotIndex-1];
};
};
};
Commander.Register[key: "Spy", proc: Spy, doc: "spies on program performance"];
}.