SymTab.mesa - definitions for symbol table abstraction
Copyright Ó 1985, 1986, 1987, 1991 by Xerox Corporation. All rights reserved.
Russ Atkinson, February 5, 1985 2:03:26 pm PST
Doug Wyatt, January 15, 1987 4:14:24 pm PST
A SymTab is hash table which associates ROPE keys with REF values. SymTab is like RefTab except for the Key type.
DIRECTORY
Rope USING [ROPE];
SymTab: CEDAR DEFINITIONS = BEGIN
Ref: TYPE = REF SymTabRep;
SymTabRep: TYPE = MONITORED RECORD [impl: REF SymTabImplRep];
SymTabImplRep: TYPE;
Key: TYPE = Rope.ROPE;
Val: TYPE = REF;
Create: PROC [mod: NAT ¬ 17, case: BOOL ¬ TRUE] RETURNS [Ref];
... creates new table with suggested hash size; if case is TRUE, keys are compared exactly; if case is FALSE, case is ignored in comparing keys.
GetSize: PROC [x: Ref] RETURNS [INT];
... returns number of key-value pairs in table (use this to properly deal with monitored data in preference to using the size field)
Fetch: PROC [x: Ref, key: Key] RETURNS [found: BOOL, val: Val];
... looks up key in table, returns associated value (if any); if found = TRUE, val = value associated with given key; if found = FALSE, val = NIL
FetchText: PROC [x: Ref, key: REF READONLY TEXT] RETURNS [found: BOOL, val: Val];
... looks up key in table, returns associated value (if any); if found = TRUE, val = value associated with given key; if found = FALSE, val = NIL; the key MUST NOT BE ALTERED during a call of this procedure
Replace: PROC [x: Ref, key: Key, val: Val] RETURNS [BOOL];
... replaces value for existing key; returns TRUE if previous value overwritten; if no previous value for key, returns FALSE without inserting new pair
Store: PROC [x: Ref, key: Key, val: Val] RETURNS [BOOL];
... stores new key-value pair, overwriting previous value for given key; returns TRUE if new value, FALSE if previous value overwritten
Insert: PROC [x: Ref, key: Key, val: Val] RETURNS [BOOL];
... inserts new key-value pair, except if previous value for given key; returns TRUE if inserted, FALSE if previous value for key
Delete: PROC [x: Ref, key: Key] RETURNS [BOOL];
... deletes key-value pair associated with given key; returns TRUE if deletion actually occurred, FALSE if no such key
Erase: PROC [x: Ref];
... deletes all key-value pairs in the table
EachPairAction: TYPE = PROC [key: Key, val: Val] RETURNS [quit: BOOL ¬ FALSE];
Pairs: PROC [x: Ref, action: EachPairAction] RETURNS [BOOL];
... enumerates pairs currently in symbol table in unspecified order; pairs inserted/deleted during enumeration may or may not be seen; applies action to each pair until action returns TRUE or no more pairs; returns TRUE if some action returns TRUE
UpdateOperation: TYPE = {none, store, delete};
UpdateAction: TYPE = PROC [found: BOOL, val: Val]
RETURNS [op: UpdateOperation ¬ none, new: Val ¬ NIL];
Update: PROC [x: Ref, key: Key, action: UpdateAction];
... atomically performs an update action; looks up key and calls action, which returns the desired operation. If op=none, the table is not changed; if op=store, the new value is stored; if op=delete, key is removed from the table.
Copy: PROC [x: Ref] RETURNS [Ref];
... atomically copies the table.
END.