<<>>
    <<XlAsciiImpl.mesa>>
        <<Copyright Ó 1991, 1992 by Xerox Corporation.  All rights reserved.>>
        <<Christian Jacobi, March 29, 1991 1:12:40 pm PST>>
        <<Christian Jacobi, February 27, 1992 1:23 pm PST>>

    DIRECTORY 
        Ascii,
        KeyChars,
        KeySymsKB,
        KeyMapping,
        Xl,
        XlAscii;

    XlAsciiImpl: CEDAR MONITOR 
        IMPORTS Ascii, KeyChars, KeyMapping, Xl
        EXPORTS XlAscii ~
    BEGIN 

    nullKeySym: Xl.KeySym ~ [0];

    AsciiFromKeySym: PUBLIC PROC [keysym: Xl.KeySym] RETURNS [char: CHAR Ź 0C] = {
        char Ź KeyChars.CharFromKeySym[keysym];
        IF char>VAL[127] THEN char Ź 0C;
        }; 

    KeySymFromAscii: PUBLIC PROC [char: CHAR] RETURNS [keysym: Xl.KeySym] = {
        keysym Ź KeyChars.KeySymFromChar[char];
        };

    Convert: PUBLIC PROC [connection: Xl.Connection, keyCode: Xl.KeyCode, state: Xl.SetOfKeyButMask Ź [], matchKeys: LIST OF Xl.KeySym 
    Ź NIL] RETURNS [char: CHAR Ź 0C, keysym: Xl.KeySym Ź [0], matched: Xl.KeySym Ź [0], isModifier: BOOL Ź FALSE] = {
        modmap: Xl.ModifierMapping Ź Xl.GetModifierMapping[connection];
        mapping: Xl.KeyboardMapping Ź Xl.GetKeyboardMapping[connection];
        FOR m: Xl.KeyBut IN [shift..mod5] DO
            IF modmap[0][m]=keyCode THEN {isModifier Ź TRUE; EXIT};
            ENDLOOP; 
        IF isModifier 
            THEN {
                keysym Ź KeyMapping.GetKeySym[mapping, keyCode, 0];
                char Ź AsciiFromKeySym[keysym];
                }
            ELSE {
                ks0: Xl.KeySym Ź KeyMapping.GetKeySym[mapping, keyCode, 0];
                ks1: Xl.KeySym Ź KeyMapping.GetKeySym[mapping, keyCode, 1];
                ks2: Xl.KeySym Ź KeyMapping.GetKeySym[mapping, keyCode, 2];
                ks3: Xl.KeySym Ź KeyMapping.GetKeySym[mapping, keyCode, 3];
                FOR list: LIST OF Xl.KeySym Ź matchKeys, list.rest WHILE list #NIL DO
                    SELECT list.first FROM
                        ks0, ks1, ks2, ks3 => {matched Ź list.first; EXIT};
                        ENDCASE => {};
                    ENDLOOP; 
                SELECT TRUE FROM
                    state.control AND state.shift => {
                        keysym Ź ks3;
                        IF keysym=nullKeySym THEN {
                            keysym Ź ks1;
                            IF keysym=nullKeySym THEN keysym Ź ks0;
                            };
                        char Ź AsciiFromKeySym[ks1];
                        char Ź Ascii.Control[char];
                        };
                    state.control => {
                        keysym Ź ks2;
                        IF keysym=nullKeySym THEN keysym Ź ks0;
                        char Ź AsciiFromKeySym[ks0];
                        char Ź Ascii.Control[char];
                        };
                    state.shift => {
                        keysym Ź ks1;
                        IF keysym#nullKeySym 
                            THEN char Ź AsciiFromKeySym[ks1] 
                            ELSE {
                                char Ź AsciiFromKeySym[ks0];
                                char Ź Ascii.Upper[char];
                                keysym Ź KeySymFromAscii[char];
                                };
                        };
                    state.lock => {
                        char1: CHAR Ź AsciiFromKeySym[ks0];
                        char Ź Ascii.Upper[char1];
                        keysym Ź IF char1=char THEN ks0 ELSE ks1;
                        };
                    ENDCASE => {
                        char1: CHAR Ź AsciiFromKeySym[ks0];
                        keysym Ź ks0;
                        char Ź Ascii.Lower[char1];
                        IF char#char1 THEN {
                            keysym Ź KeySymFromAscii[char];
                            };
                        };
                };
        };

    END.