
    <<CDPExt.mesa>>
        <<Copyright © 1985, 1987 by Xerox Corporation.  All rights reserved.>>
        <<Created by Christian Jacobi, December 12, 1985 2:19:57 pm PST>>
        <<Last edited by: Christian Jacobi, February 13, 1987 1:16:14 pm PST>>
    DIRECTORY
        CD,
        CDBottomUp,
        CDCommandOps,
        CDOps,
        CDTextExtraction,
        CDSequencer,
        IO,
        Rope,
        TerminalIO;

    CDPExt: CEDAR PROGRAM
        IMPORTS CD, CDBottomUp, CDCommandOps, CDOps, CDTextExtraction, CDSequencer, IO, TerminalIO =
    BEGIN 

    propertyExtractor: CDBottomUp.Class = CDBottomUp.Register[DoExt, ReUseExt];

    Message: PROC [handle: CDBottomUp.Handle, ob: CD.Object, errNo: INT, prefix: Rope.ROPE] = {
        TerminalIO.PutF["  %g %g; found %g errors\n", IO.rope[prefix], IO.rope[CD.Describe[ob]], IO.int[errNo]];
        IF errNo>0 THEN {
            handle.cnt _ handle.cnt+1;
            handle.r _ IO.PutFR["%g  %g errors in %g\n", IO.rope[handle.r], IO.int[errNo], IO.rope[CD.Describe[ob]]]
            };
        CDSequencer.CheckAborted[handle.design];
        };

    DoExt: CDBottomUp.DoProc = {
        errNo: INT ~ CDTextExtraction.ExtractProperties[handle.design, ob].errors;
        Message[handle, ob, errNo, "extracting properties: "];
        val _ NEW[INT_errNo];
        };

    ReUseExt: CDBottomUp.ReUseProc = {
        WITH previousVal SELECT FROM
            ri: REF INT => Message[handle, ob, ri^, "previously extracted properties: "];
            ENDCASE => NULL;
        };

    HierarchicalPropertyExtractionComm: PROC [comm: CDSequencer.Command] = {

        HierarchicalPropertyExtraction: PROC [design: CD.Design, ob: CD.Object] = {
            h: CDBottomUp.Handle _ CDBottomUp.StartRecurse[propertyExtractor, ob, design].handle;
            IF h.cnt=0 THEN TerminalIO.PutRope["no errors found\n"]
            ELSE TerminalIO.PutF1["error(s) found in %g object(s)\n", [integer[h.cnt]]]
            };

        inst: CD.Instance _ CDOps.TheInstance[comm.design, "hierarchical Property extraction\n"];
        IF inst#NIL THEN HierarchicalPropertyExtraction[comm.design, inst.ob];
        };

    CDCommandOps.RegisterWithMenu[menu: $ProgramMenu, entry: "Hierarchical Property extraction", proc: 
    HierarchicalPropertyExtractionComm, key: $HPExt];
    END.