#!/bin/csh
#
# StartX
# Command file to start X windows
# Created by Christian Jacobi, February 9, 1990
# David Nichols, August 9, 1990
#   Willie-Sue, March 30, 1992
#
# You need the files
#   .xinitrc
#   .twmrc
#   .Xdefaults
# in your home directory.
#
# You may edit these three, but be careful not to update them from
# the /project/cedar10.1 versions afterward.  You can use the file
# ~/.xinit-personal for some customization to .xinitrc.

# Make sure the search paths contains X windows.  If you add these
# directories in your .login, they won't get set here.
if ( $PATH !~ */import/bin/X11R3* ) set path = ( $path /import/bin/X11R3 )
if ( $PATH !~ */import/X11R4/bin* ) set path = ( /import/X11R4/bin $path )

# Make sure the X11 stuff is on the search path for man.
if ( ! $?MANPATH ) then
    setenv MANPATH /import/X11R4/man:/usr/man
else if ( $MANPATH !~ */import/X11R4/man* ) then
    setenv MANPATH /import/X11R4/man:$MANPATH
endif

# Make sure X11 dynamic link libraries are available.
if ( ! $?LD_LIBRARY_PATH ) then
    setenv LD_LIBRARY_PATH /import/X11R4/usr/lib
else if ( $LD_LIBRARY_PATH !~ */import/X11R4/usr/lib* ) then
    setenv LD_LIBRARY_PATH /import/X11R4/usr/lib:$LD_LIBRARY_PATH
endif

# Use the local display
if (! $?DISPLAY ) setenv DISPLAY "unix:0.0" 

# Make sure the the cleanup part is executed even after errors
onintr cleanup

# Start X server MIT's X11R4.
xinit -- -ar1 550 -ar2 40


# Now we are done; clean up.
cleanup:
if (! $?WINDOW_PARENT) then
	reset
	clear
	kbd_mode -a
else
	kbd_mode -a
endif
#
#eof
#