<<>>
    <<CodeTimerToolImpl.mesa>>
        <<Copyright Ó 1989, 1993 by Xerox Corporation.  All rights reserved.>>
        <<Pier, February 15, 1989 12:07:45 pm PST>>
        <<Bier, March 26, 1993 4:36 pm PST>>
        <<>>
    DIRECTORY
        Atom, Buttons, CodeTimer, Commander, MJSContainers, IO, Menus, RefTab, Rope, TypeScript, ViewerClasses, ViewerOps, ViewerTools;

    CodeTimerToolImpl: CEDAR PROGRAM
        IMPORTS Atom, Buttons, CodeTimer, Commander, MJSContainers, IO, Menus, RefTab, Rope, TypeScript, ViewerOps, ViewerTools = BEGIN

    ToolData: TYPE = REF ToolDataObj;
    ToolDataObj: TYPE = RECORD [
        typescript, textViewer: Viewer
        ];
    Viewer: TYPE = ViewerClasses.Viewer;

    PrintHerald: PROC [r: Rope.ROPE, look: CHAR, typescript: Viewer] = {
        TypeScript.ChangeLooks[typescript, look];
        TypeScript.PutRope[typescript, r];
        TypeScript.ChangeLooks[typescript, ' ]; -- clear looks
        };

    scratch: IO.STREAM;
    scratchRope: Rope.ROPE;

    PrintIntervalProc: ViewerClasses.ClickProc = {
        <<PROC [parent: Viewer, clientData: REF ANY _ NIL, 
        mouseButton: MouseButton _ red, shift, control: BOOL _ FALSE];>>
        toolData: ToolData Ź NARROW[MJSContainers.GetClientData[parent]];
        typescript: Viewer Ź toolData.typescript;
        problemMessage: Rope.ROPE;
        BEGIN
            ENABLE CodeTimer.Problem => {
                problemMessage Ź msg;
                GOTO CTProblem;
                };
            textViewer: Viewer Ź toolData.textViewer;
            table, interval: Rope.ROPE;
            tableName, intervalName: ATOM;
            from: CodeTimer.Table;
            PrintHerald["\nPrintInterval: \n", heraldLook, typescript];
            table Ź ViewerTools.GetContents[viewer: textViewer];
            IF Rope.Length[table]=0 THEN GOTO BogusT;
            tableName Ź Atom.MakeAtom[table];
            from Ź CodeTimer.GetTable[tableName];
            IF from=NIL THEN GOTO BogusT;
            interval Ź ViewerTools.GetSelectionContents[];
            IF Rope.Length[interval]=0 THEN GOTO BogusI;
            intervalName Ź Atom.MakeAtom[interval];
            scratch Ź IO.ROS[scratch];
            CodeTimer.PrintInt[scratch, intervalName, tableName];
            scratchRope Ź IO.RopeFromROS[self: scratch, close: TRUE];
            IF Rope.Length[scratchRope]=0 THEN scratchRope Ź IO.PutFR1["%g  is empty\n", [rope[interval]] ];
            TypeScript.PutRope[typescript, scratchRope];
            TypeScript.BackSpace[typescript, 1]; -- extra CR
            EXITS
                BogusT => TypeScript.PutRope[typescript, "NIL or unknown table - Bogus"];
                BogusI => TypeScript.PutRope[typescript, "NIL or unknown interval - Bogus"];
                CTProblem => TypeScript.PutRope[typescript, problemMessage];
            END;
        };

    PrintAllIntervalsProc: ViewerClasses.ClickProc = {
        toolData: ToolData Ź NARROW[MJSContainers.GetClientData[parent]];
        typescript: Viewer Ź toolData.typescript;
        problemMessage: Rope.ROPE;
        BEGIN
            ENABLE CodeTimer.Problem => {
                problemMessage Ź msg;
                GOTO CTProblem;
                };
            table: Rope.ROPE;
            tableName: ATOM;
            from: CodeTimer.Table;
            textViewer: Viewer Ź toolData.textViewer;
            PrintHerald["\nPrintAllIntervals: \n", heraldLook, typescript];
            table Ź ViewerTools.GetContents[viewer: textViewer];
            IF Rope.Length[table]=0 THEN GOTO Bogus;
            tableName Ź Atom.MakeAtom[table];
            from Ź CodeTimer.GetTable[tableName];
            IF from=NIL THEN GOTO Bogus;
            scratch Ź IO.ROS[scratch];
            CodeTimer.PrintTable[scratch, from];
            scratchRope Ź IO.RopeFromROS[self: scratch, close: TRUE];
            IF Rope.Length[scratchRope]=0 THEN scratchRope Ź IO.PutFR1["Table %g is empty\n", [rope[table]] ];
            TypeScript.PutRope[typescript, scratchRope];
            TypeScript.BackSpace[typescript, 1]; -- extra CR
            EXITS
                Bogus => TypeScript.PutRope[typescript, "NIL or unknown table - Bogus"];
                CTProblem => TypeScript.PutRope[typescript, problemMessage];
            END;
        };

    ListIntervalsProc: ViewerClasses.ClickProc = {
        toolData: ToolData Ź NARROW[MJSContainers.GetClientData[parent]];
        typescript: Viewer Ź toolData.typescript;
        problemMessage: Rope.ROPE;
        BEGIN
            ENABLE CodeTimer.Problem => {
                problemMessage Ź msg;
                GOTO CTProblem;
                };
            DoPrintName: CodeTimer.ForEachIntervalInContextProc = {
                <<PROC [intervalName: ATOM, process: CARD, starts, totalMsec, minMsec, maxMsec, maxIndex, startsWithoutStops: CARD, level: NAT _ 0] 
                RETURNS [done: BOOL _ FALSE];>>
                <<This should do duplicate suppression>>
                found: BOOL Ź intervalTable.Fetch[intervalName].found;
                IF NOT found THEN {
                    scratch.PutF1[" %g", [atom[intervalName]] ];
                    [] Ź intervalTable.Store[intervalName, intervalName];
                    };
                };
            table: Rope.ROPE;
            tableName: ATOM;
            from: CodeTimer.Table;
            intervalTable: RefTab.Ref Ź RefTab.Create[];
            textViewer: Viewer Ź toolData.textViewer;
            PrintHerald["\nListIntervals: ", heraldLook, typescript];
            table Ź ViewerTools.GetContents[viewer: textViewer];
            IF Rope.Length[table]=0 THEN GOTO Bogus;
            tableName Ź Atom.MakeAtom[table];
            from Ź CodeTimer.GetTable[tableName];
            IF from=NIL THEN GOTO Bogus;
            scratch Ź IO.ROS[scratch];
            [] Ź CodeTimer.ForEachIntervalInContext[from, DoPrintName];
            scratchRope Ź IO.RopeFromROS[self: scratch, close: TRUE];
            TypeScript.PutRope[typescript, scratchRope];
            EXITS
                Bogus => TypeScript.PutRope[typescript, "NIL or unknown table - Bogus"];
                CTProblem => TypeScript.PutRope[typescript, problemMessage];
            END;
        };

    ResetIntervalProc: ViewerClasses.ClickProc = {
        toolData: ToolData Ź NARROW[MJSContainers.GetClientData[parent]];
        typescript: Viewer Ź toolData.typescript;
        problemMessage: Rope.ROPE;
        BEGIN
            ENABLE CodeTimer.Problem => {
                problemMessage Ź msg;
                GOTO CTProblem;
                };
            table, interval: Rope.ROPE;
            tableName, intervalName: ATOM;
            from: CodeTimer.Table;
            textViewer: Viewer Ź toolData.textViewer;
            PrintHerald["\nResetInterval: ", heraldLook, typescript];
            table Ź ViewerTools.GetContents[viewer: textViewer];
            IF Rope.Length[table]=0 THEN GOTO BogusT;
            tableName Ź Atom.MakeAtom[table];
            from Ź CodeTimer.GetTable[tableName];
            IF from=NIL THEN GOTO BogusT;
            interval Ź ViewerTools.GetSelectionContents[];
            IF Rope.Length[interval]=0 THEN GOTO BogusI;
            intervalName Ź Atom.MakeAtom[interval];
            CodeTimer.ResetInterval[intervalName, from];
            TypeScript.PutRope[typescript, IO.PutFR1["Interval %g reset", [rope[interval]] ]];
            EXITS
                BogusT => TypeScript.PutRope[typescript, "NIL or unknown table - Bogus"];
                BogusI => TypeScript.PutRope[typescript, "NIL or unknown interval - Bogus"];
                CTProblem => TypeScript.PutRope[typescript, problemMessage];
            END;
        };

    ResetAllIntervalsProc: ViewerClasses.ClickProc = {
        toolData: ToolData Ź NARROW[MJSContainers.GetClientData[parent]];
        typescript: Viewer Ź toolData.typescript;
        problemMessage: Rope.ROPE;
        BEGIN
            ENABLE CodeTimer.Problem => {
                problemMessage Ź msg;
                GOTO CTProblem;
                };
            table: Rope.ROPE;
            tableName: ATOM;
            textViewer: Viewer Ź toolData.textViewer;
            from: CodeTimer.Table;
            PrintHerald["\nResetAllIntervals: ", heraldLook, typescript];
            table Ź ViewerTools.GetContents[viewer: textViewer];
            IF Rope.Length[table]=0 THEN GOTO Bogus;
            tableName Ź Atom.MakeAtom[table];
            from Ź CodeTimer.GetTable[tableName];
            IF from=NIL THEN GOTO Bogus;
            CodeTimer.ResetTable[from];
            TypeScript.PutRope[typescript, IO.PutFR1["Table %g reset", [rope[table]] ]];
            EXITS
                Bogus => TypeScript.PutRope[typescript, "NIL or unknown table - Bogus"];
                CTProblem => TypeScript.PutRope[typescript, problemMessage];
            END;
        };

    ListTablesProc: ViewerClasses.ClickProc = {
        toolData: ToolData Ź NARROW[MJSContainers.GetClientData[parent]];
        typescript: Viewer Ź toolData.typescript;
        problemMessage: Rope.ROPE;
        BEGIN
            ENABLE CodeTimer.Problem => {
                problemMessage Ź msg;
                GOTO CTProblem;
                };
            PrintTableName: CodeTimer.ForEachTableProc = {
                <<PROC [tableName: ATOM, table: Table] RETURNS [done: BOOL _ FALSE];>>
                scratch.PutF1[" %g", [atom[tableName]] ];
                };

            textViewer: Viewer Ź toolData.textViewer;
            PrintHerald["\nListTables: ", heraldLook, typescript];
            scratch Ź IO.ROS[scratch];
            [] Ź CodeTimer.ForEachTable[PrintTableName];
            scratchRope Ź IO.RopeFromROS[self: scratch, close: TRUE];
            TypeScript.PutRope[typescript, IF Rope.Length[scratchRope]=0 THEN "No tables" ELSE scratchRope];
            EXITS
                CTProblem => TypeScript.PutRope[typescript, problemMessage];
            END;
        };

    SetSelectionProc: ViewerClasses.ClickProc = {
        <<PROC [parent: Viewer, clientData: REF ANY _ NIL, mouseButton: MouseButton _ red, shift, control: BOOL _ FALSE];>>
        toolData: ToolData Ź NARROW[clientData];
        textViewer: Viewer Ź toolData.textViewer;
        ViewerTools.SetSelection[textViewer];
        };

    heraldLook: CHAR Ź 'b;
    entryHeight: INTEGER Ź 20;
    gap: INTEGER Ź 5;

    CreateCodeTimerTool: Commander.CommandProc = {
        <<PROC [cmd: Handle] RETURNS [result: REF _ NIL, msg: ROPE _ NIL];>>
        menu: ViewerClasses.Menu;
        printInterval, printAllIntervals, listIntervals, resetInterval, resetAllIntervals, listTables: Menus.MenuEntry;

        buttonLabel, container, textViewer, typescript: Viewer;

        toolData: ToolData Ź NEW[ToolDataObj];

        menu Ź Menus.CreateMenu[2];
        printInterval Ź Menus.CreateEntry[name: "PrintInterval", proc: PrintIntervalProc, fork: FALSE];
        printAllIntervals Ź Menus.CreateEntry[name: "PrintAllIntervals", proc: PrintAllIntervalsProc, fork: FALSE];
        listIntervals Ź Menus.CreateEntry[name: "ListIntervals", proc: ListIntervalsProc, fork: FALSE];
        resetInterval Ź Menus.CreateEntry[name: "ResetInterval", proc: ResetIntervalProc, fork: FALSE];
        resetAllIntervals Ź Menus.CreateEntry[name: "ResetAllIntervals", proc: ResetAllIntervalsProc, fork: FALSE];
        listTables Ź Menus.CreateEntry[name: "ListTables", proc: ListTablesProc, fork: FALSE];

        Menus.AppendMenuEntry[menu, printInterval, 0];
        Menus.AppendMenuEntry[menu, printAllIntervals, 0];
        Menus.AppendMenuEntry[menu, listIntervals, 0];
        Menus.AppendMenuEntry[menu, resetInterval, 1];
        Menus.AppendMenuEntry[menu, resetAllIntervals, 1];
        Menus.AppendMenuEntry[menu, listTables, 1];

        container Ź MJSContainers.Create[viewerFlavor: $VanillaMJSContainer, info: [name: "CodeTimerTool", menu: menu, scrollable: FALSE, 
        data: toolData], paint: FALSE];
        buttonLabel Ź Buttons.Create[clientData: toolData, info: [name: "TableName: ", parent: container, border: FALSE], proc: 
        SetSelectionProc, fork: FALSE, paint: FALSE];
        textViewer Ź ViewerOps.CreateViewer[flavor: $Text, info: [parent: container, wx: buttonLabel.wx+buttonLabel.ww+gap, wh: 
        entryHeight, border: TRUE, scrollable: FALSE], paint: FALSE];
        MJSContainers.ChildXBound[container, textViewer];

        typescript Ź TypeScript.Create[info: [parent: container, wy: entryHeight, border: FALSE, scrollable: TRUE], paint: FALSE];
        toolData.typescript Ź typescript;
        toolData.textViewer Ź textViewer;
        MJSContainers.ChildXBound[container, typescript];
        MJSContainers.ChildYBound[container, typescript];

        PrintHerald["\nWelcome to CodeTimerTool of March, 1993", heraldLook, typescript];

        ViewerOps.PaintViewer[viewer: container, hint: all, clearClient: TRUE, whatChanged: NIL];
        };

    Commander.Register["CodeTimerTool", CreateCodeTimerTool, "Creates a tool to look at the tables of timed code intervals.  Use 
    codeTimerOn to enable timing."];

    END.