
<<TiogaVoice.tip>>
    <<Copyright Ó 1985, 1986, 1987 by Xerox Corporation.  All rights reserved.>>
    <<modified from Tioga.tip of June 11, 1985 11:26:27 am PDT (Rick Beach)>>
    <<>>
OPTIONS
Fast,
PrintKeys;

<<Miscellaneous macro definitions to standardize certain conventions>>

[DEF,ClickTime,(200)]

[DEF,DownClick,(~1 Down BEFORE [ClickTime])]

[DEF,UpClick,(~1 Up BEFORE [ClickTime])]

[DEF,Click,([UpClick,~1] AND [DownClick,~1])]

[DEF,BothUp,(~1 Up WHILE ~2 Up)]

[DEF,WhileThreeUp,
(WHILE ~1 Up WHILE ~2 Up WHILE ~3 Up)]

[DEF,FourUp,(~1 Up WHILE ~2 Up WHILE ~3 Up WHILE ~4 Up)]

[DEF,WhileFiveUp,
(WHILE ~1 Up WHILE ~2 Up WHILE ~3 Up WHILE ~4 Up WHILE ~5 Up)]

[DEF,WhileSixUp,
(WHILE ~1 Up WHILE ~2 Up WHILE ~3 Up WHILE ~4 Up WHILE ~5 Up WHILE ~6 Up)]

[DEF,CTRL,(Ctrl Down | Spare3 Down)]

[DEF,WhileCTRLUp,(WHILE Ctrl Up WHILE Spare3 Up)]

[DEF,WhenCTRLUp,(
Ctrl Up WHILE Spare3 Up ~1 => ~2;
Spare3 Up WHILE Ctrl Up ~1 => ~2)]

[DEF,SHIFT,(LeftShift Down | RightShift Down)]

[DEF,SHIFTUp,[BothUp,LeftShift,RightShift]]

[DEF,WhenSHIFTUp,(
LeftShift Up WHILE RightShift Up ~1 => ~2;
RightShift Up WHILE LeftShift Up ~1 => ~2)]

[DEF,IfShift,(SELECT ENABLE FROM
[SHIFT] => ~1;
ENDCASE => ~2)]

[DEF,IfCtrl,(SELECT ENABLE FROM
[CTRL] => ~1;
ENDCASE => ~2)]


SELECT TRIGGER FROM -- top level trigger select

<<Mouse buttons and mouse movement>>

[DEF,Sel,(SELECT ENABLE FROM
[CTRL] => [IfShift,
{ ~2 Coords SelSecondary ToPrimary SelPendDel ~1 },
{ ~2 Coords ToLimbo SelPendDel ~1 }];
[SHIFT] => { ~2 Coords SelSecondary ToPrimary SelNotPendDel ~1 };
ENDCASE => { ~2 Coords SelNotPendDel ~1 })]

[DEF,ClickSel,(SELECT ENABLE FROM
[SHIFT] [WhileCTRLUp] => [Sel,~1,~2 ForceSelNotPendDel];
ENDCASE => [Sel,~1,~2])]

[DEF,MouseClick,(SELECT TRIGGER FROM
[Click,~1] => [ClickSel,~3,~1Mouse];
ENDCASE => [ClickSel,~2,~1Mouse])]

Red Down => [MouseClick,Red,SelChar,SelNode];

Yellow Down => SELECT ENABLE FROM
Red Up => [MouseClick,Yellow,SelWord,SelBranch];
ENDCASE;

[DEF,Extend,(
[IfShift,[Sel,~1 SelStartExtend,BlueMouse],[Sel,~1 SelStartExtend,BlueMouse ForceSelPendDel]])]

Blue Down => SELECT ENABLE FROM
[BothUp,Red,Yellow] => SELECT TRIGGER FROM
[Click,Blue] => SELECT TRIGGER FROM
[Click,Blue] => [Extend,SelExpand];
ENDCASE => [Extend,SelReduce];
ENDCASE => [Extend];
ENDCASE;

Mouse => SELECT ENABLE FROM
Red Down => [Sel,SelUpdate];
Yellow Down => [Sel,SelUpdate];
Blue Down => { Coords SelExtend };
ENDCASE;

[DEF,ButtonUp,(SELECT ENABLE FROM
[SHIFTUp] [WhileCTRLUp] WHILE [BothUp,~1,~2] => SELECT ENABLE FROM
ESC Down => Repeat;
ENDCASE => DoEdit;
ENDCASE)]

Red Up => SELECT ENABLE FROM
Blue Down => [Extend,ForceSelPendDel];
ENDCASE => [ButtonUp,Blue,Yellow];

Yellow Up => SELECT ENABLE FROM
Blue Down WHILE Red Up => [Extend,ForceSelPendDel];
ENDCASE => [ButtonUp,Red,Blue];

Blue Up => [ButtonUp,Red,Yellow];


<<Shift key Commands>>

[WhenSHIFTUp,[WhileThreeUp,Red,Yellow,Blue] [WhileCTRLUp],DoEdit];
[WhenCTRLUp,[WhileThreeUp,Red,Yellow,Blue] WHILE [SHIFTUp],DoEdit];


<<Function key Commands>>

BS Down => [IfCtrl,
[IfShift,{ 1 DeleteNextWord },{ 1 BackWord }],
[IfShift,{ 1 DeleteNextChar },{ 1 BackSpace }]];

ESC Down [WhileCTRLUp] => [IfShift,Undo,Repeat];

DEL Down => SELECT ENABLE FROM
[SHIFT] => EditAbort;
[CTRL] => EditAbort;
Red Down => EditAbort;
Yellow Down => EditAbort;
Blue Down => EditAbort;
ENDCASE => Delete;


<<Number Commands>>

[DEF,Num,(~1 Down => SELECT ENABLE FROM
~3
[CTRL] => { IntermediateUser Command~2 };
ENDCASE)]

[Num,Zero,0];
[Num,One,1, [SHIFT] WHILE [CTRL] => { AdvancedUser ReadProfile };];
[Num,Two,2];
[Num,Three,3];
[Num,Four,4];
[Num,Five,5];
[Num,Six,6];
[Num,Seven,7];
[Num,Eight,8];
[Num,Nine,9];


<<Punctuation Commands>>

Return Down => SELECT ENABLE FROM
[SHIFT] => Char;
ENDCASE => Char;

<<Letter Commands>>

[DEF,Letter,(
~1 Down WHILE BW Up => SELECT ENABLE FROM
~3
ENDCASE)]


[Letter,A,0,
[CTRL] => [IfShift,{ IntermediateUser 1 DeleteNextChar },{ 1 BackSpace }]];
[Letter,B,1];
[Letter,C,2];
[Letter,D,3,
[CTRL] => { IntermediateUser Everything }];
[Letter,E,4];
[Letter,F,5];
[Letter,G,6];
[Letter,H,7,
[CTRL] => [IfShift,{ IntermediateUser 1 DeleteNextChar },{ 1 BackSpace }]];
[Letter,I,8];
[Letter,J,9];
[Letter,K,10];
[Letter,L,11];
[Letter,M,12];
[Letter,N,13];
[Letter,O,14];
[Letter,P,15,
[CTRL] => { IntermediateUser Paste }];
[Letter,Q,16,
[CTRL] => { IntermediateUser ToPrimary SelSecondary SelNotPendDel EditLooks }];
[Letter,R,17, -- romp to end of current node
[CTRL] => { MakePointSelection GrowSelection GrowSelection GrowSelection CaretAfter MakePointSelection }];
[Letter,S,18,-- copy primary
[CTRL] => { IntermediateUser MakeNotPendingDelete ToSecondary SelSecondary SelNotPendDel }];
[Letter,T,19]; 
[Letter,U,20];
[Letter,V,21];
[Letter,W,22,
[CTRL] => [IfShift,{ IntermediateUser 1 DeleteNextWord },{ 1 BackWord }]];
[Letter,X,23,-- transpose
[CTRL] => { IntermediateUser MakePendingDelete ToBoth SelSecondary }];
[Letter,Y,24];
[Letter,Z,25,-- move primary
[CTRL] => { IntermediateUser MakePendingDelete ToSecondary SelSecondary SelNotPendDel }];

ENDCASE.