ImagerPixelArray.mesa
Copyright Ó 1984, 1985, 1986, 1987, 1991 by Xerox Corporation. All rights reserved.
Michael Plass, June 5, 1991 10:30 pm PDT
Doug Wyatt, January 19, 1987 5:59:52 pm PST
DIRECTORY
ImagerPixel USING [PixelBuffer, PixelMap, PixelProc],
ImagerSample USING [Function, maxVec, nullFunction, Sample, SampleMap, SampleBuffer, Vec, zeroVec],
ImagerTransformation USING [ScanMode, Transformation],
Prop USING [PropList],
Rope USING [ROPE],
SF USING [Box];
ImagerPixelArray: CEDAR DEFINITIONS
~ BEGIN
Transformation: TYPE ~ ImagerTransformation.Transformation;
ScanMode: TYPE ~ ImagerTransformation.ScanMode;
Sample: TYPE ~ ImagerSample.Sample;
SampleBuffer: TYPE ~ ImagerSample.SampleBuffer;
SampleMap: TYPE ~ ImagerSample.SampleMap;
PixelProc: TYPE ~ ImagerPixel.PixelProc;
PixelBuffer: TYPE ~ ImagerPixel.PixelBuffer;
PixelMap: TYPE ~ ImagerPixel.PixelMap;
Vec: TYPE ~ ImagerSample.Vec;
zeroVec: Vec ~ ImagerSample.zeroVec;
maxVec: Vec ~ ImagerSample.maxVec;
Function: TYPE ~ ImagerSample.Function;
nullFunction: Function ~ ImagerSample.nullFunction;
ROPE: TYPE ~ Rope.ROPE;
maxCount: NAT ~ NAT.LAST;
Basic operations
PixelArray: TYPE ~ REF PixelArrayRep;
PixelArrayRep: TYPE ~ RECORD [
immutable: BOOL,
samplesPerPixel: NAT, -- number of samples for each pixel
sSize, fSize: INT, -- slow and fast dimensions (Interpress calls these xPixels, yPixels)
m: Transformation, -- transforms [s, f] coordinates to "upright" [x, y] coordinates
class: REF PixelArrayClassRep, -- class operations
data: REF, -- instance data
propList: Prop.PropList ¬ NIL
];
The pixel array contains sSize*fSize pixels, samplesPerPixel*sSize*fSize samples.
A sample is named by a triple: i IN[0..samplesPerPixel), s IN[0..sSize), f IN[0..fSize).
PixelArrayClassRep: TYPE; -- see ImagerPixelArrayPrivate
ErrorDesc: TYPE ~ RECORD [code: ATOM, explanation: ROPE];
Error: ERROR [error: ErrorDesc];
GetClass: PROC [pa: PixelArray] RETURNS [ATOM];
... returns an ATOM that identifies the PixelArray's class.
MaxSampleValue: PROC [pa: PixelArray, i: NAT] RETURNS [Sample];
... returns the maximum sample value for the ith sample.
For all i IN[0..pa.samplesPerPixel), s IN[0..pa.sSize), f IN[0..pa.fSize):
pa.Get[i, s, f] IN[0..pa.MaxSampleValue[i]].
Get: PROC [pa: PixelArray, i: NAT ¬ 0, s, f: INT] RETURNS [Sample];
... returns the sample value with indices [i, s, f].
! BoundsFault if i ~IN[0..pa.samplesPerPixel) OR s ~IN[0..pa.sSize) OR f ~IN[0..pa.fSize).
GetSamples: PROC [pa: PixelArray, i: NAT ¬ 0, s, f: INT ¬ 0,
buffer: SampleBuffer, start: NAT ¬ 0, count: NAT ¬ maxCount];
... fetches a run of samples into a buffer. The effect is:
FOR k: NAT IN[0..MIN[samples.length-start, count]) DO
samples[start+k] ← pa.Get[i, s, f+k]
ENDLOOP
! BoundsFault if any index into the pixel array is out of range
GetPixels: PROC [pa: PixelArray, s, f: INT ¬ 0,
pixels: PixelBuffer, start: NAT ¬ 0, count: NAT ¬ maxCount];
... fetches a run of pixels into a buffer. The effect is:
FOR i: NAT IN[0..pa.samplesPerPixel) DO
pa.GetSamples[i, s, f, pixels[i], start, count]
ENDLOOP
! BoundsFault if any index into the pixel array is out of range
Transfer: PROC [pa: PixelArray, i: NAT ¬ 0, s, f: INT ¬ 0,
dst: SampleMap, dstMin: Vec ¬ zeroVec, size: Vec ¬ maxVec,
function: Function ¬ nullFunction];
... like ImagerSample.Transfer, where the pixel array is the source.
! BoundsFault if any sample index is out of range
Creating pixel arrays
Copy: PROC [pa: PixelArray] RETURNS [PixelArray];
... makes an immutable copy of a pixel array; returns pa if pa.immutable.
Extract: PROC [old: PixelArray, samplesPerPixel: NAT, select: PROC [NAT] RETURNS [NAT]]
RETURNS [new: PixelArray];
... extracts selected sample layers from a pixel array.
new.samplesPerPixel = samplesPerPixel
new.sSize = old.sSize, new.fSize = old.fSize
ImagerTransformation.Equal[new.m, old.m]
new.MaxSampleValue[i] = old.MaxSampleValue[select[i]]
new.Get[i, s, f] = old.Get[select[i], s, f]
! BoundsFault if for any i IN[0..samplesPerPixel), select[i] ~IN[0..pa.samplesPerPixel).
Join: PROC [list: LIST OF PixelArray] RETURNS [PixelArray];
Join3: PROC [pa1, pa2, pa3: PixelArray] RETURNS [PixelArray];
... joins multiple sample planes into one PixelArray.
! Error[[$incompatibleJoin, ...]] if sizes or transformations do not match.
FromPixelMap: PROC [pixelMap: PixelMap, box: SF.Box, scanMode: ScanMode, immutable: BOOL ¬ FALSE] RETURNS [PixelArray];
If immutable=TRUE, caller guarantees that the contents of the PixelMap will not change as long as the PixelArray is in use.
The ScanMode relates the (slow, fast) coords of the PixelMap to the client coords of the PixelArray.
The box must lie completely within the bounds of the map, or a bounds fault will occur.
The pixel indexed by box.min in the pixelMap will be at [0, 0] in the PixelArray.
END.